get_adj_mes_lonlat_reg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_adj_mes_lonlat_reg(KGRID_PAR,KL,PGRID_PAR,KLEFT,KRIGHT,KTOP,KBOTTOM)
!     ##############################################################
!
!!**** *GET_ADJ_MES_LONLAT_REG* get the near grid mesh indices
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_lonlat_reg
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: kgrid_par ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: kl        ! number of points
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: pgrid_par ! grid parameters
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: kleft     ! left   mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: kright    ! right  mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: ktop      ! top    mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: kbottom   ! bottom mesh index
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL    :: zlonmin ! minimum longitude (degrees)
REAL    :: zlonmax ! maximum longitude (degrees)
REAL    :: zlatmin ! minimum latitude  (degrees)
REAL    :: zlatmax ! maximum latitude  (degrees)
INTEGER :: ilon    ! number of points in longitude
INTEGER :: ilat    ! number of points in latitude
INTEGER :: jlat, jlon
INTEGER :: jl
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_LONLAT_REG',0,zhook_handle)
 CALL get_gridtype_lonlat_reg(pgrid_par,zlonmin,zlonmax, &
                               zlatmin,zlatmax,ilon,ilat  )  
!
kleft(:) = 0
kright(:) = 0
ktop(:) = 0
kbottom(:) = 0
!
IF (ilon*ilat==kl) THEN
  DO jlat=1,ilat
    DO jlon=1,ilon
      jl = jlon + ilon * (jlat-1)
      IF (jlon>1   ) kleft(jl) = jl-1
      IF (jlon<ilon) kright(jl) = jl+1
      IF (jlat>1   ) kbottom(jl) = jl-ilon
      IF (jlat<ilat) ktop(jl) = jl+ilon
      IF (jlon==1    .AND. zlonmin + 360. == zlonmax) kleft(jl) = jl+ilon-1
      IF (jlon==ilon .AND. zlonmin + 360. == zlonmax) kright(jl) = jl-ilon+1
    END DO
  END DO
END IF
IF (lhook) CALL dr_hook('GET_ADJ_MES_LONLAT_REG',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_adj_mes_lonlat_reg