mode_gridtype_lonlat_rot.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##############################
      MODULE mode_gridtype_lonlat_rot
!     ##############################
!
!############################################################################
!############################################################################
!############################################################################
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
 CONTAINS
!############################################################################
!############################################################################
!############################################################################
!     ####################################################################
      SUBROUTINE put_gridtype_lonlat_rot(PGRID_PAR,                                 &
                                           pwest,psouth,pdlon,pdlat,ppolon,ppolat,  &
                                           klon,klat,kl,plon,plat                   )  
!     ####################################################################
!
!!****  *PUT_GRIDTYPE_LONLAT_ROT* - routine to store in PGRID_PAR the horizontal grid
!!
!!    AUTHOR
!!    ------
!!      P. Samuelsson   SMHI
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/2012 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
IMPLICIT NONE
!
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL,               INTENT(IN)  :: pwest   ! West longitude in rotated grid (degrees)
REAL,               INTENT(IN)  :: psouth  ! South latitude in rotated grid  (degrees)
REAL,               INTENT(IN)  :: pdlon   ! Longitudal grid spacing  (degrees)
REAL,               INTENT(IN)  :: pdlat   ! Latitudal grid spacing  (degrees)
REAL,               INTENT(IN)  :: ppolon  ! Longitude of rotated pole (degrees)
REAL,               INTENT(IN)  :: ppolat  ! Latitude of rotated pole  (degrees)
INTEGER,            INTENT(IN)  :: klon     ! number of points in longitude
INTEGER,            INTENT(IN)  :: klat     ! number of points in latitude
INTEGER,            INTENT(IN)  :: kl       ! number of points used
REAL, DIMENSION(:), INTENT(IN)  :: plon     ! regular longitudes of all points 
REAL, DIMENSION(:), INTENT(IN)  :: plat     ! regular latitudes  of all points
REAL,   DIMENSION(:),POINTER    :: pgrid_par! parameters defining this grid
REAL(KIND=JPRB) :: zhook_handle
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_ROT:PUT_GRIDTYPE_LONLAT_ROT',0,zhook_handle)
ALLOCATE(pgrid_par(9+2*kl))
pgrid_par(1) = pwest
pgrid_par(2) = psouth
pgrid_par(3) = pdlon
pgrid_par(4) = pdlat
pgrid_par(5) = ppolon
pgrid_par(6) = ppolat
pgrid_par(7) = float(klon)
pgrid_par(8) = float(klat)
pgrid_par(9) = float(kl)
pgrid_par(10:9+kl)      = plon(:)
pgrid_par(10+kl:9+2*kl) = plat(:)
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_ROT:PUT_GRIDTYPE_LONLAT_ROT',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE put_gridtype_lonlat_rot
!############################################################################
!############################################################################
!############################################################################
!     ####################################################################
      SUBROUTINE get_gridtype_lonlat_rot(PGRID_PAR,                                 &
                                           pwest,psouth,pdlon,pdlat,ppolon,ppolat,  &
                                           klon,klat,kl,plon,plat                   )  
!     ####################################################################
!
!!****  *GET_GRIDTYPE_LONLAT_ROT* - routine to get from PGRID_PAR the horizontal grid
!!
!!    AUTHOR
!!    ------
!!      P. Samuelsson   SMHI
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/2012 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
IMPLICIT NONE
!
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL, DIMENSION(:), INTENT(IN)            :: pgrid_par! parameters defining this grid
REAL,               INTENT(OUT), OPTIONAL :: pwest    ! West longitude in rotated grid (degrees)
REAL,               INTENT(OUT), OPTIONAL :: psouth   ! South latitude in rotated grid  (degrees)
REAL,               INTENT(OUT), OPTIONAL :: pdlon    ! Longitudal grid spacing  (degrees)
REAL,               INTENT(OUT), OPTIONAL :: pdlat    ! Latitudal grid spacing  (degrees)
REAL,               INTENT(OUT), OPTIONAL :: ppolon   ! Longitude of rotated pole (degrees)
REAL,               INTENT(OUT), OPTIONAL :: ppolat   ! Latitude of rotated pole  (degrees)
INTEGER,            INTENT(OUT), OPTIONAL :: klon     ! number of points in longitude
INTEGER,            INTENT(OUT), OPTIONAL :: klat     ! number of points in latitude
INTEGER,            INTENT(OUT), OPTIONAL :: kl       ! number of points used
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: plon     ! longitudes of all points
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: plat     ! latitudes  of all points
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: ilon, ilat
INTEGER :: il
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_ROT:GET_GRIDTYPE_LONLAT_ROT',0,zhook_handle)
ilon = nint(pgrid_par(7))
ilat = nint(pgrid_par(8))
il   = nint(pgrid_par(9))
!
IF (present(pwest   )) pwest   = pgrid_par(1)
IF (present(psouth  )) psouth  = pgrid_par(2)
IF (present(pdlon   )) pdlon   = pgrid_par(3)
IF (present(pdlat   )) pdlat   = pgrid_par(4)
IF (present(ppolon  )) ppolon  = pgrid_par(5)
IF (present(ppolat  )) ppolat  = pgrid_par(6)
IF (present(klon    )) klon    = ilon
IF (present(klat    )) klat    = ilat
IF (present(kl      )) kl      = il
IF (present(plon    )) plon(:) = pgrid_par(10:9+il)
IF (present(plat    )) plat(:) = pgrid_par(10+il:9+2*il)
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_ROT:GET_GRIDTYPE_LONLAT_ROT',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE get_gridtype_lonlat_rot
!---------------------------------------------------------------------------------
!
!      ###################################################
       SUBROUTINE latlon_lonlat_rot(PWEST,PSOUTH,PDLON,PDLAT,PPOLON,PPOLAT, &
                                      klon,klat,plon,plat                   )  
!      ###################################################
!
!!****  *LATLON_LONLAT_ROT * - Routine to compute regular geographical coordinates
!!
!!     PURPOSE
!!     -------
!!       
!!     AUTHOR
!!     ------
!!      P. Samuelsson   SMHI
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/2012 
!-------------------------------------------------------------------------------
!
!*     0.     DECLARATIONS
!             ------------
!
!RJ: missing modi
USE modi_regrot_lonlat_rot
!
IMPLICIT NONE
!
!*     0.1    Declarations of arguments and results
!
REAL,               INTENT(IN)  :: pwest    ! West longitude in rotated grid (degrees)
REAL,               INTENT(IN)  :: psouth   ! South latitude in rotated grid  (degrees)
REAL,               INTENT(IN)  :: pdlon    ! Longitudal grid spacing  (degrees)
REAL,               INTENT(IN)  :: pdlat    ! Latitudal grid spacing  (degrees)
REAL,               INTENT(IN)  :: ppolon   ! Longitude of rotated south pole (degrees)
REAL,               INTENT(IN)  :: ppolat   ! Latitude of rotated south pole  (degrees)
INTEGER,            INTENT(IN)  :: klon     ! number of points in longitude
INTEGER,            INTENT(IN)  :: klat     ! number of points in latitude
REAL, DIMENSION(:), INTENT(OUT) :: plon,plat    
                                            ! returned geographic latitudes and 
                                            ! longitudes of the processed points 
                                            ! (degrees).
!
!*     0.2    Declarations of local variables
! 
INTEGER :: jlon, jlat
INTEGER :: jl, kl
INTEGER :: jc

REAL, DIMENSION(:), ALLOCATABLE :: zlatrot ! rotated latitude  of all points
REAL, DIMENSION(:), ALLOCATABLE :: zlonrot ! rotated longitude of all points


REAL(KIND=JPRB) :: zhook_handle
!--------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_ROT:LATLON_LONLAT_ROT',0,zhook_handle)

kl = klon * klat

ALLOCATE(zlatrot(kl))
ALLOCATE(zlonrot(kl))

!
DO jlat=1,klat
  DO jlon=1,klon
    jl = jlon + klon * (jlat-1)
    zlatrot(jl) = psouth + pdlat * (jlat-1)
    zlonrot(jl) = pwest  + pdlon * (jlon-1)
  END DO
END DO

 CALL regrot_lonlat_rot(plon,plat,zlonrot,zlatrot,   &
                             kl,1,kl,1,             &
                             ppolon,ppolat,-1       )  

WHERE (plon(:)>180.) plon(:)=plon(:)-360.
WHERE (plon(:)<-180.) plon(:)=plon(:)+360.

IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_ROT:LATLON_LONLAT_ROT',1,zhook_handle)
!---------------------------------------------------------------------------------
END SUBROUTINE latlon_lonlat_rot
!---------------------------------------------------------------------------------
!
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!
END MODULE mode_gridtype_lonlat_rot