mode_snowcro_flanner.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
MODULE mode_snowcro_flanner

!!****  SNOWCRO_FLANNER - read "drdt_bst_fit_60.nc" file, which containes parameters from Flanner and Zender, 2006
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     C. Carmagnola
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2013
!
USE modd_surfex_omp, ONLY : nblock
USE modd_surfex_mpi, ONLY : nrank, npio, nproc, ncomm
!
USE modi_abor1_sfx

USE mode_read_cdf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
!
#ifdef AIX64
!$ USE OMP_LIB
#endif
!
IMPLICIT NONE
!
include 'netcdf.inc'
!
#ifdef SFX_MPI
include 'mpif.h'
#endif
!
#ifndef AIX64
!$ INCLUDE 'omp_lib.h'
#endif
!
 CONTAINS
!
!------------------------------------------------------------------
!
SUBROUTINE read_fz06(HFILE)
!
USE modd_snow_metamo, ONLY : nid_file, xdrdt0, xtau, xkappa
!
IMPLICIT NONE
!
!*      1.    declarations of arguments
!
 CHARACTER(LEN=18),  INTENT(IN)  :: hfile     ! name of file
 CHARACTER(LEN=5),DIMENSION(3),PARAMETER :: hvarname=(/'drdt0','tau  ','kappa'/)
!
!*      2.    declarations of local variables
!
INTEGER :: infompi
INTEGER :: ierror !error status
!
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('SNOWCRO_FLANNER',0,zhook_handle)
!
!*      3.     Reading of field
!
! Open netcdf file
!
IF (nrank==npio) THEN
!$OMP SINGLE
  ierror = nf_open(hfile,nf_nowrite,nid_file)
  CALL handle_err_cdf(ierror,"can't open file "//trim(hfile))
!$OMP END SINGLE
ENDIF
!
IF (nproc>1) THEN
#ifdef SFX_MPI
!$OMP SINGLE
  CALL mpi_bcast(nid_file,kind(nid_file)/4,mpi_integer,npio,ncomm,infompi)
!$OMP END SINGLE
#endif
ENDIF
!
 CALL read_var_fz06(nid_file,hvarname(1),xdrdt0)
 CALL read_var_fz06(nid_file,hvarname(2),xtau)
 CALL read_var_fz06(nid_file,hvarname(3),xkappa)
!
IF (nrank==npio) THEN
!$OMP SINGLE
  ! Close netcdf file
  ierror=nf_close(nid_file)
!$OMP END SINGLE
ENDIF
!
IF (lhook) CALL dr_hook('SNOWCRO_FLANNER',1,zhook_handle)
!
END SUBROUTINE read_fz06
!------------------------------------------------------------------
SUBROUTINE read_var_fz06(ID_FILE,HSURF,PVAR)
!
USE modd_snow_metamo, ONLY : nvardims, nlendim1, nlendim2, &
                             nlendim3, nid_var
!
IMPLICIT NONE
!
INTEGER,INTENT(IN) :: id_file
 CHARACTER(LEN=5),INTENT(IN) :: hsurf
REAL, DIMENSION(:,:,:), POINTER :: pvar
!
INTEGER :: infompi
INTEGER, DIMENSION(:), ALLOCATABLE :: ivardimsid
!
INTEGER :: ierror !error status
!
IF (nrank==npio) THEN
!$OMP SINGLE
  ! Look for variable ID
  ierror = nf_inq_varid(id_file,trim(hsurf),nid_var)
  CALL handle_err_cdf(ierror,"can't find variable "//trim(hsurf))
  !
  ! Number of dimensions
  ierror = nf_inq_varndims(id_file,nid_var,nvardims)
  IF ( ierror/=nf_noerr ) CALL handle_err_cdf(ierror,"can't get variable dimensions number")
  !
  ! Id of dimensions
  ALLOCATE(ivardimsid(nvardims))
  ierror = nf_inq_vardimid(id_file,nid_var,ivardimsid)
  IF ( ierror/=nf_noerr ) CALL handle_err_cdf(ierror,"can't get variable dimensions ids")
  !
  SELECT CASE (nvardims)
    !
    CASE (3)
      ierror = nf_inq_dimlen(id_file,ivardimsid(1),nlendim1)
      IF ( ierror/=nf_noerr ) CALL handle_err_cdf(ierror,"can't get variable dimensions lengths")
      ierror = nf_inq_dimlen(id_file,ivardimsid(2),nlendim2)
      IF ( ierror/=nf_noerr ) CALL handle_err_cdf(ierror,"can't get variable dimensions lengths")
      ierror = nf_inq_dimlen(id_file,ivardimsid(3),nlendim3)
      IF ( ierror/=nf_noerr ) CALL handle_err_cdf(ierror,"can't get variable dimensions lengths")
      !
    CASE default
      CALL abor1_sfx('SNOWCRO_FLANNER: incorrect number of dimensions for variable '//trim(hsurf))
    !
  END SELECT
!$OMP END SINGLE
ENDIF
!
IF (nproc>1) THEN
#ifdef SFX_MPI
!$OMP SINGLE
  CALL mpi_bcast(nlendim1,kind(nlendim1)/4,mpi_integer,npio,ncomm,infompi)
  CALL mpi_bcast(nlendim2,kind(nlendim2)/4,mpi_integer,npio,ncomm,infompi)
  CALL mpi_bcast(nlendim3,kind(nlendim3)/4,mpi_integer,npio,ncomm,infompi)
!$OMP END SINGLE
#endif
ENDIF
!
!$OMP SINGLE
ALLOCATE(pvar(nlendim1,nlendim2,nlendim3))
!$OMP END SINGLE
!
IF (nrank==npio) THEN
!$OMP SINGLE
  ! Read 3D variable
  ierror = nf_get_var_double(id_file,nid_var,pvar)
  CALL handle_err_cdf(ierror,"can't read variable "//trim(hsurf))
!$OMP END SINGLE
ENDIF
!
IF (nproc>1) THEN
#ifdef SFX_MPI
!$OMP SINGLE
  CALL mpi_bcast(pvar,kind(pvar)*SIZE(pvar)/4,mpi_real,npio,ncomm,infompi)
!$OMP END SINGLE
#endif
ENDIF
!
END SUBROUTINE read_var_fz06
!------------------------------------------------------------------
END MODULE mode_snowcro_flanner