init_isban.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#############################################################
SUBROUTINE init_isba_n (DTCO, DGU, UG, U, IM, DTZ, DST, SLT, SV, &
                            hprogram,hinit,oland_use,                    &
                             ki,ksv,ksw,                                &
                             hsv,pco2,prhoa,                            &
                             pzenith,pazim,psw_bands,pdir_alb,psca_alb, &
                             pemis,ptsrad, ptsurf,                      &
                             kyear, kmonth,kday, ptime,                 &
                             hatmfile,hatmfiletype,                     &
                             htest                                      )  
!#############################################################
!
!!****  *INIT_ISBA_n* - routine to initialize ISBA
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      Modified by P. Le Moigne (11/2004): miscellaneous diagnostics
!!      Modified by P. Le Moigne (06/2006): seeding and irrigation    
!!      Modified by B. Decharme    (2008) : SGH and Flooding scheme
!!      Modified by B. Decharme  (01/2009): optional deep soil temperature as in Arpege
!!      Modified by R. Hamdi     (01/2009): Cp and L
!!      Modified by B. Decharme  (06/2009): read topographic index statistics
!!      Modified by P. Le Moigne (01/2009): Beljaars sso
!!      Modified by B. Decharme  (08/2009): Active Trip coupling variable if Earth System Model
!!      A.L. Gibelin   04/09 : change BSLAI_NITRO initialisation
!!      A.L. Gibelin   04/09 : modifications for CENTURY model 
!!      A.L. Gibelin   06/09 : soil carbon initialisation
!!      B. Decharme    07/11 : read pgd+prep
!!      R. Alkama      05/12 : new carbon spinup
!!      J.Escobar      11/13 : add USE MODI_DEFAULT_CROCUS
!!      B. Decharme  04/2013 new coupling variables
!!      P. Samuelsson  10/14 : MEB
!!
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surfex_n, ONLY : isba_model_t
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_data_tsz0_n, ONLY : data_tsz0_t
USE modd_dst_n, ONLY : dst_t
USE modd_slt_n, ONLY : slt_t
USE modd_sv_n, ONLY : sv_t
!
!
USE modd_data_cover,     ONLY : xdata_lai, xdata_h_tree,                          &
                                xdata_albnir_veg, xdata_albvis_veg,               &
                                xdata_albuv_veg, xdata_rsmin,                     &
                                xdata_root_extinction,xdata_root_lin,             &
                                xdata_rgl, xdata_cv, xdata_gamma, xdata_gmes,     &
                                xdata_gc, xdata_bslai, xdata_sefold, xdata_laimin,&
                                xdata_dmax, xdata_stress, xdata_f2i,              &
                                xdata_veg, xdata_green, xdata_z0, xdata_z0_o_z0h, &
                                xdata_emis_eco, xdata_wrmax_cf,                   &
                                xdata_ce_nitro,xdata_cf_nitro,xdata_cna_nitro,    &
                                xdata_soilrc_so2, xdata_soilrc_o3, xdata_re25,    &
                                xdata_gmes_st, xdata_bslai_st, xdata_sefold_st,   &
                                xdata_gc_st, xdata_dmax_st
!
USE modd_surf_atm,       ONLY : lcpl_gcm
!
USE modd_surf_par,       ONLY : xundef, nundef
USE modd_agri,           ONLY : lagrip
!
USE mode_tartes, ONLY : init_tartes
USE mode_snowcro_flanner, ONLY : read_fz06
!
USE modd_read_namelist,  ONLY : lnam_read
!
USE modd_co2v_par,  ONLY : xmco2, xspin_co2
USE modd_csts,      ONLY : xmd
!
USE modi_init_io_surf_n
!
USE modi_get_luout
USE modi_abor1_sfx
USE modi_default_isba
USE modi_default_ch_dep
USE modi_default_ch_bio_flux
USE modi_default_diag_isba
USE modi_default_crocus
USE modi_read_default_isba_n
USE modi_read_isba_conf_n
USE modi_read_prep_isba_snow
USE modi_read_prep_isba_carbon
USE modi_read_surf
USE modi_prep_ctrl_isba
USE modi_read_isba_date
USE modi_read_pgd_isba_n
USE modi_compute_isba_parameters
USE modi_read_nam_prep_isba_n
USE modi_ini_data_param
!
USE modi_set_surfex_filein
!
USE modi_end_io_surf_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(isba_model_t), INTENT(INOUT) :: im
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(data_tsz0_t), INTENT(INOUT) :: dtz
TYPE(dst_t), INTENT(INOUT) :: dst
TYPE(slt_t), INTENT(INOUT) :: slt
TYPE(sv_t), INTENT(INOUT) :: sv
!
 CHARACTER(LEN=6),                 INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=3),                 INTENT(IN)  :: hinit     ! choice of fields to initialize
LOGICAL,                          INTENT(IN)  :: oland_use !
INTEGER,                          INTENT(IN)  :: ki        ! number of points
INTEGER,                          INTENT(IN)  :: ksv       ! number of scalars
INTEGER,                          INTENT(IN)  :: ksw       ! number of short-wave spectral bands
 CHARACTER(LEN=6), DIMENSION(KSV), INTENT(IN)  :: hsv       ! name of all scalar variables
REAL,             DIMENSION(KI),  INTENT(IN)  :: pco2      ! CO2 concentration (kg/m3)
REAL,             DIMENSION(KI),  INTENT(IN)  :: prhoa     ! air density
REAL,             DIMENSION(KI),  INTENT(IN)  :: pzenith   ! solar zenithal angle
REAL,             DIMENSION(KI),  INTENT(IN)  :: pazim     ! solar azimuthal angle (rad from N, clock)
REAL,             DIMENSION(KSW), INTENT(IN)  :: psw_bands ! middle wavelength of each band
REAL,             DIMENSION(KI,KSW),INTENT(OUT) :: pdir_alb  ! direct albedo for each band
REAL,             DIMENSION(KI,KSW),INTENT(OUT) :: psca_alb  ! diffuse albedo for each band
REAL,             DIMENSION(KI),  INTENT(OUT) :: pemis     ! emissivity
REAL,             DIMENSION(KI),  INTENT(OUT) :: ptsrad    ! radiative temperature
REAL,             DIMENSION(KI),  INTENT(OUT) :: ptsurf    ! surface effective temperature         (K)
!
INTEGER,                          INTENT(IN)  :: kyear     ! current year (UTC)
INTEGER,                          INTENT(IN)  :: kmonth    ! current month (UTC)
INTEGER,                          INTENT(IN)  :: kday      ! current day (UTC)
REAL,                             INTENT(IN)  :: ptime     ! current time since
                                                          !  midnight (UTC, s)
!
 CHARACTER(LEN=28),                INTENT(IN)  :: hatmfile    ! atmospheric file name
 CHARACTER(LEN=6),                 INTENT(IN)  :: hatmfiletype! atmospheric file type
 CHARACTER(LEN=2),                 INTENT(IN)  :: htest       ! must be equal to 'OK'
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI) :: zco2     ! CO2 concentration  (kg/m3)
REAL                :: zspinco2
INTEGER             :: ispinend
!
INTEGER             :: iluout   ! unit of output listing file
INTEGER             :: iversion       ! surface version
INTEGER             :: iresp   ! return code
INTEGER             :: isize_lmeb_patch   ! Number of patches where multi-energy balance should be applied
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!               Initialisation for IO
!
!
IF (lhook) CALL dr_hook('INIT_ISBA_N',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
IF (htest/='OK') THEN
  CALL abor1_sfx('INIT_ISBAN: FATAL ERROR DURING ARGUMENT TRANSFER')
END IF
!
!               Other little things
!
IF (lnam_read) THEN
 !
 !*       0.     Defaults
!               --------

 !        0.1. Hard defaults
 !      
 CALL default_isba(im%I%XTSTEP, im%I%XOUT_TSTEP,                           &
                     im%I%CROUGH,im%I%CRUNOFF,im%I%CALBEDO,im%I%CSCOND,              &
                     im%I%CC1DRY, im%I%CSOILFRZ, im%I%CDIFSFCOND, im%I%CSNOWRES,     &
                     im%I%CCPSURF, im%I%XCGMAX, im%I%XCDRAG, im%I%CKSAT, im%I%LSOC,       &
                     im%I%CRAIN, im%I%CHORT, im%I%LGLACIER, im%I%LCANOPY_DRAG,       &
                     im%I%LVEGUPD, im%I%LSPINUPCARBS, im%I%LSPINUPCARBW,        &
                     im%I%XSPINMAXS, im%I%XSPINMAXW, im%I%XCO2_START, im%I%XCO2_END, &
                     im%I%NNBYEARSPINS, im%I%NNBYEARSPINW, im%I%LNITRO_DILU     )
 !                  
 CALL default_ch_dep(im%CHI%CCH_DRY_DEP)
 CALL default_ch_bio_flux(im%CHI%LCH_BIO_FLUX)                  
 CALL default_diag_isba(im%DGI%N2M,im%DGI%LSURF_BUDGET,im%DGI%L2M_MIN_ZS,im%DGI%LRAD_BUDGET,   &
                        im%DGI%LCOEF,im%DGI%LSURF_VARS,im%DGEI%LSURF_EVAP_BUDGET,        &
                        im%DGMI%LSURF_MISC_BUDGET,im%DGMI%LSURF_DIAG_ALBEDO,       &
                        im%DGEI%LSURF_BUDGETC,im%DGMI%LSURF_MISC_DIF,im%DGI%LPATCH_BUDGET,&
                        im%DGI%LPGD,im%DGEI%LRESET_BUDGETC,im%DGEI%LWATER_BUDGET,         &
                        im%DGI%XDIAG_TSTEP                                )  
 !
 CALL default_crocus(im%I%LSNOWDRIFT,im%I%LSNOWDRIFT_SUBLIM,im%I%LSNOW_ABS_ZENITH,&
                     im%I%CSNOWMETAMO,im%I%CSNOWRAD)
 ! 
ENDIF
!
!        0.2. Defaults from file header
!    
 CALL read_default_isba_n(im%CHI, im%DGEI, im%DGI, im%DGMI, im%I, &
                          hprogram)
!
 CALL read_isba_conf_n(im%CHI, im%DGEI, im%DGI, im%DGMI, im%I, &
                       hprogram)
!
 CALL init_io_surf_n(dtco, dgu, u, &
                     hprogram,'FULL  ','ISBA  ','READ ')
 CALL read_surf(&
                hprogram,'VERSION',iversion,iresp)
 CALL end_io_surf_n(hprogram)
!
!*       1.     Reading of configuration:
!               -------------------------
!
!* initialization of snow and carbon schemes
!
im%I%NNBYEARSOLD = 1
im%I%NSPINS      = 1
im%I%NSPINW      = 1
!
IF (hinit=='PRE') THEN 
  CALL read_prep_isba_snow(hprogram,im%I%TSNOW%SCHEME,im%I%TSNOW%NLAYER) 
!
!* initialization of soil carbon scheme
!
  CALL read_prep_isba_carbon(hprogram,im%I%CRESPSL)
!
  IF (im%I%CRESPSL=='CNT') THEN
    im%I%NNLITTER = 2
    im%I%NNLITTLEVS = 2
    im%I%NNSOILCARB = 3
  ELSE
    im%I%NNLITTER = 0
    im%I%NNLITTLEVS = 0
    im%I%NNSOILCARB = 0
  ENDIF

ELSEIF (hinit=='ALL') THEN
!
 CALL init_io_surf_n(dtco, dgu, u, &
                     hprogram,'NATURE','ISBA  ','READ ')
!
  IF (iversion<6) THEN
    im%I%CRESPSL='DEF'
  ELSE  
    CALL read_surf(&
                hprogram,'RESPSL',im%I%CRESPSL,iresp)
    CALL read_surf(&
                hprogram,'NLITTER',im%I%NNLITTER,iresp)
    CALL read_surf(&
                hprogram,'NLITTLEVS',im%I%NNLITTLEVS,iresp)
    CALL read_surf(&
                hprogram,'NSOILCARB',im%I%NNSOILCARB,iresp)
    IF(iversion>=7.AND.(im%I%LSPINUPCARBS.OR.im%I%LSPINUPCARBW))THEN
      CALL read_surf(&
                hprogram,'NBYEARSOLD',im%I%NNBYEARSOLD,iresp)
    ELSE
      im%I%NNBYEARSOLD=nundef
    ENDIF
  ENDIF
!
  CALL end_io_surf_n(hprogram)
!
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       2.     Physiographic fields
!               --------------------
!
!
!* date
!
SELECT CASE (hinit)
  CASE ('PGD')
    im%I%TTIME%TDATE%YEAR = nundef
    im%I%TTIME%TDATE%MONTH= nundef
    im%I%TTIME%TDATE%DAY  = nundef
    im%I%TTIME%TIME       = xundef

  CASE ('PRE')
    CALL prep_ctrl_isba(im%DGI%N2M,im%DGI%LSURF_BUDGET,im%DGI%L2M_MIN_ZS,im%DGI%LRAD_BUDGET,&
                        im%DGI%LCOEF,im%DGI%LSURF_VARS,&
                          im%DGEI%LSURF_EVAP_BUDGET,im%DGMI%LSURF_MISC_BUDGET,im%DGEI%LSURF_BUDGETC,     &
                          im%DGI%LPATCH_BUDGET,im%DGMI%LSURF_MISC_DIF,iluout                    )    
    IF (lnam_read) CALL read_nam_prep_isba_n(hprogram)                        
    CALL read_isba_date(&
                        hprogram,hinit,iluout,hatmfile,hatmfiletype,kyear,kmonth,kday,ptime,im%I%TTIME)

  CASE default
 CALL init_io_surf_n(dtco, dgu, u, &
                     hprogram,'NATURE','ISBA  ','READ ')
    CALL read_surf(&
                hprogram,'DTCUR',im%I%TTIME,iresp)
    CALL end_io_surf_n(hprogram)
END SELECT
!
!-----------------------------------------------------------------------------------------------------
! READ PGD FILE
!-----------------------------------------------------------------------------------------------------
!
! initialization for I/O
!
 CALL set_surfex_filein(hprogram,'PGD ') ! change input file name to pgd name
 CALL init_io_surf_n(dtco, dgu, u, &
                     hprogram,'NATURE','ISBA  ','READ ')
!
!
!*       2.1    Cover, soil and orographic fields:
!               ---------------------------------
!
 CALL read_pgd_isba_n(im%CHI, dtco, im%DTI, dtz, dgu, im%GB, im%IG, im%I, &
                      ug, u, sv, &
                      hprogram,oland_use)
!
isize_lmeb_patch=count(im%I%LMEB_PATCH(:))
!
!
!*       2.2    Check:
!               ------
!
IF ( im%I%CPHOTO/='NON' .AND. im%I%NPATCH/=12 .AND. im%I%NPATCH/=19 )THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CPHOTO AND NPATCH')
ENDIF
!
IF (hinit=='PRE' .AND. im%I%TSNOW%SCHEME.NE.'3-L' .AND. im%I%TSNOW%SCHEME.NE.'CRO' .AND. im%I%CISBA=='DIF') THEN
    CALL abor1_sfx("INIT_ISBAN: WITH CISBA = DIF, CSNOW MUST BE 3-L OR CRO")
ENDIF
IF ( im%I%CPHOTO/='LAI' .AND. im%I%CPHOTO/='LST' .AND. im%I%CPHOTO/='NIT' .AND. im%I%CPHOTO/='NCB' .AND. lagrip) THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CPHOTO AND LAGRIP')
ENDIF
IF ( im%I%CPHOTO/='NCB' .AND. im%I%CRESPSL=='CNT') THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CPHOTO AND CRESPSL')
ENDIF
IF (hinit=='PRE' .AND. isize_lmeb_patch>0 .AND. im%I%TSNOW%SCHEME.NE.'3-L' .AND. im%I%TSNOW%SCHEME.NE.'CRO') THEN
    CALL abor1_sfx("INIT_ISBAN: WITH LMEB_PATCH = TRUE, CSNOW MUST BE 3-L OR CRO")
ENDIF
IF(im%I%CPHOTO/='NCB'.AND.im%I%LSPINUPCARBW)THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CPHOTO AND LSPINUPCARBW (if not NCB must be false)')
ENDIF
IF(im%I%CRESPSL/='CNT'.AND.im%I%LSPINUPCARBS)THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CRESPSL AND LSPINUPCARBS (if not CNT must be false)')
ENDIF
IF(im%I%LSPINUPCARBW.AND.REAL(im%i%nnbyearspinw)>REAL(im%i%nnbyearspins)*0.5)then
  WRITE(iluout,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(iluout,*)'INIT_ISBAN: INCONSISTENCY BETWEEN NNBYEARSPINW AND NNBYEARSPINS'
  WRITE(iluout,*)'NNBYEARSPINW MUST BE < TO 0.5 * NNBYEARSPINS'
  WRITE(iluout,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN NNBYEARSPINW AND NNBYEARSPINS')
ENDIF
IF(im%I%LSPINUPCARBS.AND.(im%I%XCO2_START==xundef.OR.im%I%XCO2_END==xundef))THEN
  WRITE(iluout,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(iluout,*)'INIT_ISBAN: INCONSISTENCY BETWEEN LSPINUPCARBS AND XCO2_START OR XCO2_END'
  WRITE(iluout,*)'FOR ISBA-CC SPINUP XCO2_START AND XCO2_END MUST BE DEFINED'
  WRITE(iluout,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN LSPINUPCARBS AND XCO2_START OR XCO2_END')
ENDIF
!
 CALL end_io_surf_n(hprogram)
 CALL set_surfex_filein(hprogram,'PREP') ! restore input file name
!
!-------------------------------------------------------------------------------
!
! During soil carbon spinup with ISBA-CC: 
!        (1) grass parameters are attributed to all agricultural PFT with atmospheric CO2 concentration 
!            fixed to Pre-industrial CO2 consentration XCO2_START
!        (2) Atmospheric CO2 concentration rampin up from XCO2_START to XCO2_END
!
ispinend=im%I%NNBYEARSPINS-nint(im%I%NNBYEARSPINS*xspin_co2)
!
im%I%LAGRI_TO_GRASS = .false.
!
IF ( im%I%LSPINUPCARBS .AND. (im%I%NNBYEARSOLD <= ispinend) ) THEN
!
   im%I%LAGRI_TO_GRASS = .true.
!
   CALL ini_data_param(dtco%XDATA_VEGTYPE, psurf=dtco%XDATA_NATURE, ph_tree=xdata_h_tree,plai=xdata_lai,                   &
                                  palbnir_veg=xdata_albnir_veg, palbvis_veg=xdata_albvis_veg,                    &
                                  palbuv_veg=xdata_albuv_veg, prsmin=xdata_rsmin,                                &
                                  prgl=xdata_rgl, pcv=xdata_cv, pgamma=xdata_gamma,                              &
                                  pgmes=xdata_gmes, pgc=xdata_gc, pbslai=xdata_bslai,                            &
                                  psefold=xdata_sefold, plaimin_out=xdata_laimin, pdmax=xdata_dmax,              &
                                  pstress=xdata_stress, pf2i=xdata_f2i, pveg_out=xdata_veg,                      &
                                  pgreen=xdata_green, pz0=xdata_z0, pz0_o_z0h=xdata_z0_o_z0h,                    &
                                  pemis_eco=xdata_emis_eco, pwrmax_cf=xdata_wrmax_cf,                            &
                                  proot_lin=xdata_root_lin, proot_extinction=xdata_root_extinction,              &
                                  psoilrc_so2=xdata_soilrc_so2, psoilrc_o3=xdata_soilrc_o3, pre25=xdata_re25,    &
                                  pce_nitro=xdata_ce_nitro,pcf_nitro=xdata_cf_nitro,pcna_nitro=xdata_cna_nitro,  &
                                  pgmes_st=xdata_gmes_st, pgc_st=xdata_gc_st, pbslai_st=xdata_bslai_st,          &
                                  psefold_st=xdata_sefold_st, pdmax_st=xdata_dmax_st, oagri_to_grass=im%I%LAGRI_TO_GRASS)
!
   zco2(:) = prhoa(:) * im%I%XCO2_START * 1.e-6 * xmco2 / xmd
!
ELSEIF(im%I%LSPINUPCARBS .AND. (im%I%NNBYEARSOLD > ispinend) .AND. (im%I%NNBYEARSOLD <= im%I%NNBYEARSPINS) )THEN
!
   zspinco2 = im%I%XCO2_START + (im%I%XCO2_END-im%I%XCO2_START) * REAL(IM%I%NNBYEARSOLD - ISPINEND) / &
                REAL(im%i%nnbyearspins - ispinend)
!
   zco2(:) = prhoa(:) * zspinco2 * 1.e-6 * xmco2 / xmd
!
ELSE
!
   zco2(:) = pco2(:)
!
ENDIF
!
!-----------------------------------------------------------------------------------------------------
! END READ PGD FILE
!-----------------------------------------------------------------------------------------------------
!
!-----------------------------------------------------------------------------------------------------
! Make sure some diags are conputed when coupled with atmosphere
!-----------------------------------------------------------------------------------------------------
!
IF(lcpl_gcm.AND.im%DGI%LSURF_BUDGET)THEN
  im%DGEI%LSURF_EVAP_BUDGET=.true.
ENDIF
!
!-----------------------------------------------------------------------------------------------------
!
IF (oland_use .OR. hinit=='PGD') THEN
  IF (lhook) CALL dr_hook('INIT_ISBA_N',1,zhook_handle)
  RETURN
END IF
!
 CALL compute_isba_parameters(dtco, dgu, ug, u, im, dst, slt, sv, &
                             hprogram,hinit,oland_use,                  &
                             ki,ksv,ksw,                                &
                             hsv,zco2,prhoa,                            &
                             pzenith,psw_bands,pdir_alb,psca_alb,       &
                             pemis,ptsrad,ptsurf,                       &
                             htest                                )
!
IF ( im%I%CSNOWMETAMO/="B92" ) THEN
  CALL read_fz06('drdt_bst_fit_60.nc')
ENDIF
!
IF ( im%I%CSNOWRAD=="TAR" .OR. im%I%CSNOWRAD=="TA1" .OR.  im%I%CSNOWRAD=="TA2" ) THEN
  CALL init_tartes()
END IF
!
IF (lhook) CALL dr_hook('INIT_ISBA_N',1,zhook_handle)
!
END SUBROUTINE init_isba_n