urban_exch_coef.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE urban_exch_coef(HZ0H, PZ0_O_Z0H, PTG, PQS, PEXNS, PEXNA, PTA, PQA,   &
                             PZREF, PUREF, PVMOD, PZ0,                            &
                             PRI, PCD, PCDN, PAC, PRA, PCH                        )  
!          #######################################################################
!
!!****  *URBAN_DRAG*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the surface drag coefficients over roof, road or town
!     according several scientific formulations
!         
!     
!!**  METHOD
!!    ------
!
!
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2009    from urban_drag.f90 (modified by S.  Leroyer at CMC)
!         01/2009 (S. Leroyer) option (HZ0H) for z0h applied on roof, road and town
!!      B. Decharme    06/2009 limitation of Ri
!!      B. Decharme    09/2009 limitation of Ri in surface_ri.F90
!
!-------------------------------------------------------------------------------

USE modi_surface_ri
USE modi_surface_cd
USE modi_surface_aero_cond
USE modi_wind_threshold
!
USE modd_csts, ONLY : xkarman
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_flxsurf3bx
!
IMPLICIT NONE
!
 CHARACTER(LEN=6)                  :: HZ0H     ! TEB option for z0h roof & road
REAL,               INTENT(IN)    :: PZ0_O_Z0H! z0/z0h ratio used in Mascart (1995)
REAL, DIMENSION(:), INTENT(IN)    :: PTG      ! surface temperature
REAL, DIMENSION(:), INTENT(IN)    :: PQS      ! surface specific humidity
REAL, DIMENSION(:), INTENT(IN)    :: PEXNS    ! surface exner function
REAL, DIMENSION(:), INTENT(IN)    :: PTA      ! temperature at the lowest level
REAL, DIMENSION(:), INTENT(IN)    :: PQA      ! specific humidity
                                              ! at the lowest level
REAL, DIMENSION(:), INTENT(IN)    :: PEXNA    ! exner function
                                              ! at the lowest level
REAL, DIMENSION(:), INTENT(IN)    :: PVMOD    ! module of the horizontal wind
!
REAL, DIMENSION(:), INTENT(IN)    :: PZ0      ! roughness length for momentum
REAL, DIMENSION(:), INTENT(IN)    :: PZREF    ! reference height of the first
                                              ! atmospheric level
REAL, DIMENSION(:), INTENT(IN)    :: PUREF    ! reference height of the wind
!                                             ! NOTE this is different from ZZREF
!                                             ! ONLY in stand-alone/forced mode,
!                                             ! NOT when coupled to a model (MesoNH)
REAL, DIMENSION(:), INTENT(OUT)   :: PRI      ! Richardson number
!
REAL, DIMENSION(:), INTENT(OUT)   :: PCD      ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(OUT)   :: PCDN     ! neutral drag coefficient for momentum
REAL, DIMENSION(:), INTENT(OUT)   :: PAC      ! aerodynamical conductance
REAL, DIMENSION(:), INTENT(OUT)   :: PRA      ! aerodynamical resistance
REAL, DIMENSION(:), INTENT(OUT)   :: PCH      ! drag coefficient for heat
!
!* local variables
!
REAL, DIMENSION(SIZE(PZ0))         :: ZZ0H     ! roughness length for heat
!* BRUT82 & KAND07 cases
REAL,DIMENSION(SIZE(PTA)) :: cmu, ctu, rib,ftemp,fvap,ilmo  ! temporary var for
REAL,DIMENSION(SIZE(PTA)) :: ue,fcor, hBL,lzz0,lzz0t,fm, fh ! flxsurf3
REAL,DIMENSION(SIZE(PTA)) :: z0h_roof,z0h_town,z0h_road     ! local thermal roughness
REAL,DIMENSION(SIZE(PTA)) :: zustar, zta, ztg
REAL,DIMENSION(SIZE(PTA)) :: ZVMOD                          ! wind
INTEGER N
!
!* MASC95 case
REAL,DIMENSION(SIZE(PTA)) :: ZDIRCOSZW     ! orography slope cosine
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*      1.     Mascart 1995 exchange coefficients
!              ----------------------------------
!
IF (lhook) CALL dr_hook('URBAN_EXCH_COEF',0,zhook_handle)
IF (hz0h=='MASC95') THEN
! 
  zz0h = pz0 / pz0_o_z0h ! fixed ratio for MASC95
  zdircoszw=1.           ! no orography slope effect taken into account in TEB
!
  CALL surface_ri(ptg, pqs, pexns, pexna, pta, pqa,   &
                    pzref, puref, zdircoszw, pvmod, pri )  
!
  CALL surface_cd(pri, pzref, puref, pz0, zz0h, pcd, pcdn)
!
  CALL surface_aero_cond(pri, pzref, puref, pvmod, pz0, zz0h, pac, pra, pch)
!
!
!*      2.     Brutsaert 1982  or Kanda 2007 exchange coefficients
!              ---------------------------------------------------
!
ELSEIF(hz0h=='BRUT82' .OR. hz0h=='KAND07')THEN
  ! initialisations
  fcor(:)=1.0372462e-04
!RJ: can be removed
  n=SIZE(pta)
  !
  ! Set a minimum threshold to the wind
  zvmod(:) = wind_threshold(pvmod(:),puref(:))
  !
  ! First guess of u*
  zustar(:) = 0.4 * zvmod(:) / log( puref/pz0(:) )
  !
  IF (hz0h=='KAND07') THEN ! Kanda 2007
    zz0h(:)= pz0(:) * 7.4 * exp( - 1.29 *( pz0(:)*zustar(:)/1.461e-5)**0.25)
  ELSEIF (hz0h=='BRUT82') THEN ! Brutsaert 1982
    zz0h(:)= pz0(:) * 7.4 * exp( - 2.46 *( pz0(:)*zustar(:)/1.461e-5)**0.25)
  ENDIF

  zta = pta/pexna
  ztg = ptg/pexns
  CALL flxsurf3bx( cmu, ctu, pri,ftemp,fvap,ilmo,    &
                   ue, fcor, zta, pqa,           &
                   puref, pzref, zvmod, ztg, pqs,&
                   hbl, pz0,zz0h,                      &
                   lzz0, lzz0t, fm, fh,n               )  
!
  pcd(:) = (cmu(:)/ue(:))**2  
  pcdn(:) = (xkarman/log(puref(:)/pz0(:)))**2
  pac(:) = (cmu(:)*ctu(:)/ue(:)**2) * zvmod(:)
  pra(:) = 1. / pac(:)
  pch(:) = 1. / (pra(:) * zvmod(:))
!
END IF
IF (lhook) CALL dr_hook('URBAN_EXCH_COEF',1,zhook_handle)

END SUBROUTINE urban_exch_coef