water_flux.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE water_flux(PZ0SEA,                                         &
                              PTA, PEXNA, PRHOA, PSST, PEXNS, PQA, PRR, PRS,  &
                              PTT, PVMOD, PZREF, PUREF,                       &
                              PPS, OHANDLE_SIC, PQSAT,                        &
                              PSFTH, PSFTQ, PUSTAR,                           &
                              PCD, PCDN, PCH, PRI, PRESA, PZ0HSEA             )  
!     #######################################################################
!
!
!!****  *WATER_FLUX*  
!!
!!    PURPOSE
!!    -------
!      Calculate the surface fluxes of heat, moisture, and momentum over
!      water surfaces.  
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original      01/09/95 
!!      (J.Stein)     16/11/95  use PUSLOPE and Theta to compute Ri
!!      (P.Lacarrere) 19/03/96  bug in the ZTHVI and ZTHVIS computations
!!      (J.Stein)     27/03/96  use only H and LE in the soil scheme
!!      (P.Jabouille) 12/11/96  bug in the Z0 computation
!!      (V.Masson)    01/02/00  detection of sea ice
!!      (P. Tulet)    01/10/03  aerodynamical resistance output
!!      (P. LeMoigne) 29/03/04  bug in the heat flux computation
!!      (P. LeMoigne) 29/03/04  use z0h for diagnostics (ice)
!!      (P. LeMoigne) 20/06/07  minimum wind speed and/or shear
!!      B. Decharme    06/2009 limitation of Ri
!!      B. Decharme    09/2012 limitation of Ri in surface_ri.F90
!!      B. Decharme    06/2013 Charnock number according to coare3.0
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts,       ONLY : xg, xcpd, xlstt
USE modd_surf_par,   ONLY : xundef
USE modd_snow_par,   ONLY : xz0sn, xz0hsn
!
USE modi_surface_ri
USE modi_surface_aero_cond
USE modi_surface_cd
USE modi_surface_cdch_1darp
USE modi_wind_threshold
!
USE mode_thermos
!
USE modd_surf_atm,    ONLY : ldrag_coef_arp, xvchrnk, xvz0cm, lvziustar0_arp, xvziustar0,  &
                               lrrgust_arp, xrrscale, xrrgamma, xutilgust, xrzhz0m
!
USE modd_reprod_oper,  ONLY : ccharnock
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL, DIMENSION(:), INTENT(IN)       :: PTA   ! air temperature at atm. level
REAL, DIMENSION(:), INTENT(IN)       :: PQA   ! air humidity at atm. level (kg/kg)
REAL, DIMENSION(:), INTENT(IN)       :: PEXNA ! Exner function at atm. level
REAL, DIMENSION(:), INTENT(IN)       :: PRHOA ! air density at atm. level
REAL, DIMENSION(:), INTENT(IN)       :: PVMOD ! module of wind at atm. wind level
REAL, DIMENSION(:), INTENT(IN)       :: PZREF ! atm. level for temp. and humidity
REAL, DIMENSION(:), INTENT(IN)       :: PUREF ! atm. level for wind
REAL, DIMENSION(:), INTENT(IN)       :: PSST  ! Sea Surface Temperature
REAL, DIMENSION(:), INTENT(IN)       :: PEXNS ! Exner function at sea surface
REAL, DIMENSION(:), INTENT(IN)       :: PPS   ! air pressure at sea surface
LOGICAL,            INTENT(IN)       :: OHANDLE_SIC ! if TRUE, do not care to detect seaice
REAL, DIMENSION(:), INTENT(IN)       :: PRR   ! rain rate
REAL, DIMENSION(:), INTENT(IN)       :: PRS   ! snow rate
REAL,               INTENT(IN)       :: PTT   ! temperature of freezing point
!
REAL, DIMENSION(:), INTENT(INOUT)    :: PZ0SEA! roughness length over the ocean
!                                         
!                                         
!  surface fluxes : latent heat, sensible heat, friction fluxes
REAL, DIMENSION(:), INTENT(OUT)      :: PSFTH ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(OUT)      :: PSFTQ ! water flux (kg/m2/s)
REAL, DIMENSION(:), INTENT(OUT)      :: PUSTAR! friction velocity (m/s)
!
! diagnostics
REAL, DIMENSION(:), INTENT(OUT)      :: PQSAT ! humidity at saturation
REAL, DIMENSION(:), INTENT(OUT)      :: PCD   ! heat drag coefficient
REAL, DIMENSION(:), INTENT(OUT)      :: PCDN  ! momentum drag coefficient
REAL, DIMENSION(:), INTENT(OUT)      :: PCH   ! neutral momentum drag coefficient
REAL, DIMENSION(:), INTENT(OUT)      :: PRI   ! Richardson number
REAL, DIMENSION(:), INTENT(OUT)      :: PRESA ! aerodynamical resistance
REAL, DIMENSION(:), INTENT(OUT)      :: PZ0HSEA ! heat roughness length over the ocean
!
!
!*      0.2    declarations of local variables
!
!
REAL, DIMENSION(SIZE(PTA)) :: ZVMOD     ! wind modulus
REAL, DIMENSION(SIZE(PTA)) :: ZUSTAR2   ! square of friction velocity
REAL, DIMENSION(SIZE(PTA)) :: ZAC       ! Aerodynamical conductance
REAL, DIMENSION(SIZE(PTA)) :: ZRA       ! Aerodynamical resistance
REAL, DIMENSION(SIZE(PTA)) :: ZDIRCOSZW ! orography slope cosine (=1 on water!)
REAL, DIMENSION(SIZE(PTA)) :: ZFP       ! working variable
REAL, DIMENSION(SIZE(PTA)) :: ZRRCOR    ! correction of CD, CH, CDN due to moist-gustiness
REAL, DIMENSION(SIZE(PTA)) :: ZCHARN    ! Charnock number
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!       1.     Initializations
!              ---------------
!
IF (lhook) CALL dr_hook('WATER_FLUX',0,zhook_handle)
zdircoszw=1.
!
pri(:) = xundef
pch(:) = xundef
pcd(:) = xundef
pcdn(:) = xundef
!
psfth(:)=xundef
psftq(:)=xundef
pustar(:)=xundef
presa(:)=xundef
!
!
!       1.1    Saturated specified humidity near the water surface
!              ---------------------------------------------------
!
pqsat(:) = qsat(psst(:),pps(:))
!
!
!       1.2    Wind speed threshold
!              --------------------
!
zvmod(:)=wind_threshold(pvmod(:),puref(:))
!
!       1.3    Charnock number
!              ---------------
!
IF(ccharnock=='OLD')THEN
  zcharn(:) = xvchrnk
ELSE
! vary between 0.011 et 0.018 according to Chris Fairall's data as in coare3.0        
  zcharn(:) = max(0.011,min(0.018,0.011+0.007*(zvmod(:)-10.)/8.))
ENDIF
!
!-------------------------------------------------------------------------------
!
!       2.     Calculate the drag coefficient for momentum (PCD)
!              -------------------------------------------------
!
!       2.1    Richardson number
!              -----------------
!
 CALL surface_ri(psst,pqsat,pexns,pexna,pta,pqa,  &
                pzref, puref, zdircoszw,pvmod,pri)
!
!       2.2    Detection of sea ice
!              --------------------
!
IF (lvziustar0_arp) THEN
   pz0hsea(:)=min(pz0sea(:),pz0sea(:)*xrzhz0m)
ELSE
   pz0hsea(:)=pz0sea(:)
ENDIF
!
IF (.NOT.ohandle_sic ) THEN 
   WHERE (psst(:) < ptt)
      pz0hsea(:) = xz0hsn
   END WHERE
ENDIF
!
!       2.3    Drag coefficient
!              ----------------
!
IF (ldrag_coef_arp) THEN
 
  CALL surface_cdch_1darp(pzref, pz0sea, pz0hsea, zvmod, pta, psst, &
                          pqa, pqsat, pcd, pcdn, pch                )  

  zra(:) = 1. / ( pch(:) * zvmod(:) )
!
ELSE
!
  CALL surface_cd(pri, pzref, puref, pz0sea, pz0hsea, pcd, pcdn)
!
ENDIF
!
!-------------------------------------------------------------------------------
!
!       3.     Calculate u* and the roughness length over the ocean
!              ----------------------------------------------------
!
!                              According to Charnock's expression...
!
zustar2(:) = pcd(:)*zvmod(:)*zvmod(:)
!
pz0sea(:) = zcharn(:) * zustar2(:) / xg + xvz0cm * pcd(:) / pcdn(:)
!
IF (lvziustar0_arp .AND. xvziustar0>0.) THEN
    pz0hsea(:)=pz0sea(:)*exp(-sqrt(zustar2(:))*xvziustar0)
ELSE
    pz0hsea(:)=pz0sea(:)
ENDIF
!
IF (.NOT.ohandle_sic ) THEN 
   WHERE (psst(:) < ptt)
          pz0sea(:) = xz0sn
   END WHERE
ENDIF
!
!-------------------------------------------------------------------------------
!
!       4.     Drag coefficient for heat and aerodynamical resistance
!              -------------------------------------------------------
!
IF (.NOT.ldrag_coef_arp) THEN
   CALL surface_aero_cond(pri, pzref, puref, zvmod, pz0sea, pz0hsea, zac, zra, pch)
ENDIF
!
IF (lrrgust_arp) THEN
  zfp(:)=max(0.0,prr(:)+prs(:))
  zrrcor(:)=sqrt(1.0+((((zfp(:)/(zfp(:)+xrrscale))**xrrgamma)*xutilgust)**2) &
      /(pcd(:)*zvmod(:)**2))  

  pcd  = pcd*zrrcor
  pch  = pch*zrrcor
  pcdn = pcdn*zrrcor
ENDIF
!
presa(:) = zra(:)
!
!-------------------------------------------------------------------------------
!
!       5.     The fluxes
!              ----------
!
psfth(:) =  xcpd * prhoa(:) * pch(:) * zvmod(:) * ( psst(:) -pta(:) * pexns(:) / pexna(:) ) / pexns(:)
psftq(:) =  prhoa(:) * pch(:) * zvmod(:) * ( pqsat(:)-pqa(:) )
pustar(:) = sqrt(zustar2(:))
!
IF (lhook) CALL dr_hook('WATER_FLUX',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE water_flux