exp_decay_soil_fr.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##########
      SUBROUTINE exp_decay_soil_fr (HISBA, PF, PC1SAT, PC2REF, PD_G, PD_ICE, &
                                      pc4ref, pc3, pcondsat, pksat_ice       )  
!     ##########################################################################
!
!!****  *EXP_DECAY_SOIL_FR*  
!!
!!    PURPOSE
!!    -------
!
!     We caculate the hydraulic coductivity decay factor for each FR-coefficients.
!     Also, we redefine the surface hydraulic coductivity at saturation for
!     convective precipitation parametrisation.
!     
!!**  METHOD
!!    ------
!
!     Direct calculation
!
!!    EXTERNAL
!!    --------
!
!     None
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme     
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    17/11/03 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_par,ONLY : xundef
USE modd_sgh_par, ONLY : x2                                
USE modd_csts,    ONLY : xday
#ifdef TOPD
USE modd_dummy_exp_profile,ONLY : xc_depth_ratio
#endif
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=*)                  :: hisba   ! hydrology/soil:
!                                            ! '2-L'  = single column
!                                            ! '3-L'  = root zone/baseflow layer
!                                            ! 'DIF'  = N-layer diffusion: Richard's Eq.
!
REAL, DIMENSION(:), INTENT(IN)    :: pf
!                                    PF = exponential decay factor (1/m)
!
REAL, DIMENSION(:), INTENT(INOUT) :: pc2ref,pc1sat
!                                    PC1SAT  = C1 at saturation
!                                    PC2REF  = reference value of C2
!
REAL, DIMENSION(:,:),INTENT(INOUT):: pcondsat
!                                    PCONDSAT  = hydraulic conductivity at saturation (m s-1)
!
REAL, DIMENSION(:,:), INTENT(IN)  :: pd_g 
!                                    PD_G   = Depth of bottom of Soil layers (m)
!
REAL, DIMENSION(:), INTENT(IN)    :: pd_ice 
!                                    PD_ICE = depth of the soil column for
!                                             fraction of frozen soil calculation (m)

REAL, DIMENSION(:,:),INTENT(INOUT):: pc3
!                                    PC3 = C3 coef with exponential decay of hydraulic soil profil 
!
REAL, DIMENSION(:), INTENT(INOUT) :: pc4ref
!                                    PC4REF = fiiting soil paramater for vertical diffusion (C4)
!                                             with exponential decay of hydraulic soil profil 
!
REAL, DIMENSION(:), INTENT(OUT)   :: pksat_ice
!                                    PKSAT_ICE = hydraulic conductivity at saturation (m s-1)
!                                                on frozen soil depth (Horton calculation)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PF))         :: zd_g_tot, zc_depth, zksat_noexp, zc_depth_ratio
!                                    ZD_G_TOT = depth of the soil column (m)
!                                    ZC_DEPTH = assumed as the depth where the vertical 
!                                               satured hydraulic conductivities reach
!                                               the compacted value given in Clapp and
!                                               Hornberger. (m)
!                                               For ISBA-FR, we take the root depth.
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('EXP_DECAY_SOIL_FR',0,zhook_handle)
!
zd_g_tot(:) = pd_g(:,2)
IF(hisba=='3-L')zd_g_tot(:) = pd_g(:,3)
!
zksat_noexp(:) = pcondsat(:,2)
!
zc_depth_ratio(:) = 1.
!
#ifdef TOPD
IF (ALLOCATED(xc_depth_ratio)) zc_depth_ratio(:) = xc_depth_ratio(:)
#endif
!
WHERE(zd_g_tot(:)/=xundef)
!
!compacted depth
!
zc_depth(:) = pd_g(:,2)*zc_depth_ratio(:)
!ZC_DEPTH(:) = PD_G(:,2)
!
!surface hydraulic conductivity at saturation
!
pcondsat(:,1) = pcondsat(:,1)*exp(pf(:)*zc_depth(:))
!
!mean hydraulic conductivity at saturation over the root zone
!   
pcondsat(:,2) = zksat_noexp(:)*( exp(pf(:)*zc_depth)-exp(pf(:)*(zc_depth(:)-pd_g(:,2))) )   &
                  /(pf(:)*pd_g(:,2))
!   
!mean hydraulic conductivity at saturation over the first soil centimeters
!   
pksat_ice(:) = zksat_noexp(:)*( exp(pf(:)*zc_depth)-exp(pf(:)*(zc_depth(:)-pd_ice(:))) )   &
                 /(pf(:)*pd_ice(:))  
!
!decay factor for C1 coef
!   
pc1sat(:) = pc1sat(:)*sqrt( exp(-pf(:)*zc_depth(:)) )
!
!decay factor for C2 coef 
!
pc2ref(:)=pc2ref(:)+( pcondsat(:,2)-zksat_noexp(:) ) * xday/pd_g(:,2) 
!
!C3 coef with exponential decay in root soil layer 
!
pc3(:,1)=pc3(:,1)*( exp(pf(:)*zc_depth(:))-exp(pf(:)*(zc_depth(:)-pd_g(:,2))) ) / (pf(:)*pd_g(:,2))
!
ENDWHERE
!
IF(hisba=='3-L')THEN
! 
   WHERE(pd_g(:,2)< zd_g_tot(:).AND.pd_g(:,2)/=xundef)
!           
!  C3 coef with exponential decay in deep soil layer 
!
   pc3(:,2)=pc3(:,2)*( exp(pf(:)*(zc_depth(:)-pd_g(:,2)))-exp(pf(:)*(zc_depth(:)-zd_g_tot(:))) )      &
                       / (pf(:)*(zd_g_tot(:)-pd_g(:,2)))  
! 
!  decay factor for C4 coef
!      
   pc4ref(:)=pc4ref(:)*( exp(pf(:)*(zc_depth(:)-pd_g(:,2)/x2))-exp(pf(:)*(zc_depth(:)&
                         -((pd_g(:,2)+zd_g_tot(:))/2.))) ) * x2/(pf(:)*zd_g_tot(:))        
!
   ENDWHERE
!
ENDIF
!
IF (lhook) CALL dr_hook('EXP_DECAY_SOIL_FR',1,zhook_handle)
!
END SUBROUTINE exp_decay_soil_fr