coupling_isba_svatn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################################
SUBROUTINE coupling_isba_svat_n (DTCO, UG, U, USS, IM, DTGD, DTGR, TGRO, DST, SLT,    &
                                 hprogram, hcoupling,                                       &
                 ptstep, kyear, kmonth, kday, ptime, ki, ksv, ksw, ptsun, pzenith, pzenith2, &
                 pazim, pzref, puref, pzs, pu, pv, pqa, pta, prhoa, psv, pco2, hsv,          &
                 prain, psnow, plw, pdir_sw, psca_sw, psw_bands, pps, ppa,                   &
                 psftq, psfth, psfts, psfco2, psfu, psfv,                                    &
                 ptrad, pdir_alb, psca_alb, pemis, ptsurf, pz0, pz0h, pqsurf,                &
                 ppew_a_coef, ppew_b_coef,                                                   &
                 ppet_a_coef, ppeq_a_coef, ppet_b_coef, ppeq_b_coef,                         &
                 htest                                                                       )  
!     ###############################################################################
!
!!****  *COUPLING_ISBA_SVAT_n * - Chooses the time method (explicit, 
!!        implicit, time-spliting) for ISBA scheme   
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!     A. Bogatchev 09/2005 EBA snow option
!!     A. Boone     11/2009 Exner correction for Offline T-B coef
!!     B. Decharme  11/2009 Implicit coupling ok with all snow scheme
!!     B. Decharme  04/2013 new coupling variables and init local variables
!!-------------------------------------------------------------------
!
!
USE modd_surfex_n, ONLY : isba_model_t
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_data_teb_garden_n, ONLY : data_teb_garden_t
USE modd_data_teb_greenroof_n, ONLY : data_teb_greenroof_t
USE modd_teb_greenroof_option_n, ONLY : teb_greenroof_options_t
USE modd_dst_n, ONLY : dst_t
USE modd_slt_n, ONLY : slt_t
!
!
USE modd_surf_par,   ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_coupling_isba_orography_n
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(isba_model_t), INTENT(INOUT) :: im
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(data_teb_garden_t), INTENT(INOUT) :: dtgd
TYPE(data_teb_greenroof_t), INTENT(INOUT) :: dtgr
TYPE(teb_greenroof_options_t), INTENT(INOUT) :: tgro
TYPE(dst_t), INTENT(INOUT) :: dst
TYPE(slt_t), INTENT(INOUT) :: slt
!
 CHARACTER(LEN=6),    INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=1),    INTENT(IN)  :: hcoupling ! type of coupling
                                              ! 'E' : explicit
                                              ! 'I' : implicit
INTEGER,             INTENT(IN)  :: kyear     ! current year (UTC)
INTEGER,             INTENT(IN)  :: kmonth    ! current month (UTC)
INTEGER,             INTENT(IN)  :: kday      ! current day (UTC)
REAL,                INTENT(IN)  :: ptime     ! current time since midnight (UTC, s)
INTEGER,             INTENT(IN)  :: ki        ! number of points
INTEGER,             INTENT(IN)  :: ksv       ! number of scalars
INTEGER,             INTENT(IN)  :: ksw       ! number of short-wave spectral bands
REAL, DIMENSION(KI), INTENT(IN)  :: ptsun     ! solar time                    (s from midnight)
REAL,                INTENT(IN)  :: ptstep    ! atmospheric time-step                 (s)
REAL, DIMENSION(KI), INTENT(IN)  :: pzref     ! height of T,q forcing                 (m)
REAL, DIMENSION(KI), INTENT(IN)  :: puref     ! height of wind forcing                (m)
!
REAL, DIMENSION(KI), INTENT(IN)  :: pta       ! air temperature forcing               (K)
REAL, DIMENSION(KI), INTENT(IN)  :: pqa       ! air humidity forcing                  (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: prhoa     ! air density                           (kg/m3)
REAL, DIMENSION(KI,KSV),INTENT(IN) :: psv     ! scalar variables
!                                             ! chemistry:   first char. in HSV: '#'  (molecule/m3)
!                                             !
 CHARACTER(LEN=6), DIMENSION(KSV),INTENT(IN):: hsv  ! name of all scalar variables
REAL, DIMENSION(KI), INTENT(IN)  :: pu        ! zonal wind                            (m/s)
REAL, DIMENSION(KI), INTENT(IN)  :: pv        ! meridian wind                         (m/s)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: pdir_sw ! direct  solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: psca_sw ! diffuse solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KSW),INTENT(IN)  :: psw_bands ! mean wavelength of each shortwave band (m)
REAL, DIMENSION(KI), INTENT(IN)  :: pzenith   ! zenithal angle at t      (radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: pzenith2  ! zenithal angle at t+1    (radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: pazim     ! azimuthal angle      (radian from North, clockwise)
REAL, DIMENSION(KI), INTENT(IN)  :: plw       ! longwave radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI), INTENT(IN)  :: pps       ! pressure at atmospheric model surface (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: ppa       ! pressure at forcing level             (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: pzs       ! atmospheric model orography           (m)
REAL, DIMENSION(KI), INTENT(IN)  :: pco2      ! CO2 concentration in the air          (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: psnow     ! snow precipitation                    (kg/m2/s)
REAL, DIMENSION(KI), INTENT(IN)  :: prain     ! liquid precipitation                  (kg/m2/s)
!
REAL, DIMENSION(KI), INTENT(OUT) :: psfth     ! flux of heat                          (W/m2)
REAL, DIMENSION(KI), INTENT(OUT) :: psftq     ! flux of water vapor                   (kg/m2/s)
REAL, DIMENSION(KI), INTENT(OUT) :: psfu      ! zonal momentum flux                   (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: psfv      ! meridian momentum flux                (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: psfco2    ! flux of CO2                           (m/s*kg_CO2/kg_air)
REAL, DIMENSION(KI,KSV),INTENT(OUT):: psfts   ! flux of scalar var.                   (kg/m2/s)
!
REAL, DIMENSION(KI), INTENT(OUT) :: ptrad     ! radiative temperature                 (K)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: pdir_alb! direct albedo for each spectral band  (-)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: psca_alb! diffuse albedo for each spectral band (-)
REAL, DIMENSION(KI), INTENT(OUT) :: pemis     ! emissivity                            (-)
!
REAL, DIMENSION(KI), INTENT(OUT) :: ptsurf    ! surface effective temperature         (K)
REAL, DIMENSION(KI), INTENT(OUT) :: pz0       ! roughness length for momentum         (m)
REAL, DIMENSION(KI), INTENT(OUT) :: pz0h      ! roughness length for heat             (m)
REAL, DIMENSION(KI), INTENT(OUT) :: pqsurf    ! specific humidity at surface          (kg/kg)
!
REAL, DIMENSION(KI), INTENT(IN) :: ppew_a_coef! implicit coefficients
REAL, DIMENSION(KI), INTENT(IN) :: ppew_b_coef! needed if HCOUPLING='I'
REAL, DIMENSION(KI), INTENT(IN) :: ppet_a_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppeq_a_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppet_b_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppeq_b_coef
 CHARACTER(LEN=2),    INTENT(IN) :: htest ! must be equal to 'OK'
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(KI)     :: zsfth   ! surface temperature flux 
REAL, DIMENSION(KI)     :: zsftq   ! surface water vapor flux 
REAL, DIMENSION(KI)     :: zsfco2  ! surface CO2 flux 
REAL, DIMENSION(KI,KSV) :: zsfts   ! surface scalar flux   
REAL, DIMENSION(KI)     :: zsfu    ! zonal momentum flux
REAL, DIMENSION(KI)     :: zsfv    ! meridian momentum flux
REAL, DIMENSION(KI)     :: ztrad   ! surface radiative temperature
REAL, DIMENSION(KI)     :: zemis   ! surface emissivity
REAL, DIMENSION(KI,KSW) :: zdir_alb! direct surface albedo
REAL, DIMENSION(KI,KSW) :: zsca_alb! diffuse surface albedo
REAL, DIMENSION(KI)     :: ztsurf  ! surface effective temperature         (K)
REAL, DIMENSION(KI)     :: zz0     ! roughness length for momentum         (m)
REAL, DIMENSION(KI)     :: zz0h    ! roughness length for heat             (m)
REAL, DIMENSION(KI)     :: zqsurf  ! specific humidity at surface          (kg/kg)
!
REAL, DIMENSION(KI)     :: zwork_lw  ! work array for mean upward longwave surface flux
REAL, DIMENSION(KI)     :: zwork_z0  ! work array for mean roughness length for momentum
REAL, DIMENSION(KI)     :: zwork_z0h ! work array for mean roughness length for heat
!
INTEGER :: jt      ! time loop counter
INTEGER :: it      ! total number of surface timesteps in one atmospheric timestep
REAL    :: zt      ! total number of surface timesteps in one atmospheric timestep
REAL    :: ztstep  ! surface time step
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.     number of time-steps
!              --------------------
!
!* only one timestep in Implicit coupling
IF (lhook) CALL dr_hook('COUPLING_ISBA_SVAT_N',0,zhook_handle)
IF (hcoupling=='I') THEN
  it=1
  zt=1.
  ztstep=ptstep
!
!* same timestep as atmospheric timestep as default
ELSE IF (im%I%XTSTEP==xundef) THEN
  it=1
  zt=1.
  ztstep=ptstep
!
!* case of specified SVAT time-step
ELSE
  it=max(nint(ptstep/im%I%XTSTEP),1)
  zt=float(it)
  ztstep=ptstep/zt
ENDIF
!
!*      3.     initialization of outputs
!              -------------------------
!
psftq   = 0.0
psfth   = 0.0
psfts   = 0.0
psfco2  = 0.0
psfu    = 0.0
psfv    = 0.0
ptrad   = 0.0
pdir_alb= 0.0
psca_alb= 0.0
pemis   = 0.0
ptsurf  = 0.0
pz0     = 0.0
pz0h    = 0.0
pqsurf  = 0.0
!
zsfth   = 0.0  ! surface temperature flux 
zsftq   = 0.0  ! surface water vapor flux 
zsfco2  = 0.0  ! surface CO2 flux 
zsfts   = 0.0  ! surface scalar flux   
zsfu    = 0.0  ! zonal momentum flux
zsfv    = 0.0  ! meridian momentum flux
ztrad   = 0.0  ! surface radiative temperature
zemis   = 0.0  ! surface emissivity
zdir_alb= 0.0  ! direct surface albedo
zsca_alb= 0.0  ! diffuse surface albedo
ztsurf  = 0.0  ! surface effective temperature         (K)
zz0     = 0.0  ! roughness length for momentum         (m)
zz0h    = 0.0  ! roughness length for heat             (m)
zqsurf  = 0.0  ! specific humidity at surface
!
zwork_lw = 0.0 ! work array for mean upward longwave surface flux
zwork_z0 = 0.0 ! work array for mean roughness length for momentum
zwork_z0h= 0.0 ! work array for mean roughness length for heat
!
!*      4.     loop on surface time-step
!              -------------------------
!
DO jt=1,it
!
  CALL coupling_isba_orography_n(dtco, ug, u, uss, im, dtgd, dtgr, tgro, dst, slt,   &
                                 hprogram, hcoupling,                                      &
                 ztstep, kyear, kmonth, kday, ptime,                                         &
                 ki, ksv, ksw,                                                               &
                 ptsun, pzenith, pzenith2, pazim,                                            &
                 pzref, puref, pzs, pu, pv, pqa, pta, prhoa, psv, pco2, hsv,                 &
                 prain, psnow, plw, pdir_sw, psca_sw, psw_bands, pps, ppa,                   &
                 zsftq, zsfth, zsfts, zsfco2, zsfu, zsfv,                                    &
                 ztrad, zdir_alb, zsca_alb, zemis, ztsurf, zz0, zz0h, zqsurf,                &
                 ppew_a_coef, ppew_b_coef,                                                   &
                 ppet_a_coef, ppeq_a_coef, ppet_b_coef, ppeq_b_coef,                         &
                 'OK'                                                                        ) 
!
  psftq    = psftq    + zsftq    / zt
  psfth    = psfth    + zsfth    / zt
  psfts    = psfts    + zsfts    / zt
  psfco2   = psfco2   + zsfco2   / zt
  psfu     = psfu     + zsfu     / zt
  psfv     = psfv     + zsfv     / zt
  pemis    = pemis    + zemis    / zt
  pdir_alb = pdir_alb + zdir_alb / zt
  psca_alb = psca_alb + zsca_alb / zt
  ptsurf   = ptsurf   + ztsurf   / zt
  pqsurf   = pqsurf   + zqsurf   / zt
!  
  zwork_lw  = zwork_lw  + zemis*ztrad**4 / zt
  zwork_z0  = zwork_z0  + (1.0/(log(puref(:)/zz0 ))**2) / zt
  zwork_z0h = zwork_z0h + (1.0/(log(pzref(:)/zz0h))**2) / zt
!  
END DO
!
!* radiative temperature retrieved from upward longwave flux
!
ptrad = (zwork_lw/pemis)**(0.25)
!
!* roughness length for momentum and heat
!
pz0  = puref(:) * exp( - sqrt(1./zwork_z0(:)) )
pz0h = pzref(:) * exp( - sqrt(1./zwork_z0h(:)) )
!
IF (lhook) CALL dr_hook('COUPLING_ISBA_SVAT_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE coupling_isba_svat_n