coupling_isba_orographyn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################################
SUBROUTINE coupling_isba_orography_n (DTCO, UG, U, USS, IM, DTGD, DTGR, TGRO, DST, SLT,   &
                                      hprogram, hcoupling,                                    &
                 ptstep, kyear, kmonth, kday, ptime, ki, ksv, ksw, ptsun, pzenith, pzenith2, &
                 pazim, pzref, puref, pzs, pu, pv, pqa, pta, prhoa, psv, pco2, hsv,          &
                 prain, psnow, plw, pdir_sw, psca_sw, psw_bands, pps, ppa,                   &
                 psftq, psfth, psfts, psfco2, psfu, psfv,                                    &
                 ptrad, pdir_alb, psca_alb, pemis, ptsurf, pz0, pz0h, pqsurf,                &
                 ppew_a_coef, ppew_b_coef,                                                   &
                 ppet_a_coef, ppeq_a_coef, ppet_b_coef, ppeq_b_coef,                         &
                 htest                                                                       )  
!     ###############################################################################
!
!!****  *COUPLING_ISBA_OROGRAPHY_n * - Parameterizes effects of subgrid 
!!     orography on radiative and energy fluxes
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      modified    05/2004 by P. LeMoigne: vertical shift of implicit
!!                          coefficients
!!      B. Decharme   2008   reset the subgrid topographic effect on the forcing
!!      B. Decharme  04/2013 new coupling variables and optimization
!!                           improve forcing vertical shift
!----------------------------------------------------------------
!
!
USE modd_surfex_n, ONLY : isba_model_t
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_data_teb_garden_n, ONLY : data_teb_garden_t
USE modd_data_teb_greenroof_n, ONLY : data_teb_greenroof_t
USE modd_teb_greenroof_option_n, ONLY : teb_greenroof_options_t
USE modd_dst_n, ONLY : dst_t
USE modd_slt_n, ONLY : slt_t
!
USE modd_surf_par,ONLY : xundef
USE modd_csts,    ONLY : xstefan, xcpd, xrd, xp00
!
USE modd_surf_atm, ONLY : lnosof, lvertshift
!
USE modi_forcing_vert_shift
USE modi_coupling_isba_canopy_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(isba_model_t), INTENT(INOUT) :: im
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(data_teb_garden_t), INTENT(INOUT) :: dtgd
TYPE(data_teb_greenroof_t), INTENT(INOUT) :: dtgr
TYPE(teb_greenroof_options_t), INTENT(INOUT) :: tgro
TYPE(dst_t), INTENT(INOUT) :: dst
TYPE(slt_t), INTENT(INOUT) :: slt
!
 CHARACTER(LEN=6),    INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=1),    INTENT(IN)  :: hcoupling ! type of coupling
                                              ! 'E' : explicit
                                              ! 'I' : implicit
INTEGER,             INTENT(IN)  :: kyear     ! current year (UTC)
INTEGER,             INTENT(IN)  :: kmonth    ! current month (UTC)
INTEGER,             INTENT(IN)  :: kday      ! current day (UTC)
REAL,                INTENT(IN)  :: ptime     ! current time since midnight (UTC, s)
INTEGER,             INTENT(IN)  :: ki        ! number of points
INTEGER,             INTENT(IN)  :: ksv       ! number of scalars
INTEGER,             INTENT(IN)  :: ksw       ! number of short-wave spectral bands
REAL, DIMENSION(KI), INTENT(IN)  :: ptsun     ! solar time                    (s from midnight)
REAL,                INTENT(IN)  :: ptstep    ! atmospheric time-step                 (s)
REAL, DIMENSION(KI), INTENT(IN)  :: pzref     ! height of T,q forcing                 (m)
REAL, DIMENSION(KI), INTENT(IN)  :: puref     ! height of wind forcing                (m)
!
REAL, DIMENSION(KI), INTENT(IN)  :: pta       ! air temperature forcing               (K)
REAL, DIMENSION(KI), INTENT(IN)  :: pqa       ! air humidity forcing                  (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: prhoa     ! air density                           (kg/m3)
REAL, DIMENSION(KI,KSV),INTENT(IN) :: psv     ! scalar variables
!                                             ! chemistry:   first char. in HSV: '#'  (molecule/m3)
!                                             !
 CHARACTER(LEN=6), DIMENSION(KSV),INTENT(IN):: hsv  ! name of all scalar variables
REAL, DIMENSION(KI), INTENT(IN)  :: pu        ! zonal wind                            (m/s)
REAL, DIMENSION(KI), INTENT(IN)  :: pv        ! meridian wind                         (m/s)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: pdir_sw ! direct  solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: psca_sw ! diffuse solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KSW),INTENT(IN)  :: psw_bands ! mean wavelength of each shortwave band (m)
REAL, DIMENSION(KI), INTENT(IN)  :: pzenith   ! zenithal angle at t  (radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: pzenith2  ! zenithal angle at t+1(radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: pazim     ! azimuthal angle      (radian from North, clockwise)
REAL, DIMENSION(KI), INTENT(IN)  :: plw       ! longwave radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI), INTENT(IN)  :: pps       ! pressure at atmospheric model surface (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: ppa       ! pressure at forcing level             (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: pzs       ! atmospheric model orography           (m)
REAL, DIMENSION(KI), INTENT(IN)  :: pco2      ! CO2 concentration in the air          (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: psnow     ! snow precipitation                    (kg/m2/s)
REAL, DIMENSION(KI), INTENT(IN)  :: prain     ! liquid precipitation                  (kg/m2/s)
!
!
REAL, DIMENSION(KI), INTENT(OUT) :: psfth     ! flux of heat                          (W/m2)
REAL, DIMENSION(KI), INTENT(OUT) :: psftq     ! flux of water vapor                   (kg/m2/s)
REAL, DIMENSION(KI), INTENT(OUT) :: psfu      ! zonal momentum flux                   (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: psfv      ! meridian momentum flux                (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: psfco2    ! flux of CO2                           (m/s*kg_CO2/kg_air)
REAL, DIMENSION(KI,KSV),INTENT(OUT):: psfts   ! flux of scalar var.                   (kg/m2/s)
!
REAL, DIMENSION(KI), INTENT(OUT) :: ptrad     ! radiative temperature                 (K)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: pdir_alb! direct albedo for each spectral band  (-)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: psca_alb! diffuse albedo for each spectral band (-)
REAL, DIMENSION(KI), INTENT(OUT) :: pemis     ! emissivity                            (-)
!
REAL, DIMENSION(KI), INTENT(OUT) :: ptsurf    ! surface effective temperature         (K)
REAL, DIMENSION(KI), INTENT(OUT) :: pz0       ! roughness length for momentum         (m)
REAL, DIMENSION(KI), INTENT(OUT) :: pz0h      ! roughness length for heat             (m)
REAL, DIMENSION(KI), INTENT(OUT) :: pqsurf    ! specific humidity at surface          (kg/kg)
!
REAL, DIMENSION(KI), INTENT(IN) :: ppew_a_coef! implicit coefficients
REAL, DIMENSION(KI), INTENT(IN) :: ppew_b_coef! needed if HCOUPLING='I'
REAL, DIMENSION(KI), INTENT(IN) :: ppet_a_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppeq_a_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppet_b_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppeq_b_coef
 CHARACTER(LEN=2),    INTENT(IN) :: htest ! must be equal to 'OK'
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(KI)  :: zta    ! Temperature at forcing height above surface orography
REAL, DIMENSION(KI)  :: zpa    ! Pressure    at forcing height above surface orography
REAL, DIMENSION(KI)  :: zps    ! Pressure    at surface orography
REAL, DIMENSION(KI)  :: zqa    ! Humidity    at forcing height above surface orography
REAL, DIMENSION(KI)  :: zrhoa  ! Density     at forcing height above surface orography
REAL, DIMENSION(KI)  :: zlw    ! LW rad      at forcing height above surface orography
REAL, DIMENSION(KI)  :: zrain  ! Rainfall    at forcing height above surface orography
REAL, DIMENSION(KI)  :: zsnow  ! Snowfall    at forcing height above surface orography
!
!
REAL, DIMENSION(KI)    :: z3d_tot_surf ! ratio between actual surface
!                                               ! and horizontal surface
REAL, DIMENSION(KI)    :: z3d_tot_surf_inv
REAL, DIMENSION(KI,KSW)::zdir_sw ! incoming direct SW radiation
!                                                         ! per m2 of actual surface
REAL, DIMENSION(KI,KSW)::zsca_sw ! incoming diffuse SW radiation
!                                                         ! per m2 of actual surface
!
REAL, DIMENSION(KI)  ::  zpeq_b_coef   ! 1st explicit coefficient
REAL, DIMENSION(KI)  ::  zpet_b_coef   ! 2nd explicit coefficient
!
INTEGER                         :: iswb    ! number of shortwave spectral bands
INTEGER                         :: jswb    ! loop on shortwave spectral bands
INTEGER                         :: jsv     ! loop on scalar variables
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!        
!*      1.     Goes from atmospheric orography to surface orography
!              ----------------------------------------------------
!
IF (lhook) CALL dr_hook('COUPLING_ISBA_OROGRAPHY_N',0,zhook_handle)
!
zpeq_b_coef(:) = ppeq_b_coef(:)
zpet_b_coef(:) = ppet_b_coef(:)
!
IF(lvertshift)THEN
!
  zta(:) = xundef
  zqa(:) = xundef
  zps(:) = xundef
  zpa(:) = xundef
  zrhoa(:) = xundef
  zlw(:) = xundef
  zrain(:) = xundef
  zsnow(:) = xundef
!     
   CALL forcing_vert_shift(pzs,im%I%XZS,pta,pqa,ppa,prhoa,plw,prain,psnow,&
                           zta,zqa,zpa,zrhoa,zlw,zrain,zsnow         )
!
   zps(:) = zpa(:) + (pps(:) - ppa(:))
!
  IF (hcoupling=='I') THEN
    zpeq_b_coef = ppeq_b_coef + zqa - pqa
    zpet_b_coef = ppet_b_coef + zta/(zpa/xp00)**(xrd/xcpd) - pta/(ppa/xp00)**(xrd/xcpd)
  ENDIF
!
ELSE
!
  zta(:) = pta(:)
  zqa(:) = pqa(:)
  zps(:) = pps(:)
  zpa(:) = ppa(:)
  zrhoa(:) = prhoa(:)
  zlw(:) = plw(:)
  zrain(:) = prain(:)
  zsnow(:) = psnow(:)
!
ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      2.     Presence of orography slopes
!              ----------------------------
!
IF(lnosof)THEN
!        
!  No modifications to conserve mass and energy with atmosphere
!
   z3d_tot_surf(:) = 0.
   z3d_tot_surf_inv(:) = 0.
!   
   zsca_sw(:,:) = psca_sw(:,:)
   zdir_sw(:,:) = pdir_sw(:,:)
!
ELSE
!
! Note that this effect is not conservative and should not be use with
! atmospheric model
!
!* Incoming and outgoing fluxes are supposed to be on a horizontal surface.
!  When slopes are present, the actual surface is LARGER than the
!  horizontal surface (none conservative).
!
!* Therefore, this increase of surface will lead to modify the
!  radiative and energy fluxes (none conservative).
!  
!* Note that momentum fluxes are not modified, because the
!  effect of subgrid orography is already taken into account
!  in the effective roughness length (none conservative).
!
!  The subgrid slope comes from the XSSO_SLOPE field.
!
   z3d_tot_surf(:) = sqrt(1.+im%I%XSSO_SLOPE(:)**2)
   z3d_tot_surf_inv(:) = 1./z3d_tot_surf(:)
!
!  number of spectral shortwave bands
!
   iswb = SIZE(psw_bands)
!
   DO jswb=1,iswb
!     correcting for the slope angle (scaterred SW flux)
!
      zsca_sw(:,jswb) =  psca_sw(:,jswb) * z3d_tot_surf_inv(:)

!     correcting for the slope angle (scaterred SW flux)
!
      zdir_sw(:,jswb) =  pdir_sw(:,jswb) * z3d_tot_surf_inv(:)
   END DO
!
!  part of LW flux is received from the surface itself, so the outgoing flux
!  is needed.
!
!  incoming LW radiation per m2 of actual surface
!
   zlw(:) =  zlw(:)                                  *     z3d_tot_surf_inv(:) &
          + xstefan*im%I%XEMIS_NAT(:)*im%I%XTSRAD_NAT(:)**4 * (1.-z3d_tot_surf_inv(:))  
!
!  liquid precipitation per m2 of actual surface
!
   zrain(:) = zrain(:) * z3d_tot_surf_inv(:)
!
!  solid  precipitation per m2 of actual surface
!
   zsnow(:) = zsnow(:) * z3d_tot_surf_inv(:)
!
ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      3.     Call of ISBA
!              ------------
!
 CALL coupling_isba_canopy_n(dtco, ug, u, uss, im, dtgd, dtgr, tgro, dst, slt,   &
                             hprogram, hcoupling,                                           &
               ptstep, kyear, kmonth, kday, ptime,                                           &
               ki, ksv, ksw,                                                                 &
               ptsun, pzenith, pzenith2, pazim,                                              &
               pzref, puref, pzs, pu, pv, zqa, zta, zrhoa, psv, pco2, hsv,                   &
               zrain, zsnow, zlw, zdir_sw, zsca_sw, psw_bands, zps, zpa,                     &
               psftq, psfth, psfts, psfco2, psfu, psfv,                                      &
               ptrad, pdir_alb, psca_alb, pemis, ptsurf, pz0, pz0h, pqsurf,                  &
               ppew_a_coef, ppew_b_coef,                                                     &
               ppet_a_coef, ppeq_a_coef, zpet_b_coef, zpeq_b_coef,                           &
               'OK'                                                                          )  
!
!-------------------------------------------------------------------------------------
!
!*      4.     Optional modification of turbulent energy and gaz fluxes 
!              --------------------------------------------------------
!
IF(.NOT.lnosof)THEN
  psfth(:)  = psfth(:) * z3d_tot_surf(:)
  psftq(:)  = psftq(:) * z3d_tot_surf(:)
  psfco2(:)  = psfco2(:) * z3d_tot_surf(:)
  DO jsv=1,SIZE(psfts,2)
    psfts(:,jsv)  = psfts(:,jsv) * z3d_tot_surf(:)
  END DO
ENDIF
!
IF (lhook) CALL dr_hook('COUPLING_ISBA_OROGRAPHY_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE coupling_isba_orography_n