floor_layer_e_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!   ##########################################################################
    SUBROUTINE floor_layer_e_budget(PT_FLOOR, PTSTEP, PHC_FLOOR, PTC_FLOOR, PD_FLOOR, &
                                    pflx_bld_floor, pdqs_floor, pimb_floor,           &
                                    pf_floor_mass, pf_floor_wall, pf_floor_win,       &
                                    pf_floor_roof, pradht_in,           &
                                    pts_mass, prad_wall_floor, prad_roof_floor,       &
                                    prad_win_floor, pload_floor, pti_bld,             &
                                    prad_floor_mass, pconv_floor_bld                  )
!   ##########################################################################
!
!!****  *FLOOR_LAYER_E_BUDGET*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evoultion of building floor temperatures
!         
!     
!!**  METHOD
!     ------
!
!    6 : equations for evolution of Ts_floor 
!        *************************************************************
!
!     dTf_k(t) / dt = 1/(df_k*Cf_k) * (- 2*Kf_k-1*(Tf_k-Tf_k-1)/(df_k-1 +df_k) 
!                                      - 2*Kf_k  *(Tf_k-Tf_k+1)/(df_k+1 +df_k) )
!
!     dTf_1(t) / dt = 1/(df_1*Cf_1) * (- 2*Kw_1*(Tw_1-Tw_2)/(dw_1 +dw_2))
!
!       with
!
!   K*_k  = (d*_k+ d*_k+1)/(d*_k/k*_k+ d*_k+1/k*_k+1)
!
!
! The system is implicited (or semi-implicited).
!
! ZIMPL=1    ---> implicit system
! ZIMPL=0.5  ---> semi-implicit system
! ZIMPL=0    ---> explicit system
!
!
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      G. Pigeon           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    15/04/09 
!!      G. Pigeon      08/10 computation of residual of energy balance 
!!                           modification of the limit condition for
!!                           the deep temp. from the deep road temp.
!!                           to zero flux condition. idem for sfce T
!!      G. Pigeon      11/11 split in 2 for floor and mass to be flux conservative
!!      G. Pigeon      09/12 modif of conv. coef + implicitation of the exchange
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modi_layer_e_budget_get_coef
USE modi_layer_e_budget
USE mode_conv_doe
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:), INTENT(INOUT) :: pt_floor     ! floor layers temperatures
REAL,                 INTENT(IN)    :: ptstep       ! time step
REAL, DIMENSION(:,:), INTENT(IN)    :: phc_floor    ! heat capacity for road layers
REAL, DIMENSION(:,:), INTENT(IN)    :: ptc_floor    ! thermal conductivity for 
                                                    !road layers
REAL, DIMENSION(:,:), INTENT(IN)  :: pd_floor       ! depth of road layers
REAL, DIMENSION(:),   INTENT(OUT)  :: pflx_bld_floor !flux from building to floor
REAL, DIMENSION(:),   INTENT(OUT) :: pdqs_floor !heat storage inside the floor
REAL, DIMENSION(:),   INTENT(OUT) :: pimb_floor !floor energy residual imbalance for verification
REAL, DIMENSION(:), INTENT(IN)    :: pf_floor_mass  ! View factor floor-mass
REAL, DIMENSION(:), INTENT(IN)    :: pf_floor_wall  ! View factor floor-wall
REAL, DIMENSION(:), INTENT(IN)    :: pf_floor_win   ! View factor floor-window
REAL, DIMENSION(:), INTENT(IN)    :: pf_floor_roof  ! View factor floor-roof
REAL, DIMENSION(:), INTENT(IN)    :: pradht_in      ! Indoor radiant heat transfer coefficient
                                                    ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: pts_mass  ! surf. mass temp. (contact with bld air)
REAL, DIMENSION(:), INTENT(IN)    :: prad_roof_floor ! rad. fluxes from roof to floor[W m-2(roof)]
REAL, DIMENSION(:), INTENT(IN)    :: prad_wall_floor ! rad. fluxes from wall to floor[W m-2(wall)]
REAL, DIMENSION(:), INTENT(IN)    :: prad_win_floor  ! rad. fluxes from win to floor[W m-2(win)]
REAL, DIMENSION(:), INTENT(IN)    :: pti_bld   ! indoor air temp.
REAL, DIMENSION(:), INTENT(IN)    :: pload_floor ! solar and internal load to the floor
REAL, DIMENSION(:), INTENT(OUT)   :: prad_floor_mass  ! rad. fluxes from floor to mass [W m-2(floor)]
REAL, DIMENSION(:), INTENT(OUT)   :: pconv_floor_bld  ! conv. fluxes from floor to bld [W m-2(floor)]
!
!*      0.2    declarations of local variables
!
!
REAL :: zimpl=1.0      ! implicit coefficient
REAL :: zexpl=0.0      ! explicit coefficient
!
REAL, DIMENSION(SIZE(PT_FLOOR,1),SIZE(PT_FLOOR,2)) :: za,& ! lower diag.
                                                      zb,& ! main  diag.
                                                      zc,& ! upper diag.
                                                      zy   ! r.h.s.
!
REAL, DIMENSION(SIZE(PT_FLOOR,1)) :: zts_floor ! surf. floor temp.  used for rad. exchanges
REAL, DIMENSION(SIZE(PT_FLOOR,1)) :: zts_floor_conv ! surf. floor temp. used for conv exchanges
                                               ! used during calculation
REAL, DIMENSION(SIZE(PT_FLOOR,1)) :: zchtc_in_floor   ! Indoor floor convec heat transfer coefficient
                                                    ! [W K-1 m-2(bld)]

REAL(KIND=JPRB) :: zhook_handle
INTEGER :: jj
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('FLOOR_LAYER_E_BUDGET',0,zhook_handle)
!
! *Convection heat transfer coefficients [W m-2 K-1]
!  From EP Engineering Reference
zchtc_in_floor(:) = chtc_up_doe(pt_floor(:,1), pti_bld(:))
DO jj=1,SIZE(zchtc_in_floor)
   zchtc_in_floor(jj) = max(1., zchtc_in_floor(jj))
ENDDO


!
 CALL layer_e_budget_get_coef( pt_floor, ptstep, zimpl, phc_floor, ptc_floor, pd_floor, &
                              za, zb, zc, zy )
!
zts_floor(:) = pt_floor(:,1) 

zb(:,1) = zb(:,1) + zimpl * &
   (zchtc_in_floor(:)*4./3. + pradht_in(:) * pf_floor_mass(:))


zy(:,1) = zy(:,1)  &
   + zchtc_in_floor(:) * (pti_bld(:) - 1./3. * pt_floor(:, 1) * (4* zexpl -1))  &
   + pf_floor_win(:) * prad_win_floor(:)                    &
   + pf_floor_wall(:) * prad_wall_floor(:)                   &
   + pf_floor_roof(:) * prad_roof_floor(:)                   &
   + pradht_in(:) * pf_floor_mass(:) * (pts_mass(:) - zexpl * pt_floor(:,1))  &
   + pload_floor(:)
!
 CALL layer_e_budget( pt_floor, ptstep, zimpl, phc_floor, ptc_floor, pd_floor, &
                     za, zb, zc, zy, pdqs_floor )
!
!*      floor surface temperature used in the implicit formulation
!       ----------------------------------------------------------
zts_floor_conv(:) = 4./3. * zimpl * pt_floor(:,1) + 1./3. * zts_floor(:) * (4 * zexpl - 1.)
zts_floor(:) = zexpl * zts_floor(:) + zimpl * pt_floor(:,1)
!
!*      fluxes with mass and indoor air
!       ----------------------------------------------------------
prad_floor_mass(:) = pradht_in(:)    * (zts_floor(:) - pts_mass(:))
pconv_floor_bld(:) = zchtc_in_floor(:) * (zts_floor_conv(:) - pti_bld(:))
!
!*     Flux between floor and indoor surfaces and air
!       ------------------------------------------------
pflx_bld_floor(:) = - pconv_floor_bld(:)  &
       + pf_floor_win(:) * prad_win_floor(:)  &
       + pf_floor_wall(:) * prad_wall_floor(:) &
       + pf_floor_roof(:) * prad_roof_floor(:) &
       + pradht_in(:) * pf_floor_mass(:) * (pts_mass(:)  - zts_floor(:)) &
       + pload_floor(:)
!
!*     Floor residual energy imbalance for verification
!       ------------------------------------------------
pimb_floor(:) = pflx_bld_floor(:) - pdqs_floor(:)
!
IF (lhook) CALL dr_hook('FLOOR_LAYER_E_BUDGET',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE floor_layer_e_budget