get_mesh_dim_lonlat_rot.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_mesh_dim_lonlat_rot(KGRID_PAR,KL,PGRID_PAR,PDX,PDY)
!     ##############################################################
!
!!**** *GET_MESH_DIM_LONLAT_ROT* get the grid mesh dimensions
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    P. Samuelsson  SMHI
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/2012
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_csts, ONLY : xpi, xradius
!
USE mode_gridtype_lonlat_rot
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: kgrid_par ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: kl        ! number of points
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: pgrid_par ! grid parameters
REAL,    DIMENSION(KL),          INTENT(OUT)   :: pdx       ! dimension in x dir. (meters)
REAL,    DIMENSION(KL),          INTENT(OUT)   :: pdy       ! dimension in y dir. (meters)
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(KL) :: zlat     ! rotated latitude
REAL    :: zwest   ! West longitude in rotated grid (degrees)
REAL    :: zsouth  ! South latitude in rotated grid  (degrees)
REAL    :: zdlon   ! Longitudal grid spacing  (degrees)
REAL    :: zdlat   ! Latitudal grid spacing  (degrees)
REAL    :: zpolon  ! Longitude of rotated pole (degrees)
REAL    :: zpolat  ! Latitude of rotated pole  (degrees)
INTEGER :: ilon    ! number of points in longitude
INTEGER :: ilat    ! number of points in latitude
INTEGER :: jlon, jlat, jl
REAL(KIND=JPRB) :: zhook_handle

!----------------------------------------------------------------------------
!
!*       1.    Get grid information
!              --------------------
!
IF (lhook) CALL dr_hook('GET_MESH_DIM_LONLAT_ROT',0,zhook_handle)
!
 CALL get_gridtype_lonlat_rot(pgrid_par,                                 &
                               zwest,zsouth,zdlon,zdlat,zpolon,zpolat,  &
                               ilon,ilat                                )  
!
!-----------------------------------------------------------------------------
!
!*       2.    Compute grid size
!              -----------------
!
DO jlat=1,ilat
  DO jlon=1,ilon
    jl = jlon + ilon * (jlat-1)
    zlat(jl) = zsouth + zdlat * (jlat-1)
  END DO
END DO
!
pdx(:) = zdlon * (xpi / 180.) * xradius * cos(zlat(:)*xpi/180.)
pdy(:) = zdlat * (xpi / 180.) * xradius
IF (lhook) CALL dr_hook('GET_MESH_DIM_LONLAT_ROT',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_mesh_dim_lonlat_rot