writesurf_teb_gardenn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE writesurf_teb_garden_n (HSELECT, OSNOWDIMNC, IO, S, PEK, HPROGRAM,HPATCH)
!     #####################################
!
!!****  *WRITESURF_TEB_GARDEN_n* - writes ISBA prognostic fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      P. LeMoigne 12/2004 : correct dimensionning if more than 10 layers in
!!                            the soil (diffusion version)
!!      B. Decharme  2008    : Floodplains
!!      B. Decharme  01/2009 : Optional Arpege deep soil temperature write
!!      B. Decharme  09/2012 : suppress NWG_LAYER (parallelization problems)
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_pe_t, isba_s_t
!
USE modd_surf_par, ONLY : nundef
!
USE modi_write_surf
USE modi_writesurf_gr_snow
USE modd_dst_surf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
 CHARACTER(LEN=*), DIMENSION(:), INTENT(IN) :: HSELECT 
LOGICAL, INTENT(IN) :: OSNOWDIMNC
!
TYPE(isba_options_t), INTENT(IN) :: IO
TYPE(isba_s_t), INTENT(INOUT) :: S
TYPE(isba_pe_t), INTENT(IN) :: PEK
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! program calling
 CHARACTER(LEN=3),  INTENT(IN)  :: HPATCH   ! current teb patch
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER, DIMENSION(SIZE(PEK%XTG,1)) :: IMASK_P
INTEGER           :: IRESP          ! IRESP  : return-code if a problem appears
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
 CHARACTER(LEN=100):: YCOMMENT       ! Comment string
 CHARACTER(LEN=14) :: YFORM          ! Writing format
 CHARACTER(LEN=4 ) :: YLVL
!
INTEGER :: JL, JI ! loop counter on soil layers
!
REAL, DIMENSION(:),ALLOCATABLE  :: ZWORK      ! 2D array to write data in file
!
INTEGER :: JNBIOMASS
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!------------------------------------------------------------------------------
!
!*       2.     Prognostic fields:
!               -----------------
!
IF (lhook) CALL dr_hook('WRITESURF_TEB_GARDEN_N',0,zhook_handle)
ALLOCATE(zwork(SIZE(pek%XTG,1)))
!* soil temperatures
!
DO jl=1,io%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jl
  yrecfm=hpatch//'GD_TG'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  yform='(A11,I1.1,A4)'
  IF (jl >= 10)  yform='(A11,I2.2,A4)'
  WRITE(ycomment,fmt=yform) 'X_Y_GD_TG',jl,' (K)'
  zwork=pek%XTG(:,jl)
  CALL write_surf(hselect,hprogram,yrecfm,zwork,iresp,hcomment=ycomment)
END DO
!
!
!* soil liquid water content
!
DO jl=1,io%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jl
  yrecfm=hpatch//'GD_WG'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  yform='(A11,I1.1,A8)'
  IF (jl >= 10)  yform='(A11,I2.2,A8)'
  WRITE(ycomment,fmt=yform) 'X_Y_GD_WG',jl,' (m3/m3)'
  zwork=pek%XWG(:,jl)
  CALL write_surf(hselect,hprogram,yrecfm,zwork,iresp,hcomment=ycomment)
END DO
!
!
!* soil ice water content
!
DO jl=1,io%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jl
  yrecfm=hpatch//'GD_WGI'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  yform='(A11,I1.1,A8)'
  IF (jl >= 10)  yform='(A11,I2.2,A8)'
  WRITE(ycomment,yform) 'X_Y_GD_WGI',jl,' (m3/m3)'
  zwork=pek%XWGI(:,jl)
  CALL write_surf(hselect,hprogram,yrecfm,zwork,iresp,hcomment=ycomment)
END DO
!
DEALLOCATE(zwork)
!
!* water intercepted on leaves
!
yrecfm=hpatch//'GD_WR'
yrecfm=adjustl(yrecfm)
ycomment='X_Y_GD_WR (kg/m2)'
 CALL write_surf(hselect,hprogram,yrecfm,pek%XWR(:),iresp,hcomment=ycomment)
!
!* Leaf Area Index
!
IF (io%CPHOTO/='NON' .AND. io%CPHOTO/='AST') THEN
  yrecfm=hpatch//'GD_LAI'
  yrecfm=adjustl(yrecfm)
  ycomment='X_Y_GD_LAI (m2/m2)'
 CALL write_surf(hselect,hprogram,yrecfm,pek%XLAI(:),iresp,hcomment=ycomment)
END IF
!
IF (io%CPHOTO=='NIT') THEN
  !
  DO jnbiomass=1,io%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    yrecfm=hpatch//'GD_BIOMA'//adjustl(ylvl(:len_trim(ylvl)))
    yrecfm=adjustl(yrecfm)
    yform='(A11,I1.1,A8)'
    WRITE(ycomment,fmt=yform) 'X_Y_BIOMASS',jnbiomass,' (kg/m2)'
    CALL write_surf(hselect,hprogram,yrecfm,pek%XBIOMASS(:,jnbiomass),iresp,hcomment=ycomment)
  END DO
  !
  !
  DO jnbiomass=2,io%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    yrecfm=hpatch//'GD_RESPI'//adjustl(ylvl(:len_trim(ylvl)))
    yrecfm=adjustl(yrecfm)
    yform='(A16,I1.1,A10)'
    WRITE(ycomment,fmt=yform) 'X_Y_RESP_BIOMASS',jnbiomass,' (kg/m2/s)'
    CALL write_surf(hselect,hprogram,yrecfm,pek%XRESP_BIOMASS(:,jnbiomass),iresp,hcomment=ycomment)
  END DO
  !
END IF
!
!* aerodynamical resistance
!
yrecfm=hpatch//'GD_RES'
yrecfm=adjustl(yrecfm)
ycomment='X_Y_GD_RESA (s/m)'
 CALL write_surf(hselect,hprogram,yrecfm,pek%XRESA(:),iresp,hcomment=ycomment)
!
!* snow mantel
!
yrecfm='GD'
DO ji = 1,SIZE(imask_p)
  imask_p(ji) = ji
ENDDO
 CALL writesurf_gr_snow(osnowdimnc, hselect, hprogram, yrecfm, hpatch,&
                        SIZE(pek%XTG,1), imask_p, 0, pek%TSNOW, s%XWSN_WR, &
                        s%XRHO_WR, s%XHEA_WR, s%XAGE_WR, s%XSG1_WR, s%XSG2_WR, &
                        s%XHIS_WR, s%XALB_WR)
!
IF (lhook) CALL dr_hook('WRITESURF_TEB_GARDEN_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE writesurf_teb_garden_n