diag_inline_tebn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_inline_teb_n (DGT, TCP, T, &
                                      ocanopy, pta, pts, pqa, ppa, pps, prhoa,                  &
                                       pzona, pmera, pwind, pht, phw,                          &
                                       pcd, pcdn, pri, pch, pz0,                               &
                                       ptrad, pemis, pdir_alb, psca_alb,                       &
                                       plw, pdir_sw, psca_sw,                                  &
                                       psfth, psftq, psfzon, psfmer, psfco2,                   &
                                       prn, ph, ple, pgflux                                    )  
!     ###############################################################################!
!!****  *DIAG_INLINE_TEB_n * - Computes diagnostics during TEB time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette   06/2009 CLS_WIND has one more argument (height of diagnostic)
!!      S. Riette   01/2010 Use of interpol_sbl to compute 10m wind diagnostic
!       B. decharme 04/2013 : Add EVAP and SUBL diag
!!------------------------------------------------------------------
!

!
!
!
USE modd_diag_teb_n, ONLY : diag_teb_t
USE modd_teb_canopy_n, ONLY : teb_canopy_t
USE modd_teb_n, ONLY : teb_t
!
USE modd_surf_par,   ONLY : xundef
!
USE modi_cls_wind
USE modi_param_cls
USE modi_diag_surf_budget_teb
USE modi_interpol_sbl
!
USE mode_thermos
USE mode_coupling_canopy
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_teb_t), INTENT(INOUT) :: dgt
TYPE(teb_canopy_t), INTENT(INOUT) :: tcp
TYPE(teb_t), INTENT(INOUT) :: t
!
LOGICAL,            INTENT(IN)       :: ocanopy  ! Flag for canopy
REAL, DIMENSION(:), INTENT(IN)       :: pta      ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN)       :: pts      ! surface temperature
REAL, DIMENSION(:), INTENT(IN)       :: pqa      ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN)       :: ppa      ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN)       :: pps      ! surface pressure
REAL, DIMENSION(:), INTENT(IN)       :: prhoa    ! air density
REAL, DIMENSION(:), INTENT(IN)       :: pzona    ! zonal wind
REAL, DIMENSION(:), INTENT(IN)       :: pmera    ! meridian wind
REAL, DIMENSION(:), INTENT(IN)       :: pwind    ! wind
REAL, DIMENSION(:), INTENT(IN)       :: pht      ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN)       :: phw      ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN)       :: pcd      ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN)       :: pcdn     ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN)       :: psfzon   ! zonal friction
REAL, DIMENSION(:), INTENT(IN)       :: psfmer   ! meridian friction
REAL, DIMENSION(:), INTENT(IN)       :: psfco2   ! CO2 flux   (m/s*kg_CO2/kg_air)
REAL, DIMENSION(:), INTENT(IN)       :: psfth    ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN)       :: psftq    ! water flux (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN)       :: pri      ! Richardson number
REAL, DIMENSION(:), INTENT(IN)       :: pch      ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN)       :: pz0      ! roughness length for momentum
REAL, DIMENSION(:), INTENT(IN)       :: prn      ! net radiation
REAL, DIMENSION(:), INTENT(IN)       :: ph       ! sensible heat flux
REAL, DIMENSION(:), INTENT(IN)       :: ple      ! latent heat flux
REAL, DIMENSION(:), INTENT(IN)       :: pgflux   ! storage flux
REAL, DIMENSION(:,:),INTENT(IN)      :: pdir_sw  ! direct  solar radiation (on horizontal surf.)
!                                                !                                      (W/m2)
REAL, DIMENSION(:,:),INTENT(IN)      :: psca_sw  ! diffuse solar radiation (on horizontal surf.)
!                                                !                                      (W/m2)
REAL, DIMENSION(:), INTENT(IN)       :: plw      ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN)       :: ptrad    ! radiative temperature                 (K)
REAL, DIMENSION(:,:),INTENT(IN)      :: pdir_alb ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN)      :: psca_alb ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN)       :: pemis    ! emissivity                            (-)
!
!*      0.2    declarations of local variables
!
REAL                                 :: zz0_o_z0h
REAL, DIMENSION(SIZE(PTA))           :: zh  
REAL, DIMENSION(SIZE(PTA))  :: zu10
REAL, DIMENSION(SIZE(PTA))  :: zwind10m_max
REAL, DIMENSION(SIZE(PTA))  :: zt2m_min
REAL, DIMENSION(SIZE(PTA))  :: zt2m_max
REAL, DIMENSION(SIZE(PTA))  :: zhu2m_min
REAL, DIMENSION(SIZE(PTA))  :: zhu2m_max
INTEGER                              :: jj    ! loop counter

REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_TEB_N',0,zhook_handle)
!
! * Mean surface temperature need to couple with AGCM
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Here it is the radiative temperature that is wrong !
!It should be the arithmetic mean of the surface temperature
!of each independant energy budget, if there is. See ISBA for more detail.
!
dgt%XDIAG_TS(:) = pts(:)
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
zz0_o_z0h = 200.
!
!* 2m and 10m variables interpolated from canopy if used
!
IF (ocanopy) THEN
  zt2m_min(:) = xundef
  zt2m_max(:) = xundef
  zhu2m_min(:) = xundef
  zhu2m_max(:) = xundef
  zwind10m_max(:) = xundef
  IF (dgt%N2M>0) CALL init_2m_10m( tcp%XP(:,2), tcp%XT(:,2), tcp%XQ(:,2),  tcp%XU, tcp%XZ, &
                               pzona, pmera, pwind, prhoa,         &
                               dgt%XT2M, dgt%XQ2M, dgt%XHU2M, dgt%XZON10M, dgt%XMER10M,&
                               zu10, zwind10m_max, zt2m_min,       &
                               zt2m_max, zhu2m_min, zhu2m_max )
ELSE
!* 2m and 10m variables using CLS laws
 IF (dgt%N2M==1) THEN
  CALL param_cls(pta, pts, pqa, ppa, prhoa, pzona, pmera, pht, phw, &
                   psfth, psftq, psfzon, psfmer,                       &
                   dgt%XT2M, dgt%XQ2M, dgt%XHU2M, dgt%XZON10M, dgt%XMER10M                )  
  !
  !* erases temperature and humidity 2m above roof level bu canyon air values
  !
  dgt%XT2M  = t%CUR%XT_CANYON
  dgt%XQ2M  = t%CUR%XQ_CANYON
  !
  !* Richardson number
  !
  dgt%XRI = pri
  dgt%XHU2M = min(t%CUR%XQ_CANYON /qsat(t%CUR%XT_CANYON,ppa),1.)
 ELSE IF (dgt%N2M==2) THEN
  zh(:)=10.
  CALL cls_wind(pzona, pmera, phw,  &
                  pcd, pcdn, pri, zh, &
                  dgt%XZON10M, dgt%XMER10M    )  
  dgt%XT2M  = t%CUR%XT_CANYON
  dgt%XQ2M  = t%CUR%XQ_CANYON
  dgt%XRI   = pri
  dgt%XHU2M = min(t%CUR%XQ_CANYON /qsat(t%CUR%XT_CANYON,ppa),1.)
 END IF
END IF
!
IF (dgt%N2M>=1) THEN
  !
  dgt%XT2M_MIN(:) = min(dgt%XT2M_MIN(:),dgt%XT2M(:))
  dgt%XT2M_MAX(:) = max(dgt%XT2M_MAX(:),dgt%XT2M(:))
  !
  dgt%XHU2M_MIN(:) = min(dgt%XHU2M_MIN(:),dgt%XHU2M(:))
  dgt%XHU2M_MAX(:) = max(dgt%XHU2M_MAX(:),dgt%XHU2M(:))
  !
  dgt%XWIND10M    (:) = sqrt(dgt%XZON10M**2+dgt%XMER10M**2)
  dgt%XWIND10M_MAX(:) = max(dgt%XWIND10M_MAX(:),dgt%XWIND10M(:))
  !
END IF

!
IF (dgt%LSURF_BUDGET) THEN
   !
   CALL diag_surf_budget_teb(pdir_sw, psca_sw, pdir_alb, psca_alb,  &
                               plw, pemis, ptrad,                     &
                               dgt%XSWD, dgt%XSWU, dgt%XSWBD, dgt%XSWBU, dgt%XLWD, dgt%XLWU   )  
   !                             
   dgt%XRN    = prn
   dgt%XH     = ph
   dgt%XLE    = ple
   dgt%XGFLUX = pgflux
   dgt%XFMU   = psfzon
   dgt%XFMV   = psfmer
   dgt%XSFCO2 = psfco2
   !
END IF
!
IF (dgt%LCOEF) THEN
  dgt%XCD    = pcd
  dgt%XCH    = pch
  dgt%XCE    = pch
  dgt%XZ0    = pz0
  dgt%XZ0H   = pz0 / zz0_o_z0h
END IF
!
IF (dgt%LSURF_VARS) THEN
  dgt%XQS    = t%CUR%XQ_CANYON
END IF
IF (lhook) CALL dr_hook('DIAG_INLINE_TEB_N',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_teb_n