surface_aero_cond.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!   ######################################################################
    SUBROUTINE surface_aero_cond(PRI, PZREF, PUREF, PVMOD, PZ0,&
                                     PZ0H, PAC, PRA, PCH           ) 
!   ######################################################################
!
!!****  *SURFACE_AERO_COND*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the drag coefficients for heat and momentum near the ground
!         
!     
!!**  METHOD
!!    ------
!
!
!
!    1 and 2 : computation of relative humidity near the ground
!
!    3 : richardson number
!
!    4 : the aerodynamical resistance for heat transfers is deduced
!
!    5 : the drag coefficient for momentum ZCD is computed
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    20/01/98 
!!                  02/04/01 (P Jabouille) limitation of Z0 with 0.5 PUREF
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts,ONLY : xkarman
USE modi_wind_threshold
!
USE mode_thermos
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL, DIMENSION(:), INTENT(IN)    :: PRI      ! Richardson number
REAL, DIMENSION(:), INTENT(IN)    :: PVMOD    ! module of the horizontal wind
REAL, DIMENSION(:), INTENT(IN)    :: PZREF    ! reference height of the first
                                              ! atmospheric level
REAL, DIMENSION(:), INTENT(IN)    :: PUREF    ! reference height of the wind
                                              ! NOTE this is different from ZZREF
                                              ! ONLY in stand-alone/forced mode,
                                              ! NOT when coupled to a model (MesoNH)
REAL, DIMENSION(:), INTENT(IN)    :: PZ0      ! roughness length for momentum
REAL, DIMENSION(:), INTENT(IN)    :: PZ0H     ! roughness length for heat
!
REAL, DIMENSION(:), INTENT(OUT)   :: PAC      ! aerodynamical conductance
REAL, DIMENSION(:), INTENT(OUT)   :: PRA      ! aerodynamical resistance
REAL, DIMENSION(:), INTENT(OUT)   :: PCH      ! drag coefficient for heat
!
!*      0.2    declarations of local variables
!
!
REAL, DIMENSION(SIZE(PRI)) :: ZZ0, ZZ0H, ZMU,          &
                               ZFH, ZCHSTAR, ZPH, ZCDN, &
                               ZSTA, ZDI, ZWORK1, ZWORK2, ZWORK3 
REAL, DIMENSION(SIZE(PRI)) :: ZVMOD
!
INTEGER                    :: JJ
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
! Functions:
REAL :: X, CHSTAR, PH
chstar(x) = 3.2165 + 4.3431*x + 0.5360*x*x - 0.0781*x*x*x
ph(x) = 0.5802 - 0.1571*x + 0.0327*x*x - 0.0026*x*x*x
!
!-------------------------------------------------------------------------------
!
!*       4.     Surface aerodynamic resistance for heat transfers
!               -------------------------------------------------
!
IF (lhook) CALL dr_hook('SURFACE_AERO_COND',0,zhook_handle)
zvmod(:) = wind_threshold(pvmod(:),puref(:))
!
DO jj=1,SIZE(pri)

  zz0(jj)  = min(pz0(jj),puref(jj)*0.5)
  zz0h(jj) = min(zz0(jj),pz0h(jj))
  zz0h(jj) = min(zz0h(jj),pzref(jj)*0.5)
!
  zwork1(jj)=log( puref(jj)/zz0(jj) )
  zwork2(jj)=pzref(jj)/zz0h(jj)
  zwork3(jj)=zvmod(jj)*zvmod(jj)

  zmu(jj) = max( log( zz0(jj)/zz0h(jj) ), 0.0 )
  zfh(jj) = zwork1(jj) / log(zwork2(jj))
!
  zchstar(jj) = chstar(zmu(jj))
  zph(jj)     = ph(zmu(jj))
!
! 
  zcdn(jj) = (xkarman/zwork1(jj))**2.
!
!
  zsta(jj) = pri(jj)*zwork3(jj)
!
!
  IF ( pri(jj) < 0.0 ) THEN
    zdi(jj) = 1. / ( zvmod(jj)                                  &
                   +zchstar(jj)*zcdn(jj)*15.                         &
                                *zwork2(jj)**zph(jj)  &
                                *zfh(jj) * sqrt(-zsta(jj))           &
                  ) 
    pac(jj) = zcdn(jj)*(zvmod(jj)-15.* zsta(jj)*zdi(jj))*zfh(jj)

  ELSE
    zdi(jj) = sqrt(zwork3(jj) + 5. * zsta(jj) )
    pac(jj) = zcdn(jj)*zvmod(jj)/(1.+15.*zsta(jj)*zdi(jj)  &
             / zwork3(jj) /zvmod(jj) )*zfh(jj)    
  ENDIF
!
  pra(jj) = 1. / pac(jj)
!
  pch(jj) = 1. / (pra(jj) * zvmod(jj))
!
ENDDO
IF (lhook) CALL dr_hook('SURFACE_AERO_COND',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE surface_aero_cond