init_teb_greenroof_pgdn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#############################################################
SUBROUTINE init_teb_greenroof_pgd_n (DTCO, U, CHI, DTI, I, DST, SLT, CHT, TG, T, TOP, TVG, GRM, &
                                     hprogram,hinit,oread_pgd, ki, ksv, hsv, kversion, pco2, prhoa)
!#############################################################
!
!!****  *INIT_TEB_GREENROOF_PGD_n* - routine to initialize ISBA
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      A. Lemonsu  *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    09/2009
!!                  11/2013 (B. Decharme) No exp profile with DIF
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_ch_isba_n, ONLY : ch_isba_t
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_isba_n, ONLY : isba_t
USE modd_dst_n, ONLY : dst_t
USE modd_slt_n, ONLY : slt_t
USE modd_ch_teb_n, ONLY : ch_teb_t
USE modd_teb_grid_n, ONLY : teb_grid_t
USE modd_teb_n, ONLY : teb_t
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_teb_veg_n, ONLY : teb_veg_options_t
USE modd_surfex_n, ONLY : teb_greenroof_model_t
!
USE modd_type_date_surf
USE modd_type_snow
!


USE modd_data_cover_par,       ONLY: nvegtype
USE modd_surf_par,             ONLY: xundef, nundef

USE modd_sgh_par,              ONLY: ndimtab, xf_decay
!
USE modi_get_luout
USE modi_allocate_teb_greenroof_pgd
USE modi_read_pgd_teb_greenroof_n
USE modi_convert_patch_teb_greenroof
USE modi_init_from_data_greenroof_n
USE modi_init_veg_pgd_garden_n
USE modi_exp_decay_soil_fr
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(ch_isba_t), INTENT(INOUT) :: chi
TYPE(data_isba_t), INTENT(INOUT) :: dti
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(dst_t), INTENT(INOUT) :: dst
TYPE(slt_t), INTENT(INOUT) :: slt
TYPE(ch_teb_t), INTENT(INOUT) :: cht
TYPE(teb_grid_t), INTENT(INOUT) :: tg
TYPE(teb_t), INTENT(INOUT) :: t
TYPE(teb_options_t), INTENT(INOUT) :: top
TYPE(teb_veg_options_t), INTENT(INOUT) :: tvg
TYPE(teb_greenroof_model_t), INTENT(INOUT) :: grm
!
 CHARACTER(LEN=6),                   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=3),                   INTENT(IN)  :: hinit     ! choice of fields to initialize
LOGICAL,                            INTENT(IN)  :: oread_pgd ! flag to read PGD fields in the file
INTEGER,                            INTENT(IN)  :: ki        ! number of points
INTEGER,                            INTENT(IN)  :: ksv       ! number of scalars
 CHARACTER(LEN=6), DIMENSION(KSV),   INTENT(IN)  :: hsv       ! name of all scalar variables
INTEGER,                            INTENT(IN)  :: kversion  ! version number of the file being read
REAL,             DIMENSION(KI),    INTENT(IN)  :: pco2        ! CO2 concentration (kg/m3)
REAL,             DIMENSION(KI),    INTENT(IN)  :: prhoa       ! air density
!
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER           :: jilu     ! loop increment
INTEGER           :: iluout   ! unit of output listing file
!
INTEGER           :: idecade  ! decade of simulation
!
INTEGER :: jvegtype, jlayer  ! loop counter on layers
!
REAL, DIMENSION(KI)               :: zf
REAL, DIMENSION(KI)               :: zwork
!
!*       0.3   Soil parameter values for organic matter - from Lawrence and Slater (2008):
!              ----------------------------------------------------------------------------------
!
REAL, PARAMETER   :: zwsat_om      = 0.9       ! Porosity of OM (m3/m3)
REAL, PARAMETER   :: zcondsat_om   = 2.8e-4    ! Saturated hydraulic conductivity for OM (m/s)
REAL, PARAMETER   :: zmpotsat_om   = -10.3e-3  ! Saturated matric potential for OM (m)
REAL, PARAMETER   :: zbcoef_om     = 2.7       ! CH78 b-parameter for OM (-)
!
REAL, PARAMETER   :: zconddry_om   = 0.05      ! Dry thermal conductivity for OM (W/m/K)
REAL, PARAMETER   :: zcondsld_om   = 0.25      ! Soil solids thermal conductivity for OM (W/m/K)
REAL, PARAMETER   :: zhcapsoil_om  = 2.5e+6    ! Soil heat capacity for OM
!
REAL, PARAMETER   :: zmpot_wwilt   = -150.     ! Matric potential at wilting point (m)
REAL, PARAMETER   :: zhydcond_wfc  = 1.157e-9  ! Hydraulic conductivity at field capacity (m/s)
!                                              ! = 0.1 mm/day
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!               Initialisation for IO
!
IF (lhook) CALL dr_hook('INIT_TEB_GREENROOF_PGD_n',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!-------------------------------------------------------------------------------
!
!*       2.     Physiographic fields
!               --------------------
!
!
!*       2.1    Cover, soil and orographic fields:
!               ---------------------------------
!
IF (oread_pgd) &
 CALL read_pgd_teb_greenroof_n(cht, dtco, grm%DTGR, grm%GBGR, u, grm%TGRO, grm%TGRP, tg, &
                               hprogram,kversion)
!
!
!* allocation of green roofs variables
!
 CALL allocate_teb_greenroof_pgd(grm%TGRPE, grm%TGRP, &
                                 oread_pgd, ki, nvegtype, grm%TGRO%NLAYER_GR, ndimtab)
!
!*       2.2    Physiographic data fields from land cover:
!               -----------------------------------------
!
IF (top%TTIME%TDATE%MONTH /= nundef) THEN
  idecade = 3 * ( top%TTIME%TDATE%MONTH - 1 ) + min(top%TTIME%TDATE%DAY-1,29) / 10 + 1
ELSE
  idecade = 1
END IF
!
!
IF (.NOT. grm%TGRO%LPAR_GREENROOF) THEN
  CALL convert_patch_teb_greenroof(dtco, dti, i, grm%TGRO, grm%TGRPE, grm%TGRP, top, tvg, &
                                   ki,idecade)
ELSE
 CALL init_from_data_greenroof_n(grm%DTGR, grm%TGRO, idecade,tvg%CPHOTO,        &
                                 grm%TGRP%XOM_GR, grm%TGRP%XSAND_GR, grm%TGRP%XCLAY_GR, &
                                 grm%TGRPE%CUR%XVEG, grm%TGRPE%CUR%XLAI,grm%TGRP%XRSMIN, &
                                 grm%TGRP%XGAMMA,grm%TGRP%XWRMAX_CF,grm%TGRP%XRGL,grm%TGRP%XCV,&
                                 grm%TGRP%XDG,grm%TGRP%XD_ICE,grm%TGRPE%CUR%XZ0,grm%TGRP%XZ0_O_Z0H,  &
                                 grm%TGRP%XALBNIR_VEG,grm%TGRP%XALBVIS_VEG,grm%TGRP%XALBUV_VEG,&
                                 grm%TGRPE%CUR%XEMIS,grm%TGRP%XVEGTYPE,grm%TGRP%XROOTFRAC,          &
                                 grm%TGRP%XGMES,grm%TGRP%XBSLAI,grm%TGRP%XLAIMIN,grm%TGRP%XSEFOLD,grm%TGRP%XGC,   &
                                 grm%TGRP%XDMAX, grm%TGRP%XF2I, grm%TGRP%LSTRESS, grm%TGRP%XH_TREE,grm%TGRP%XRE25,&
                                 grm%TGRP%XCE_NITRO,grm%TGRP%XCF_NITRO,grm%TGRP%XCNA_NITRO      )  
  IF (grm%TGRO%CISBA_GR=='DIF') THEN
    WHERE(t%CUR%XGREENROOF(:)/=0.)
      grm%TGRP%NWG_LAYER(:)=grm%TGRO%NLAYER_GR 
      grm%TGRP%XDG2  (:)=0.0
      grm%TGRP%XDROOT(:)=0.0
    ENDWHERE
    DO jlayer=grm%TGRO%NLAYER_GR,1,-1
      DO jilu=1,ki
        IF(t%CUR%XGREENROOF(jilu)/=0..AND.grm%TGRP%XROOTFRAC(jilu,jlayer)>=1.0)THEN
          grm%TGRP%XDG2  (jilu)=grm%TGRP%XDG(jilu,jlayer)
          grm%TGRP%XDROOT(jilu)=grm%TGRP%XDG(jilu,jlayer)
        ENDIF
      ENDDO
    ENDDO
  ENDIF
END IF
!
WHERE (t%CUR%XGREENROOF(:)==0.)
  ! GARDEN default values /may need changing for green roofs
  grm%TGRP%XOM_GR     (:,1) = 0.5
  grm%TGRP%XOM_GR     (:,2) = 0.5
  grm%TGRP%XSAND_GR   (:,1) = 0.33
  grm%TGRP%XSAND_GR   (:,2) = 0.33
  grm%TGRP%XCLAY_GR   (:,1) = 0.33
  grm%TGRP%XCLAY_GR   (:,2) = 0.33
  grm%TGRPE%CUR%XVEG       (:  ) = 0.
  grm%TGRPE%CUR%XLAI       (:  ) = 0.
  grm%TGRP%XRSMIN     (:  ) = 40.
  grm%TGRP%XGAMMA     (:  ) = 0.
  grm%TGRP%XWRMAX_CF  (:  ) = 0.2
  grm%TGRP%XRGL       (:  ) = 100.
  grm%TGRP%XCV        (:  ) = 2.e-5
  grm%TGRPE%CUR%XZ0        (:  ) = 0.013
  grm%TGRP%XZ0_O_Z0H  (:  ) = 10.
  grm%TGRP%XALBNIR_VEG(:  ) = 0.30
  grm%TGRP%XALBVIS_VEG(:  ) = 0.30
  grm%TGRP%XALBUV_VEG (:  ) = 0.06
  grm%TGRPE%CUR%XEMIS      (:  ) = 0.94
END WHERE
IF (tvg%CPHOTO/='NON') THEN
  WHERE (t%CUR%XGREENROOF(:)==0.)
    grm%TGRP%XGMES      (:  ) = 0.020
    grm%TGRP%XBSLAI     (:  ) = 0.36
    grm%TGRP%XLAIMIN    (:  ) = 0.3
    grm%TGRP%XSEFOLD    (:  ) = 90*86400.
    grm%TGRP%XH_TREE    (:  ) = 0.
    grm%TGRP%XRE25      (:  ) = 3.6e-7    
    grm%TGRP%XGC        (:  ) = 0.00025
  END WHERE
  IF (tvg%CPHOTO/='AGS' .AND. tvg%CPHOTO/='LAI') THEN
    WHERE (t%CUR%XGREENROOF(:)==0.)     
      grm%TGRP%XDMAX      (:  ) = 0.1
      grm%TGRP%XF2I       (:  ) = 0.3
    END WHERE
    IF (tvg%CPHOTO=='NIT' .OR. tvg%CPHOTO=='NCB') THEN
      WHERE (t%CUR%XGREENROOF(:)==0.)          
        grm%TGRP%XCE_NITRO  (:  ) = 7.68
        grm%TGRP%XCF_NITRO  (:  ) = -4.33
        grm%TGRP%XCNA_NITRO (:  ) = 1.3
      END WHERE
    ENDIF
  ENDIF
ENDIF  
IF(grm%TGRO%CISBA_GR/='DIF')THEN
  DO jlayer=1,grm%TGRO%NLAYER_GR
    WHERE (t%CUR%XGREENROOF(:)==0.)
      grm%TGRP%XDG(:,jlayer)=0.2*jlayer
    END WHERE
  ENDDO
ELSE
  WHERE (t%CUR%XGREENROOF(:)==0.) 
    grm%TGRP%XDG(:,1)=0.01
    grm%TGRP%XDG(:,2)=0.04
    grm%TGRP%XROOTFRAC(:,1)=0.
    grm%TGRP%XROOTFRAC(:,2)=0.
  END WHERE        
  DO jlayer=3,grm%TGRO%NLAYER_GR
    WHERE (t%CUR%XGREENROOF(:)==0.)
      grm%TGRP%XDG(:,jlayer)=0.1*(jlayer-2)
      grm%TGRP%XROOTFRAC(:,jlayer)=0.
    END WHERE
  ENDDO               
  WHERE (t%CUR%XGREENROOF(:)==0.) 
    grm%TGRP%NWG_LAYER(:)=grm%TGRO%NLAYER_GR
    grm%TGRP%XDROOT   (:)=0.0
    grm%TGRP%XDG2     (:)=grm%TGRP%XDG(:,grm%TGRO%NLAYER_GR-1)
  ENDWHERE    
ENDIF  
WHERE (t%CUR%XGREENROOF(:)==0.) 
  grm%TGRP%XD_ICE(:)=0.8*grm%TGRP%XDG(:,2)
END WHERE  
DO jvegtype=1,nvegtype
  WHERE (t%CUR%XGREENROOF(:)==0.)
    grm%TGRP%XVEGTYPE(:,jvegtype)=0.
    grm%TGRP%XVEGTYPE(:,1)=1.
  END WHERE
ENDDO
!
 CALL init_veg_pgd_garden_n(chi, dtco, dst, i, slt, u, &
                            hprogram, iluout, ki, grm%TGRO%NLAYER_GR, top%TTIME%TDATE%MONTH,    &
                        grm%TGRP%XVEGTYPE, grm%TGRP%XTDEEP, grm%TGRP%XGAMMAT, tvg%CPHOTO, hinit, &
                        grm%TGRO%LTR_ML_GR, grm%TGRO%CRUNOFF_GR, tvg%NNBIOMASS, pco2, prhoa, &
                        grm%TGRP%XABC, grm%TGRP%XPOI, grm%TGRP%XGMES, grm%TGRP%XGC, grm%TGRP%XDMAX, &
                        grm%TGRP%XANMAX, grm%TGRP%XFZERO, grm%TGRP%XEPSO, grm%TGRP%XGAMM, grm%TGRP%XQDGAMM,   &
                        grm%TGRP%XQDGMES, grm%TGRP%XT1GMES, grm%TGRP%XT2GMES, grm%TGRP%XAMAX, grm%TGRP%XQDAMAX, &
                        grm%TGRP%XT1AMAX, grm%TGRP%XT2AMAX,grm%TGRP%XAH, grm%TGRP%XBH,            &
                        ksv, hsv, cht%SVT, cht%CCH_NAMES, cht%CAER_NAMES,cht%CDSTNAMES, cht%CSLTNAMES, &
                        cht%CCHEM_SURF_FILE, grm%TGRP%XCLAY_GR, grm%TGRP%XSAND_GR, tvg%CPEDOTF,      &
                        grm%TGRP%XCONDSAT, grm%TGRP%XMPOTSAT, grm%TGRP%XBCOEF, grm%TGRP%XWWILT, &
                        grm%TGRP%XWFC, grm%TGRP%XWSAT, grm%TGRP%XTAUICE, grm%TGRP%XCGSAT, grm%TGRP%XC1SAT, &
                        grm%TGRP%XC2REF, grm%TGRP%XC3, grm%TGRP%XC4B, grm%TGRP%XACOEF, grm%TGRP%XPCOEF, &
                        grm%TGRP%XC4REF, grm%TGRP%XPCPS, grm%TGRP%XPLVTT, grm%TGRP%XPLSTT,        &
                        grm%TGRO%CSCOND_GR, grm%TGRO%CISBA_GR, grm%TGRP%XHCAPSOIL, grm%TGRP%XCONDDRY, &
                        grm%TGRP%XCONDSLD, tvg%CCPSURF, grm%TGRP%XDG, grm%TGRP%XDROOT, grm%TGRP%XDG2, &
                        grm%TGRP%XROOTFRAC, grm%TGRP%XRUNOFFD, grm%TGRP%XDZG, grm%TGRP%XDZDIF,       &
                        grm%TGRP%XSOILWGHT, grm%TGRP%NWG_LAYER, grm%TGRO%NLAYER_HORT_GR, &
                        grm%TGRO%NLAYER_DUN_GR, grm%TGRP%XD_ICE,  &
                        grm%TGRP%XKSAT_ICE, grm%TGRP%XALBNIR_DRY, grm%TGRP%XALBVIS_DRY, grm%TGRP%XALBUV_DRY,   &
                        grm%TGRP%XALBNIR_WET, grm%TGRP%XALBVIS_WET, grm%TGRP%XALBUV_WET, grm%TGRP%XBSLAI_NITRO, &
                        grm%TGRP%XCE_NITRO, grm%TGRP%XCNA_NITRO, grm%TGRP%XCF_NITRO                            )
!
!-------------------------------------------------------------------------------
!
!*       5.1     Soil thermal characteristics for greenroofs:
!               ----------------------------------------------
!
! WARNING: must be done before soil hydraulic characteristics (because of WSAT)
! Estimation of WSAT_MI for use in HEATCAPZ and THRMCONDZ for mineral fraction
! and allow weighted combination with regard to OM & no-OM fractions:
!
IF (grm%TGRO%CSCOND_GR=='PL98' .OR. grm%TGRO%CISBA_GR=='DIF') THEN
  DO jlayer=1,grm%TGRO%NLAYER_GR
     grm%TGRP%XHCAPSOIL(:,jlayer) =    grm%TGRP%XOM_GR(:,jlayer)  * zhcapsoil_om +      &
                           (1-grm%TGRP%XOM_GR(:,jlayer)) * grm%TGRP%XHCAPSOIL(:,jlayer)  
     grm%TGRP%XCONDDRY(:,jlayer) = (zconddry_om         * grm%TGRP%XCONDDRY(:,jlayer))    &
                         /(  grm%TGRP%XOM_GR(:,jlayer)  * grm%TGRP%XCONDDRY(:,jlayer) +   &
                          (1-grm%TGRP%XOM_GR(:,jlayer)) * zconddry_om)
     grm%TGRP%XCONDSLD(:,jlayer) = (zcondsld_om         * grm%TGRP%XCONDSLD(:,jlayer))    &
                         /(  grm%TGRP%XOM_GR(:,jlayer)  * grm%TGRP%XCONDSLD(:,jlayer) +   &
                          (1-grm%TGRP%XOM_GR(:,jlayer)) * zcondsld_om)
  ENDDO
END IF
!
! +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
! Validation case : experimental values for Nancy 2011 case
! +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
! Substrate layer
DO jlayer=1,4
    grm%TGRP%XCONDDRY (:,jlayer) = 0.15
    grm%TGRP%XHCAPSOIL(:,jlayer) = 1342000.
ENDDO
! Drainage layer
DO jlayer=5,6
    grm%TGRP%XCONDDRY (:,jlayer) = 0.09
    grm%TGRP%XHCAPSOIL(:,jlayer) = 331500.
ENDDO
! +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
!*       5.2     Soil thermal characteristics:
!               --------------------------------
!
DO jlayer=1,grm%TGRO%NLAYER_GR
  grm%TGRP%XCONDSAT(:,jlayer) =   grm%TGRP%XOM_GR(:,jlayer)* zcondsat_om   &
                        +(1-grm%TGRP%XOM_GR(:,jlayer))* grm%TGRP%XCONDSAT(:,jlayer)
END DO
!
! Note that if ISBA/=DIF, always CDIF = 'BC' and CPEDOTF = 'CH78'
DO jlayer=1,grm%TGRO%NLAYER_GR
  grm%TGRP%XBCOEF  (:,jlayer) =    grm%TGRP%XOM_GR(:,jlayer) * zbcoef_om        &
                       +(1-grm%TGRP%XOM_GR(:,jlayer))* grm%TGRP%XBCOEF(:,jlayer)
  grm%TGRP%XMPOTSAT(:,jlayer) =    grm%TGRP%XOM_GR(:,jlayer) * zmpotsat_om      &
                       +(1-grm%TGRP%XOM_GR(:,jlayer))* grm%TGRP%XMPOTSAT(:,jlayer)
END DO
!        
DO jlayer=1,grm%TGRO%NLAYER_GR
   grm%TGRP%XWSAT (:,jlayer) =    grm%TGRP%XOM_GR(:,jlayer)* zwsat_om            &
                     +(1-grm%TGRP%XOM_GR(:,jlayer))* grm%TGRP%XWSAT(:,jlayer)
   grm%TGRP%XWWILT(:,jlayer) = exp(((log(-1*zmpot_wwilt)-log(-1*grm%TGRP%XMPOTSAT(:,jlayer)))   &
                    / (-1*grm%TGRP%XBCOEF(:,jlayer)))+log(grm%TGRP%XWSAT(:,jlayer)))
   grm%TGRP%XWFC  (:,jlayer) = exp(((log(zhydcond_wfc)-log(grm%TGRP%XCONDSAT(:,jlayer)))        &
                    / (2*grm%TGRP%XBCOEF(:,jlayer)+3))+log(grm%TGRP%XWSAT(:,jlayer)))
END DO
!
! +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
! Validation case : experimental values for Nancy 2011 case
! +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
! Substrate layer
DO jlayer=1,4
  grm%TGRP%XWSAT   (:,jlayer) = 0.674     ! Value tested
  grm%TGRP%XCONDSAT(:,jlayer) = 2.162e-3  ! Value tested
  grm%TGRP%XMPOTSAT(:,jlayer) = -0.932    ! Value tested
  grm%TGRP%XBCOEF  (:,jlayer) = 3.9       ! Value tested
  grm%TGRP%XWWILT  (:,jlayer) = 0.15      ! from OBS-NANCY
  grm%TGRP%XWFC    (:,jlayer) = 0.37      ! from OBS-NANCY
ENDDO
! Drainage layer
DO jlayer=5,6
   grm%TGRP%XWSAT   (:,jlayer) = 0.9       ! Value tested
   grm%TGRP%XCONDSAT(:,jlayer) = 3.32e-3   ! Value tested
   grm%TGRP%XMPOTSAT(:,jlayer) = -0.121    ! Value tested
   grm%TGRP%XBCOEF  (:,jlayer) = 2.7       ! Value tested
   grm%TGRP%XWWILT  (:,jlayer) = 0.15      ! sert à initialiser le WG ds la couche
   grm%TGRP%XWFC    (:,jlayer) = 0.37      ! sert à initialiser le WG ds la couche
ENDDO
!-------------------------------------------------------------------------------
!
!*       6.1    Initialize of the SGH scheme:'
!               ------------------------------
!
IF(grm%TGRO%CKSAT_GR=='SGH' .AND. grm%TGRO%CISBA_GR/='DIF' .AND. hinit/='PRE')THEN 
  zf(:)=min(4.0/grm%TGRP%XDG(:,2),xf_decay)
  CALL exp_decay_soil_fr(grm%TGRO%CISBA_GR, zf(:),grm%TGRP%XC1SAT(:),grm%TGRP%XC2REF(:),&
                         grm%TGRP%XDG(:,:),grm%TGRP%XD_ICE(:),grm%TGRP%XC4REF(:),&
                         grm%TGRP%XC3(:,:),grm%TGRP%XCONDSAT(:,:),grm%TGRP%XKSAT_ICE(:))
ENDIF
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('INIT_TEB_GREENROOF_PGD_n',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
!
END SUBROUTINE init_teb_greenroof_pgd_n