trip_change_date.F90

Go to the documentation of this file.

!#########
PROGRAM trip_change_date
!############################################
!
!!****  *TRIP_CHANGE_DATE*  
!!
!!    PURPOSE
!!    -------
!
!     Change the current date in the TRIP restart.
!     Important for spin up procedure
!     
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/14 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_trip_par, ONLY : lncprint
!
USE netcdf
USE mode_trip_netcdf
!
USE modi_init_trip_par
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME), PARAMETER :: YFILE    = 'TRIP_RESTART.nc'
 CHARACTER(LEN=NF90_MAX_NAME), PARAMETER :: YDATE    = 'date'
INTEGER,                      PARAMETER :: ILISTING = 6
LOGICAL,                      PARAMETER :: LRW      = .true.
!
REAL*4, DIMENSION(4) :: ZDATE_OLD, ZDATE
REAL,   DIMENSION(4) :: ZREAD
!
INTEGER            :: IYEAR
INTEGER            :: IMONTH
INTEGER            :: IDAY
INTEGER            :: ITIME
!
INTEGER            :: IC, IDATEID, INCID
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_CHANGE_DATE',0,zhook_handle)
!
!-------------------------------------------------------------------------------
 CALL init_trip_par
!-------------------------------------------------------------------------------
!
! * Read current date
!
OPEN(unit=21, file='date_trip', form='formatted')
READ(21, *) iyear, imonth, iday, itime
 CLOSE(21)
!
zdate(1) = REAL(iyear)
zdate(2) = REAL(imonth)
zdate(3) = REAL(iday)
zdate(4) = REAL(itime)
!
! * Open netcdf file
!
 CALL ncopen(ilisting,lrw,lncprint,yfile,incid)
!
! * read date in restart file
!
 CALL ncread(ilisting,incid,ydate,zread(:),lncprint)
zdate_old(:) = zread(:)
!
WRITE(ilisting,*)'Change date in trip restart :'
WRITE(ilisting,*)'Year  :',int(zdate_old(1)),'to',iyear
WRITE(ilisting,*)'Month :',int(zdate_old(2)),'to',imonth
WRITE(ilisting,*)'Day   :',int(zdate_old(3)),'to',iday
WRITE(ilisting,*)'Time  :',int(zdate_old(4)),'to',itime

! * Write current date in restart file
!
ic = nf90_inq_varid(incid,ydate,idateid)
IF(ic/=nf90_noerr)THEN
  WRITE(ilisting,*)'TRIP_CHANGE_DATE: NF90_INQ_VARID problem'
  stop
ENDIF
!
ic = nf90_put_var(incid,idateid,zdate)
IF(ic/=nf90_noerr)THEN
  WRITE(ilisting,*)'TRIP_CHANGE_DATE: NF90_PUT_VAR problem'
  stop
ENDIF
!
WRITE(ilisting,*)'Sucess in writting current date'
!
! * Close netcdf file
!
 CALL ncclose(ilisting,lncprint,yfile,incid)
!
IF (lhook) CALL dr_hook('TRIP_CHANGE_DATE',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END PROGRAM trip_change_date