diag_surf_budget_teb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_surf_budget_teb (PDIR_SW, PSCA_SW, PDIR_ALB, PSCA_ALB,  &
                                          plw, pemis, ptrad,                     &
                                          pswd, pswu, pswbd, pswbu, plwd, plwu   )  
!     ###############################################################################
!
!!****  *DIAG_SURF_BUDGET_TEB * - Computes diagnostics over TEB
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     P. Le Moigne 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    04/2006
!!------------------------------------------------------------------
!

!
!
USE modd_csts,           ONLY : xstefan
!
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:),INTENT(IN)  :: pdir_sw   ! direct  solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN)  :: psca_sw   ! diffuse solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN)   :: plw       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN)   :: ptrad     ! radiative temperature                 (K)
REAL, DIMENSION(:,:),INTENT(IN)  :: pdir_alb  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN)  :: psca_alb  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN)   :: pemis     ! emissivity                            (-)
!
REAL, DIMENSION(:,:), INTENT(OUT):: pswbd     ! incoming short wave radiation by spectral band (W/m2)
REAL, DIMENSION(:,:), INTENT(OUT):: pswbu     ! upward  short wave radiation by spectral band (W/m2)
REAL, DIMENSION(:), INTENT(OUT)  :: pswd      ! total incoming short wave radiation (W/m2)
REAL, DIMENSION(:), INTENT(OUT)  :: pswu      ! total upward short wave radiation (W/m2)
REAL, DIMENSION(:), INTENT(OUT)  :: plwd      ! Downward long wave radiation (W/m2)
REAL, DIMENSION(:), INTENT(OUT)  :: plwu      ! upward long wave radiation (W/m2)  
!
                                        
!
!*      0.2    declarations of local variables
!
INTEGER                          :: iswb      ! number of SW bands
INTEGER                          :: jswb      ! loop counter on number of SW bands
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_TEB',0,zhook_handle)
iswb = SIZE(pdir_sw,2)
! 
!* total incoming and outgoing SW
!
DO jswb=1,iswb
  pswbd(:,jswb) = pdir_sw(:,jswb)                    + psca_sw(:,jswb)
  pswbu(:,jswb) = pdir_sw(:,jswb) * pdir_alb(:,jswb) + psca_sw(:,jswb) * psca_alb(:,jswb) 
ENDDO
!
pswd(:) = 0.
pswu(:) = 0.
DO jswb=1,iswb
   pswd(:)=pswd(:)+pswbd(:,jswb)
   pswu(:)=pswu(:)+pswbu(:,jswb)
ENDDO
!
!*incoming outgoing LW
!
plwd(:)=plw(:)
plwu(:)=pemis(:)*xstefan*ptrad(:)**4 + (1.-pemis(:))*plw(:)
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_TEB',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_surf_budget_teb