writesurf_tebn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE writesurf_teb_n (HSELECT, OSNOWDIMNC, DTCO, U, TOP, BOP, T, B, ODATA_ROAD_DIR, TPN, &
                                  GDO, GDS, GDPEK, GRO, GRS, GRPEK, HPROGRAM,KPATCH,HWRITE)
!     ####################################
!
!!****  *WRITE_TEB_n* - writes TEB fields
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERGREENROOFE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_bem_option_n, ONLY : bem_options_t
USE modd_teb_n, ONLY : teb_t
USE modd_bem_n, ONLY : bem_t
USE modd_teb_panel_n, ONLY : teb_panel_t
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_pe_t, isba_s_t
!
USE modn_prep_surf_atm, ONLY : lwrite_extern
!
USE modi_end_io_surf_n
USE modi_init_io_surf_n
!
USE modi_write_surf
USE modi_writesurf_gr_snow
USE modi_writesurf_teb_garden_n
USE modi_writesurf_teb_greenroof_n
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!RJ #ifdef SFX_MPI
!RJ INCLUDE "mpif.h"
!RJ #endif
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT 
LOGICAL, INTENT(IN) :: OSNOWDIMNC
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(teb_options_t), INTENT(IN) :: TOP
TYPE(bem_options_t), INTENT(IN) :: BOP
TYPE(teb_t), INTENT(IN) :: T
TYPE(bem_t), INTENT(IN) :: B
LOGICAL, INTENT(IN) :: ODATA_ROAD_DIR
TYPE(teb_panel_t), INTENT(INOUT) :: TPN
TYPE(isba_options_t), INTENT(IN) :: GDO
TYPE(isba_s_t), INTENT(INOUT) :: GDS
TYPE(isba_pe_t), INTENT(IN) :: GDPEK
TYPE(isba_options_t), INTENT(IN) :: GRO
TYPE(isba_s_t), INTENT(INOUT) :: GRS
TYPE(isba_pe_t), INTENT(IN) :: GRPEK
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! program calling
INTEGER,           INTENT(IN)  :: KPATCH   ! current TEB patch
 CHARACTER(LEN=3),    INTENT(IN)  :: HWRITE    ! 'PREP' : does not write SBL XUNDEF fields
!                                             ! 'ALL' : all fields are written
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(0,0,1) :: ZWSN_WR, ZRHO_WR, ZHEA_WR, ZAGE_WR, ZSG1_WR, ZSG2_WR, ZHIS_WR
REAL, DIMENSION(0,1) :: ZALB_WR
!
INTEGER, DIMENSION(SIZE(T%XT_ROOF,1)) :: IMASK
INTEGER           :: IRESP           ! IRESP  : return-code if a problem appears
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
 CHARACTER(LEN=100):: YCOMMENT       ! Comment string
 CHARACTER(LEN=3)  :: YPATCH         ! Patch identificator
 CHARACTER(LEN=7)  :: YDIR           ! Direction identificator
 CHARACTER(LEN=100):: YSTRING        ! Comment string
!
INTEGER :: JLAYER, JI ! loop on surface layers
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('WRITESURF_TEB_N',0,zhook_handle)
!
ypatch='   '
IF (top%NTEB_PATCH>1) WRITE(ypatch,fmt='(A,I1,A)') 'T',kpatch,'_'
!
!
!*       2.     Option for road orientation:
!               ---------------------------
!
ycomment='Option for Road orientation in TEB scheme'
 CALL write_surf(hselect,hprogram,'ROAD_DIR',top%CROAD_DIR,iresp,ycomment)
ycomment='Option for Wall representation in TEB scheme'
 CALL write_surf(hselect,hprogram,'WALL_OPT',top%CWALL_OPT,iresp,ycomment)
!
!*       3.     Prognostic fields:
!               -----------------
!
!* roof temperatures
!

DO jlayer=1,top%NROOF_LAYER
  WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TROOF',jlayer,' '
  WRITE(ycomment,'(A9,I1.1,A4)') 'X_Y_TROOF',jlayer,' (K)'
  yrecfm=adjustl(yrecfm)
 CALL write_surf(hselect,hprogram,yrecfm,t%XT_ROOF(:,jlayer),iresp,hcomment=ycomment)
END DO

!
!* roof water content
!

yrecfm=ypatch//'WS_ROOF'
yrecfm=adjustl(yrecfm)
ycomment='WS_ROOF (kg/m2)'
 CALL write_surf(hselect,hprogram,yrecfm,t%XWS_ROOF(:),iresp,hcomment=ycomment)
!
!* road temperatures
!

DO jlayer=1,top%NROAD_LAYER
  WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TROAD',jlayer,' '
  yrecfm=adjustl(yrecfm)
  IF (top%CROAD_DIR=='UNIF' .OR. odata_road_dir) THEN
    ystring = 'X_Y_TROAD'
  ELSEIF (SIZE(t%XROAD_DIR)>0) THEN
    !* road direction is uniform spatially, one can then indicate it in the comment
    CALL road_dir(t%XROAD_DIR(1),ydir)
    ystring=trim(ydir)//' ROAD TEMP. LAYER '
  ELSE
    ystring='? ROAD TEMP. LAYER '
  ENDIF
  WRITE(ycomment,'(A,I1.1,A4)') trim(ystring), jlayer,' (K)'
  CALL write_surf(hselect,hprogram,yrecfm,t%XT_ROAD(:,jlayer),iresp,hcomment=ycomment)
END DO
!
!* road water content
!

yrecfm=ypatch//'WS_ROAD'
yrecfm=adjustl(yrecfm)
ycomment='WS_ROAD (kg/m2)'
 CALL write_surf(hselect,hprogram,yrecfm,t%XWS_ROAD(:),iresp,hcomment=ycomment)
!
!* wall temperatures
!

DO jlayer=1,top%NWALL_LAYER
 IF (top%CWALL_OPT=='UNIF') THEN
  WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TWALL',jlayer,' '
  yrecfm=adjustl(yrecfm)
  WRITE(ycomment,'(A9,I1.1,A4)') 'X_Y_TWALL',jlayer,' (K)'
  CALL write_surf(hselect,hprogram,yrecfm,t%XT_WALL_A(:,jlayer),iresp,hcomment=ycomment)
 ELSE
  !* Wall A
  WRITE(yrecfm,'(A3,A6,I1.1)') ypatch,'TWALLA',jlayer
  yrecfm=adjustl(yrecfm)
  IF (odata_road_dir) THEN
    ystring = 'X_Y_TWALL_A'
  ELSEIF (SIZE(t%XROAD_DIR)>0) THEN
    !* wall direction is uniform spatially, one can then indicate it in the comment
    CALL walla_dir(t%XROAD_DIR(1),ydir)
    ystring=trim(ydir)//'-FACING WALL TEMP. LAYER '
  ELSE
    ystring='?-FACING WALL TEMP. LAYER '
  ENDIF
  WRITE(ycomment,'(A,I1.1,A4)') trim(ystring), jlayer,' (K)'
  CALL write_surf(hselect,hprogram,yrecfm,t%XT_WALL_A(:,jlayer),iresp,hcomment=ycomment)
  !
  !* Wall B
  WRITE(yrecfm,'(A3,A6,I1.1)') ypatch,'TWALLB',jlayer
  yrecfm=adjustl(yrecfm)
  IF (odata_road_dir) THEN
    ystring = 'X_Y_TWALL_B'
  ELSEIF (SIZE(t%XROAD_DIR)>0) THEN
    !* wall direction is uniform spatially, one can then indicate it in the comment
    CALL wallb_dir(t%XROAD_DIR(1),ydir)
    ystring=trim(ydir)//'-FACING WALL TEMP. LAYER '
  ELSE
    ystring='?-FACING WALL TEMP. LAYER '
  ENDIF
  WRITE(ycomment,'(A,I1.1,A4)') trim(ystring), jlayer,' (K)'
  CALL write_surf(hselect,hprogram,yrecfm,t%XT_WALL_B(:,jlayer),iresp,hcomment=ycomment)
 END IF
END DO
!
IF (lwrite_extern) THEN
  !
  DO jlayer=1,top%NROOF_LAYER
    WRITE(yrecfm,fmt='(A,I1.1)') 'D_ROOF',jlayer
    ycomment='Roof layer thickness'
    CALL write_surf(hselect, &
                 hprogram,yrecfm,t%XD_ROOF(:,jlayer),iresp,hcomment=ycomment)
  END DO
  DO jlayer=1,top%NWALL_LAYER
    WRITE(yrecfm,fmt='(A,I1.1)') 'D_WALL',jlayer
    ycomment='WALL layer thickness'
    CALL write_surf(hselect,hprogram,yrecfm,t%XD_WALL(:,jlayer),iresp,hcomment=ycomment)
  END DO
  DO jlayer=1,top%NROAD_LAYER
    WRITE(yrecfm,fmt='(A,I1.1)') 'D_ROAD',jlayer
    ycomment='ROAD layer thickness'
    CALL write_surf(hselect,hprogram,yrecfm,t%XD_ROAD(:,jlayer),iresp,hcomment=ycomment)
  END DO
  IF (top%CBEM=='BEM') THEN
    DO jlayer=1,bop%NFLOOR_LAYER
      WRITE(yrecfm,fmt='(A,I1.1)') 'D_FLOOR',jlayer
      ycomment='FLOOR layer thickness'
      CALL write_surf(hselect,hprogram,yrecfm,b%XD_FLOOR(:,jlayer),iresp,hcomment=ycomment)
    END DO
  ENDIF
  !
ENDIF
!
!* internal building temperature
!
yrecfm=ypatch//'TI_BLD'
yrecfm=adjustl(yrecfm)
ycomment='TI_BLD (K)'
 CALL write_surf(hselect,hprogram,yrecfm,b%XTI_BLD(:),iresp,hcomment=ycomment)
!
!
!* outdoor window temperature
!
yrecfm=ypatch//'T_WIN1'
yrecfm=adjustl(yrecfm)
ycomment='T_WIN1 (K)'
 CALL write_surf(hselect,hprogram,yrecfm,b%XT_WIN1(:),iresp,hcomment=ycomment)
!
IF (top%CBEM=='BEM') THEN
!* internal building specific humidity
!
yrecfm=ypatch//'QI_BLD'
yrecfm=adjustl(yrecfm)
ycomment='QI_BLD (kg/kg)'
 CALL write_surf(hselect,hprogram,yrecfm,b%XQI_BLD(:),iresp,hcomment=ycomment)
!
  !
  !* indoor window temperature
  !
  yrecfm=ypatch//'T_WIN2'
  yrecfm=adjustl(yrecfm)
  ycomment='T_WIN2 (K)'
  CALL write_surf(hselect,hprogram,yrecfm,b%XT_WIN2(:),iresp,hcomment=ycomment)
  !
  !* floor temperatures
  !
  DO jlayer=1,bop%NFLOOR_LAYER
    WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TFLOO',jlayer,' '
    WRITE(ycomment,'(A9,I1.1,A4)') 'X_Y_TFLOO',jlayer,' (K)'
    yrecfm=adjustl(yrecfm)
    CALL write_surf(hselect,hprogram,yrecfm,b%XT_FLOOR(:,jlayer),iresp,hcomment=ycomment)
  END DO
  !
  !* internal th. mass temperature
  !
  DO jlayer=1,bop%NFLOOR_LAYER
    WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TMASS',jlayer,' '
    WRITE(ycomment,'(A9,I1.1,A4)') 'X_Y_TMASS',jlayer,' (K)'
    yrecfm=adjustl(yrecfm)
    CALL write_surf(hselect,hprogram,yrecfm,b%XT_MASS(:,jlayer),iresp,hcomment=ycomment)
  END DO        
  !
ENDIF
!
!* deep road temperature
!
yrecfm=ypatch//'TI_ROAD'
yrecfm=adjustl(yrecfm)
ycomment='TI_ROAD (K)'
 CALL write_surf(hselect,hprogram,yrecfm,t%XTI_ROAD(:),iresp,hcomment=ycomment)
!
!* snow mantel
!*  
DO ji = 1,SIZE(t%XT_ROOF,1)
 imask(ji) = ji
ENDDO 
!
yrecfm='RF'
 CALL writesurf_gr_snow(osnowdimnc,hselect,hprogram,yrecfm,ypatch,&
                        SIZE(t%XT_ROOF,1),imask,0,t%TSNOW_ROOF, &
                        zwsn_wr,zrho_wr,zhea_wr,zage_wr,zsg1_wr, &
                        zsg2_wr,zhis_wr,zalb_wr)
!
yrecfm='RD'
 CALL writesurf_gr_snow(osnowdimnc,hselect,hprogram,yrecfm,ypatch,&
                        SIZE(t%XT_ROOF,1),imask,0,t%TSNOW_ROAD, &
                        zwsn_wr,zrho_wr,zhea_wr,zage_wr,zsg1_wr, &
                        zsg2_wr,zhis_wr,zalb_wr)
!
!-------------------------------------------------------------------------------
!
!*       4.     Semi-prognostic fields:
!               ----------------------
!
!* temperature of canyon air
!
yrecfm=ypatch//'TCANYON'
yrecfm=adjustl(yrecfm)
ycomment='T_CANYON (K)'
 CALL write_surf(hselect,hprogram,yrecfm,t%XT_CANYON(:),iresp,hcomment=ycomment)
!
!* humidity of canyon air
!
yrecfm=ypatch//'QCANYON'
yrecfm=adjustl(yrecfm)
ycomment='Q_CANYON (kg/kg)'
 CALL write_surf(hselect,hprogram,yrecfm,t%XQ_CANYON(:),iresp,hcomment=ycomment)
!
!
!* Thermal solar panels present day production
!
IF (top%LSOLAR_PANEL) THEN
  yrecfm=ypatch//'THER_PDAY'
  yrecfm=adjustl(yrecfm)
  ycomment='Thermal Solar Panels present day production (J/m2)'
  IF (.NOT. ASSOCIATED(tpn%XTHER_PRODC_DAY)) THEN
    ! for PREP cases
    ALLOCATE(tpn%XTHER_PRODC_DAY(SIZE(b%XTI_BLD)))
    tpn%XTHER_PRODC_DAY=0.
  END IF
  CALL write_surf(hselect,hprogram,yrecfm,tpn%XTHER_PRODC_DAY(:),iresp,hcomment=ycomment)
END IF
!-------------------------------------------------------------------------------
!
!*       5.  Time
!            ----
!
IF (kpatch==1) THEN
  yrecfm='DTCUR'
  ycomment='s'
  CALL write_surf(hselect,hprogram,yrecfm,top%TTIME,iresp,hcomment=ycomment)
END IF
!
!
!-------------------------------------------------------------------------------
!
!*       6.  Urban green areas
!            ------------------
!
! Gardens
IF (top%LGARDEN) THEN
  CALL end_io_surf_n(hprogram)
  CALL init_io_surf_n(dtco, u, hprogram,'TOWN  ','TEB   ','WRITE','GARDEN_PROGNOSTIC.OUT.nc')
  CALL writesurf_teb_garden_n(hselect, osnowdimnc, gdo, gds, gdpek, hprogram,ypatch)
ENDIF
!
! Grenn roofs
IF (top%LGREENROOF) THEN
  CALL end_io_surf_n(hprogram)
  CALL init_io_surf_n(dtco, u, hprogram,'TOWN  ','TEB   ','WRITE','GREENROOF_PROGNOSTIC.OUT.nc')
  CALL writesurf_teb_greenroof_n(hselect, osnowdimnc, gro, grs, grpek, hprogram,ypatch)
ENDIF
!
IF (lhook) CALL dr_hook('WRITESURF_TEB_N',1,zhook_handle)
!
!
!-------------------------------------------------------------------------------
CONTAINS
SUBROUTINE road_dir(PDIR,HDIR)
REAL,             INTENT(IN)  :: PDIR
 CHARACTER(LEN=7), INTENT(OUT) :: HDIR
REAL :: ZDIR
zdir=pdir
IF (pdir<0) zdir = pdir +360.
IF (zdir>=  0.   .AND. zdir< 11.25) hdir='N-S    '
IF (zdir>= 11.25 .AND. zdir< 33.75) hdir='NNE-SSW'
IF (zdir>= 33.75 .AND. zdir< 56.25) hdir='NE-SW'
IF (zdir>= 56.25 .AND. zdir< 78.75) hdir='ENE-WSW'
IF (zdir>= 78.75 .AND. zdir<101.25) hdir='E-W    '
IF (zdir>=101.25 .AND. zdir<123.75) hdir='ESE-WNW'
IF (zdir>=123.75 .AND. zdir<146.25) hdir='SE-NW  '
IF (zdir>=146.25 .AND. zdir<168.75) hdir='SSE-NNW'
IF (zdir>=168.75 .AND. zdir<180.00) hdir='N-S    '
END SUBROUTINE road_dir
SUBROUTINE walla_dir(PDIR,HDIR)
REAL,             INTENT(IN)  :: PDIR
 CHARACTER(LEN=7), INTENT(OUT) :: HDIR
REAL :: ZDIR
zdir=pdir
IF (pdir<0) zdir = pdir +360.
IF (zdir>=  0.   .AND. zdir< 11.25) hdir='E      '
IF (zdir>= 11.25 .AND. zdir< 33.75) hdir='ESE    '
IF (zdir>= 33.75 .AND. zdir< 56.25) hdir='SE     ' 
IF (zdir>= 56.25 .AND. zdir< 78.75) hdir='SSE    '
IF (zdir>= 78.75 .AND. zdir<101.25) hdir='S      '
IF (zdir>=101.25 .AND. zdir<123.75) hdir='SSW    '
IF (zdir>=123.75 .AND. zdir<146.25) hdir='SW     '
IF (zdir>=146.25 .AND. zdir<168.75) hdir='WSW    '
IF (zdir>=168.75 .AND. zdir<180.00) hdir='W      '
END SUBROUTINE walla_dir
SUBROUTINE wallb_dir(PDIR,HDIR)
REAL,             INTENT(IN)  :: PDIR
 CHARACTER(LEN=7), INTENT(OUT) :: HDIR
REAL :: ZDIR
zdir=pdir
IF (pdir<0) zdir = pdir +360.
IF (zdir>=  0.   .AND. zdir< 11.25) hdir='W      '
IF (zdir>= 11.25 .AND. zdir< 33.75) hdir='WNW    '
IF (zdir>= 33.75 .AND. zdir< 56.25) hdir='NW     ' 
IF (zdir>= 56.25 .AND. zdir< 78.75) hdir='NNW    '
IF (zdir>= 78.75 .AND. zdir<101.25) hdir='N      '
IF (zdir>=101.25 .AND. zdir<123.75) hdir='NNE    '
IF (zdir>=123.75 .AND. zdir<146.25) hdir='NE     '
IF (zdir>=146.25 .AND. zdir<168.75) hdir='ENE    '
IF (zdir>=168.75 .AND. zdir<180.00) hdir='E      '
END SUBROUTINE wallb_dir
!-------------------------------------------------------------------------------
!
END SUBROUTINE writesurf_teb_n