get_mesh_corner_lonlat_reg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################
      SUBROUTINE get_mesh_corner_lonlat_reg(KGRID_PAR,KL,KC,PGRID_PAR,PCORNER_LAT,PCORNER_LON)
!     ###############################################################
!
!!**** *GET_MESH_CORNER_LONLAT_REG* get the grid mesh where point (lat,lon) is located
!!
!!    PURPOSE
!!    -------
!!
!!    AUTHOR
!!    ------
!!
!!    B. Decharme         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/2013
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_lonlat_reg
!
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                       INTENT(IN)    :: kgrid_par ! size of PGRID_PAR
INTEGER,                       INTENT(IN)    :: kl        ! number of points
INTEGER,                       INTENT(IN)    :: kc        ! number of grid point corner
REAL,    DIMENSION(KGRID_PAR), INTENT(IN)    :: pgrid_par ! grid parameters
REAL,    DIMENSION(KL,KC),     INTENT(OUT)   :: pcorner_lat ! Grid corner Latitude
REAL,    DIMENSION(KL,KC),     INTENT(OUT)   :: pcorner_lon ! Grid corner Longitude
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER             :: ilat    ! Number of lattitude
INTEGER             :: ilon    ! Number of longitude
INTEGER             :: ini     ! Number of point
REAL                :: zlonmin ! minimum longitude (degrees)
REAL                :: zlonmax ! maximum longitude (degrees)
REAL                :: zlatmin ! minimum latitude  (degrees)
REAL                :: zlatmax ! maximum latitude  (degrees)
REAL                :: zdlon   ! longitude grid size
REAL                :: zdlat   ! latitude  grid size
REAL, DIMENSION(KL) :: zlon    ! longitude grid
REAL, DIMENSION(KL) :: zlat    ! latitude  grid
!
REAL(KIND=JPRB) :: zhook_handle
!
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_MESH_CORNER_LONLAT_REG',0,zhook_handle)
!
!*    1.     Uncode parameters of the grid
!            -----------------------------
!
 CALL get_gridtype_lonlat_reg(pgrid_par,zlonmin,zlonmax,zlatmin,zlatmax,ilon,ilat,ini)  
!  
IF(kl/=ini)THEN
  CALL abor1_sfx('GET_MESH_CORNER_LONLAT_REG: WRONG NUMBER OF POINT')
ENDIF
!
 CALL get_gridtype_lonlat_reg(pgrid_par,plon=zlon,plat=zlat)
!
zdlon = (zlonmax-zlonmin) / float(ilon)
zdlat = (zlatmax-zlatmin) / float(ilat)
!
!
!*    2.     grid cell corner (counterclockwise sense)
!            -----------------------------------------
!
!       4_______3
!       |       |
!       |   .   |
!       |       |
!       |_______|
!       1       2
!
!
pcorner_lon(:,1) = zlon(:)-zdlon/2.
pcorner_lat(:,1) = zlat(:)-zdlat/2.
!
pcorner_lon(:,3) = zlon(:)+zdlon/2.
pcorner_lat(:,3) = zlat(:)+zdlat/2.
!
pcorner_lon(:,2) = pcorner_lon(:,3)
pcorner_lat(:,2) = pcorner_lat(:,1)
!
pcorner_lon(:,4) = pcorner_lon(:,1)
pcorner_lat(:,4) = pcorner_lat(:,3)
!
IF (lhook) CALL dr_hook('GET_MESH_CORNER_LONLAT_REG',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_mesh_corner_lonlat_reg