mode_trip_netcdf.F90

Go to the documentation of this file.

!######################
MODULE mode_trip_netcdf
!######################
!
!!****  *MODE_TRIP_NETCDF*
!!
!!    PURPOSE
!!    -------
!    
!      The purpose of this routine is to store here all routines 
!      used by TRIP for read/store variables in netcdf.
!
!!
!!**  IMPLICIT ARGUMENTS
!!    ------------------
!!       NONE          
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme       * Meteo France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    25/04/08
!--------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_trip_par,ONLY : xundef
!
USE modi_abort_trip
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
INTERFACE ncread
    MODULE PROCEDURE ncread_x
    MODULE PROCEDURE ncread_xy
    MODULE PROCEDURE ncread_xyz
END INTERFACE
!
!-------------------------------------------------------------------------------
!
 CONTAINS
!
!-------------------------------------------------------------------------------
!
!######################################################
SUBROUTINE ncopen(KLISTING,ORW,OVERBOSE,HFILENAME,KNCID)
!######################################################
!
!!    PURPOSE
!!    -------
!
!     Open a netcdf file name YFILENAME
!
IMPLICIT NONE
!
!*      declarations of arguments
!
 CHARACTER(LEN=NF90_MAX_NAME), INTENT(IN) :: HFILENAME
!
LOGICAL, INTENT(IN)          :: ORW, OVERBOSE
!
INTEGER, INTENT(IN)          :: KLISTING
!
INTEGER, INTENT(OUT)         :: KNCID
!
!*      declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YFNAME
!
INTEGER :: IC
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      procedure
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCOPEN',0,zhook_handle)
!
yfname = hfilename(1:len_trim(hfilename))      
!
IF(orw)THEN
  ic = nf90_open(yfname,nf90_write,kncid)
ELSE
  ic = nf90_open(yfname,nf90_nowrite,kncid)
ENDIF
!
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCOPEN for TRIP : Error opening file ',hfilename(1:len_trim(hfilename))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCOPEN for TRIP : Error opening file')
ELSEIF(overbose)THEN
  WRITE(klisting,*)'NCOPEN for TRIP : Opening file ',hfilename(1:len_trim(hfilename))
ENDIF
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCOPEN',1,zhook_handle)
!
END SUBROUTINE ncopen
!
!-------------------------------------------------------------------------------
!
!###################################################
SUBROUTINE ncclose(KLISTING,OVERBOSE,HFILENAME,KNCID)
!###################################################
!
!!    PURPOSE
!!    -------
!    
!     Close a netcdf file
!
IMPLICIT NONE
!
!*      declarations of arguments
!
 CHARACTER(LEN=NF90_MAX_NAME), INTENT(IN) :: HFILENAME
!
LOGICAL, INTENT(IN)          :: OVERBOSE
INTEGER, INTENT(IN)          :: KLISTING
INTEGER, INTENT(IN)          :: KNCID
!
!*      declarations of local variables
!
INTEGER :: IC
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      procedure
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCCLOSE',0,zhook_handle)
!
ic = nf90_close(kncid)
IF(overbose)WRITE(klisting,*)'NCCLOSE for TRIP : Close file ',hfilename(1:len_trim(hfilename))
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCCLOSE',1,zhook_handle)
!
END SUBROUTINE ncclose
!
!-------------------------------------------------------------------------------
!
!#########################################################################
SUBROUTINE ncread_x(KLISTING,KNCID,HVNAME,PVECT,OVERBOSE)
!#########################################################################
!
!!    PURPOSE
!!    -------
!    
!     Read a XY variable in a netcdf file
!
IMPLICIT NONE
!
!*      declarations of arguments
!
 CHARACTER(LEN=NF90_MAX_NAME), INTENT(IN) :: HVNAME
!
INTEGER, INTENT(IN)          :: KLISTING
INTEGER, INTENT(IN)          :: KNCID
!
LOGICAL, INTENT(IN)          :: OVERBOSE
!
REAL, DIMENSION(:), INTENT(OUT) :: PVECT
!
!*      declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YVNAME
!
REAL*4,  DIMENSION(SIZE(PVECT)) :: ZVECT
INTEGER, DIMENSION(SIZE(PVECT)) :: IVECT
!
REAL    :: ZMISS
REAL*4  :: ZMISS4
!
INTEGER :: IC, ID, IVAR_TYPE
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      procedure
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCREAD_X',0,zhook_handle)
!
yvname = hvname(1:len_trim(hvname))
!
ic = nf90_inq_varid(kncid,yvname,id)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_X for TRIP : Error reading id for variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_X for TRIP : Error reading id variable ')
ENDIF
!
ic = nf90_inquire_variable(kncid,id,xtype=ivar_type)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_X for TRIP : Error reading type for variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_X for TRIP : Error reading type variable ')
ENDIF
!
IF(ivar_type==nf90_double)THEN
  ic=nf90_get_att(kncid,id,'missing_value',zmiss)
  IF(ic/=nf90_noerr) ic=nf90_get_att(kncid,id,'_FillValue',zmiss)  
  ic=nf90_get_var(kncid,id,pvect)
  WHERE(pvect(:)==zmiss)
        pvect(:)=xundef
  ENDWHERE  
ELSEIF(ivar_type==nf90_float)THEN
  ic=nf90_get_att(kncid,id,'missing_value',zmiss4)
  IF(ic/=nf90_noerr) ic=nf90_get_att(kncid,id,'_FillValue',zmiss4)
  ic=nf90_get_var(kncid,id,zvect)
  WHERE(zvect(:)/=zmiss4)
        pvect(:)=zvect(:)
  ELSEWHERE
        pvect(:)=xundef
  ENDWHERE
ELSEIF(ivar_type==nf90_int)THEN
  ic=nf90_get_var(kncid,id,ivect)
  pvect(:)=REAL(ivect(:))
ELSE
  WRITE(klisting,*)'NCREAD_X for TRIP : type of the variable must be integer, float or double ',hvname(1:len_trim(hvname))
  CALL abort_trip('NCREAD_X for TRIP : type of the variable not good')
ENDIF        
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_X for TRIP : Error reading variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_X for TRIP : Error reading variable')
ELSEIF(overbose)THEN
  WRITE(klisting,*)'NCREAD_X for TRIP : Success in reading variable ',hvname(1:len_trim(hvname))
ENDIF
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCREAD_X',1,zhook_handle)
!
END SUBROUTINE ncread_x
!-------------------------------------------------------------------------------
!
!#########################################################################
SUBROUTINE ncread_xy(KLISTING,KNCID,HVNAME,PVECT,OVERBOSE)
!#########################################################################
!
!!    PURPOSE
!!    -------
!    
!     Read a XY variable in a netcdf file
!
IMPLICIT NONE
!
!*      declarations of arguments
!
 CHARACTER(LEN=NF90_MAX_NAME), INTENT(IN) :: HVNAME
!
INTEGER, INTENT(IN)          :: KLISTING
INTEGER, INTENT(IN)          :: KNCID
!
LOGICAL, INTENT(IN)          :: OVERBOSE
!
REAL, DIMENSION(:,:), INTENT(OUT) :: PVECT
!
!*      declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YVNAME
!
REAL*4, DIMENSION(SIZE(PVECT,1),SIZE(PVECT,2)) :: ZVECT
!
REAL    :: ZMISS
REAL*4  :: ZMISS4
!
INTEGER :: IC, ID, IVAR_TYPE
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      procedure
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCREAD_XY',0,zhook_handle)
!
yvname = hvname(1:len_trim(hvname))
!
ic = nf90_inq_varid(kncid,yvname,id)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_XY for TRIP : Error reading id for variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_XY for TRIP : Error reading id variable ')
ENDIF
!
ic = nf90_inquire_variable(kncid,id,xtype=ivar_type)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_XY for TRIP : Error reading type for variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_XY for TRIP : Error reading type variable ')
ENDIF
!
IF(ivar_type==nf90_double)THEN
  ic=nf90_get_att(kncid,id,'missing_value',zmiss)
  IF(ic/=nf90_noerr) ic=nf90_get_att(kncid,id,'_FillValue',zmiss)  
  ic=nf90_get_var(kncid,id,pvect)
  WHERE(pvect(:,:)==zmiss)
        pvect(:,:)=xundef
  ENDWHERE  
ELSEIF(ivar_type==nf90_float)THEN
  ic=nf90_get_att(kncid,id,'missing_value',zmiss4)
  IF(ic/=nf90_noerr) ic=nf90_get_att(kncid,id,'_FillValue',zmiss4)
  ic=nf90_get_var(kncid,id,zvect)
  WHERE(zvect(:,:)/=zmiss4)
        pvect(:,:)=zvect(:,:)
  ELSEWHERE
        pvect(:,:)=xundef
  ENDWHERE
ELSE
  WRITE(klisting,*)'NCREAD_XY for TRIP : type of the variable must be float or double ',hvname(1:len_trim(hvname))
  CALL abort_trip('NCREAD_XY for TRIP : type of the variable not good')
ENDIF 
!
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_XY for TRIP : Error reading variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_XY for TRIP : Error reading variable')
ELSEIF(overbose)THEN
  WRITE(klisting,*)'NCREAD_XY for TRIP : Success in reading variable ',hvname(1:len_trim(hvname))
ENDIF
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCREAD_XY',1,zhook_handle)
!
END SUBROUTINE ncread_xy
!-------------------------------------------------------------------------------
!
!#########################################################################
SUBROUTINE ncread_xyz(KLISTING,KNCID,HVNAME,PVECT,OVERBOSE)
!#########################################################################
!
!!    PURPOSE
!!    -------
!    
!     Read a XYZ variable in a netcdf file
!
IMPLICIT NONE
!
!*      declarations of arguments
!
 CHARACTER(LEN=NF90_MAX_NAME), INTENT(IN) :: HVNAME
!
INTEGER, INTENT(IN)          :: KLISTING
INTEGER, INTENT(IN)          :: KNCID
!
LOGICAL, INTENT(IN)          :: OVERBOSE
!
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PVECT
!
!*      declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YVNAME
!
REAL*4, DIMENSION(SIZE(PVECT,1),SIZE(PVECT,2),SIZE(PVECT,3)) :: ZVECT
!
REAL    :: ZMISS
REAL*4  :: ZMISS4
!
INTEGER :: IC, ID, IVAR_TYPE
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      procedure
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCREAD_XYZ',0,zhook_handle)
yvname = hvname(1:len_trim(hvname))
!
ic = nf90_inq_varid(kncid,yvname,id)
!
ic = nf90_inq_varid(kncid,yvname,id)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_XYZ for TRIP : Error reading id for variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_XYZ for TRIP : Error reading id variable ')
ENDIF
!
ic = nf90_inquire_variable(kncid,id,xtype=ivar_type)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_XYZ for TRIP : Error reading type for variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_XYZ for TRIP : Error reading type variable ')
ENDIF
!
IF(ivar_type==nf90_double)THEN
  ic=nf90_get_att(kncid,id,'missing_value',zmiss)
  IF(ic/=nf90_noerr) ic=nf90_get_att(kncid,id,'_FillValue',zmiss)  
  ic=nf90_get_var(kncid,id,pvect)
  WHERE(pvect(:,:,:)==zmiss)
        pvect(:,:,:)=xundef
  ENDWHERE  
ELSEIF(ivar_type==nf90_float)THEN
  ic=nf90_get_att(kncid,id,'missing_value',zmiss4)
  IF(ic/=nf90_noerr) ic=nf90_get_att(kncid,id,'_FillValue',zmiss4)
  ic=nf90_get_var(kncid,id,zvect)
  WHERE(zvect(:,:,:)/=zmiss4)
        pvect(:,:,:)=zvect(:,:,:)
  ELSEWHERE
        pvect(:,:,:)=xundef
  ENDWHERE
ELSE
  WRITE(klisting,*)'NCREAD_XYZ for TRIP : type of the variable must be float or double ',hvname(1:len_trim(hvname))
  CALL abort_trip('NCREAD_XYZ for TRIP : type of the variable not good')
ENDIF        
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCREAD_XYZ for TRIP : Error reading variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCREAD_XYZ for TRIP : Error reading variable')
ELSEIF(overbose)THEN
  WRITE(klisting,*)'NCREAD_XYZ for TRIP : Success in reading variable ',hvname(1:len_trim(hvname))
ENDIF
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCREAD_XYZ',1,zhook_handle)
!
END SUBROUTINE ncread_xyz
!
!-------------------------------------------------------------------------------
!
!########################################################
SUBROUTINE nccreate(KLISTING,HFILENAME,HTITLE,HTIMEUNIT, &
                    HVNAME,HVLNAME,HUNIT,PLON,PLAT,      &
                    PMISSVAL,OVERBOSE,KNCID,OTIME,       &
                    KZLEN,OVARZDIM,ODOUBLE)  
!########################################################
!
!!    PURPOSE
!!    -------
!    
!     Open a netcdf file name YFILENAME
!
IMPLICIT NONE
!
!*      declarations of arguments
!
 CHARACTER(LEN=NF90_MAX_NAME), INTENT(IN) :: HFILENAME, HTITLE, HTIMEUNIT
!
 CHARACTER(LEN=NF90_MAX_NAME), DIMENSION(:), INTENT(IN) :: HVNAME, HVLNAME, HUNIT  
!
REAL, DIMENSION(:), INTENT(IN) :: PLON
REAL, DIMENSION(:), INTENT(IN) :: PLAT
!
LOGICAL, INTENT(IN)  :: OVERBOSE
!
REAL,    INTENT(IN)  :: PMISSVAL
!
INTEGER, INTENT(IN)  :: KLISTING
!
INTEGER, INTENT(OUT) :: KNCID
!
LOGICAL, INTENT(IN)  :: OTIME
!
INTEGER,               INTENT(IN), OPTIONAL  :: KZLEN
LOGICAL, DIMENSION(:), INTENT(IN), OPTIONAL  :: OVARZDIM
LOGICAL, DIMENSION(:), INTENT(IN), OPTIONAL  :: ODOUBLE
!
!*      declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YWORK
!
REAL*4, DIMENSION(:), ALLOCATABLE :: ZWORK
!
REAL*4,  DIMENSION(SIZE(PLON)) :: ZLON
REAL*4,  DIMENSION(SIZE(PLAT)) :: ZLAT
!
LOGICAL, DIMENSION(SIZE(HVNAME)) :: LDOUBLE
!
REAL*4                        :: ZMISSVAL
!
INTEGER :: ILONDIM, ILATDIM, ILEVDIM, ITIMEDIM
INTEGER :: ILON_ID, ILAT_ID, ILEV_ID, ITIME_ID, VAR_ID
INTEGER :: IC, IWORK, INVAR
INTEGER :: JVAR
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      procedure
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCCREATE',0,zhook_handle)
!
IF(PRESENT(odouble))THEN
  ldouble(:)=odouble(:)
ELSE
  ldouble(:)=.false.
ENDIF
!
!Creation
!
ywork = hfilename(1:len_trim(hfilename))
!
ic = nf90_create(ywork,nf90_64bit_offset,kncid)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCCREATE for TRIP : Error create file ',hfilename(1:len_trim(hfilename))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCCREATE for TRIP : Error create file')
ELSEIF(overbose)THEN
    WRITE(klisting,*)'NCCREATE for TRIP : Success in creating file ',hfilename(1:len_trim(hfilename))
ENDIF
!
!Attributs
ywork = htitle(1:len_trim(htitle))
ic = nf90_put_att(kncid,nf90_global,'title',ywork)
ywork = 'COARDS'
ic = nf90_put_att(kncid,nf90_global,'Conventions',ywork)
!
!Dimensions
iwork = SIZE(plon)
ic = nf90_def_dim(kncid,'longitude',iwork,ilondim)
iwork = SIZE(plat)
ic = nf90_def_dim(kncid,'latitude',iwork,ilatdim)
IF(PRESENT(kzlen)) ic = nf90_def_dim(kncid,'level',kzlen,ilevdim)
IF(otime) ic = nf90_def_dim(kncid,'time',nf90_unlimited,itimedim)
!
!Variable attributs
!
ic = nf90_def_var(kncid,'longitude',nf90_float,ilondim,ilon_id)
ic = nf90_def_var(kncid,'latitude' ,nf90_float,ilatdim,ilat_id)
ywork = 'degrees_east'
ic = nf90_put_att(kncid,ilon_id,'units',ywork)
ywork = 'degrees_north'
ic = nf90_put_att(kncid,ilat_id,'units',ywork)
IF(PRESENT(kzlen))THEN
  ic = nf90_def_var(kncid,'level',nf90_float,ilevdim,ilev_id)
  ywork = 'level'
  ic = nf90_put_att(kncid,ilev_id,'units',ywork)
ENDIF
!
IF(otime)THEN
   ywork = htimeunit(1:len_trim(htimeunit))
   ic = nf90_def_var(kncid,'time',nf90_int,itimedim,itime_id)
   ic = nf90_put_att(kncid,itime_id,'units',ywork)
ENDIF
!
!Variables parametres
!
zmissval = REAL(pmissval)
!
invar = SIZE(hvname)
!
DO jvar=1,invar
   ywork = hvname(jvar)(1:len_trim(hvname(jvar)))
   IF(PRESENT(kzlen))THEN  
     IF(otime)THEN
       IF(ovarzdim(jvar))THEN
         IF(ldouble(jvar))THEN
           ic = nf90_def_var(kncid,ywork,nf90_double,(/ilondim,ilatdim,ilevdim,itimedim/),var_id)
         ELSE
           ic = nf90_def_var(kncid,ywork,nf90_float,(/ilondim,ilatdim,ilevdim,itimedim/),var_id)
         ENDIF
       ELSE
         IF(ldouble(jvar))THEN
           ic = nf90_def_var(kncid,ywork,nf90_double,(/ilondim,ilatdim,itimedim/),var_id)
         ELSE
           ic = nf90_def_var(kncid,ywork,nf90_float,(/ilondim,ilatdim,itimedim/),var_id)
         ENDIF
       ENDIF
     ELSE
       IF(ovarzdim(jvar))THEN
         IF(ldouble(jvar))THEN
           ic = nf90_def_var(kncid,ywork,nf90_double,(/ilondim,ilatdim,ilevdim/),var_id)
         ELSE
           ic = nf90_def_var(kncid,ywork,nf90_float,(/ilondim,ilatdim,ilevdim/),var_id)
         ENDIF
       ELSE
         IF(ldouble(jvar))THEN
           ic = nf90_def_var(kncid,ywork,nf90_double,(/ilondim,ilatdim/),var_id)
         ELSE
           ic = nf90_def_var(kncid,ywork,nf90_float,(/ilondim,ilatdim/),var_id)
         ENDIF
       ENDIF
     ENDIF
   ELSE
     IF(otime)THEN
       IF(ldouble(jvar))THEN
         ic = nf90_def_var(kncid,ywork,nf90_double,(/ilondim,ilatdim,itimedim/),var_id)
       ELSE
         ic = nf90_def_var(kncid,ywork,nf90_float,(/ilondim,ilatdim,itimedim/),var_id)
       ENDIF
     ELSE
       IF(ldouble(jvar))THEN
         ic = nf90_def_var(kncid,ywork,nf90_double,(/ilondim,ilatdim/),var_id)
       ELSE
         ic = nf90_def_var(kncid,ywork,nf90_float,(/ilondim,ilatdim/),var_id)
       ENDIF
     ENDIF
   ENDIF
   !
   ywork = hvlname(jvar)(1:len_trim(hvlname(jvar)))
   ic = nf90_put_att(kncid,var_id,'long_name',ywork)
   ywork = hunit(jvar)(1:len_trim(hunit(jvar)))
   ic = nf90_put_att(kncid,var_id,'units',ywork)
   IF(ldouble(jvar))THEN
     ic = nf90_put_att(kncid,var_id,'_FillValue',pmissval)
   ELSE
     ic = nf90_put_att(kncid,var_id,'_FillValue',zmissval)
   ENDIF
   !
ENDDO
!
ic = nf90_enddef(kncid)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCCREATE for TRIP : Error file definition'
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCCREATE for TRIP :  Error file definition')
ELSEIF(overbose)THEN
    WRITE(klisting,*)'NCCREATE for TRIP : file definition is ok'
ENDIF
!
!Write dimensions
!
zlon(:)=plon(:)
zlat(:)=plat(:)
!
ic = nf90_put_var(kncid,ilon_id,zlon)
ic = nf90_put_var(kncid,ilat_id,zlat)
IF(PRESENT(kzlen))THEN
  ALLOCATE(zwork(kzlen))
  DO jvar = 1,kzlen
     zwork(jvar)=jvar
  ENDDO
  ic = nf90_put_var(kncid,ilev_id,zwork)
  DEALLOCATE(zwork)
ENDIF
!
IF(overbose)THEN
  WRITE(klisting,*)'NCCREATE ',hfilename(1:len_trim(hfilename)),' for TRIP OK !'
ENDIF
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCCREATE',1,zhook_handle)
!
END SUBROUTINE nccreate
!
!-------------------------------------------------------------------------------
!
!################################################
SUBROUTINE ncstore(KLISTING,KNCID,HVNAME,PWRITE, &
                   OVERBOSE,KTIMENUM,KTIMEVAL,   &
                   KLEVEL,OVARZDIM,ODOUBLE       )  
!################################################
!
!!    PURPOSE
!!    -------
!    
!     Write in a netcdf file with illimited time if this this the case
!
IMPLICIT NONE
!
!*      declarations of arguments
!
 CHARACTER(LEN=NF90_MAX_NAME), INTENT(IN) :: HVNAME  
!
REAL, DIMENSION(:,:), INTENT(IN) :: PWRITE
!
INTEGER, INTENT(IN)           :: KLISTING, KNCID
!
LOGICAL, INTENT(IN)           :: OVERBOSE
!
INTEGER, INTENT(IN), OPTIONAL :: KTIMENUM
INTEGER, INTENT(IN), OPTIONAL :: KTIMEVAL

INTEGER, INTENT(IN), OPTIONAL :: KLEVEL
LOGICAL, INTENT(IN), OPTIONAL :: OVARZDIM
LOGICAL, INTENT(IN), OPTIONAL :: ODOUBLE
!
!*      declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YWORK
!
REAL*4, DIMENSION(SIZE(PWRITE,1),SIZE(PWRITE,2)) :: ZWRITE
!
INTEGER, DIMENSION(4) :: ISTART, ICOUNT
!
INTEGER :: IUNLIMID, ITIMEID, ILENGHT, INDIM
INTEGER :: IC, IVAR_ID
LOGICAL :: LDOUBLE
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      procedure
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCSTORE',0,zhook_handle)
!
IF(PRESENT(odouble))THEN
  ldouble=odouble
ELSE
  ldouble=.false.
ENDIF
!
IF(PRESENT(klevel).AND..NOT.PRESENT(ovarzdim))THEN
  WRITE(klisting,*)'NCSTORE for TRIP : Error writing variable dimenssion ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)'ILEVEL present but not LVARZDIM'
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCSTORE for TRIP : Error writing variable dimenssion')
ENDIF       
!
IF(PRESENT(ktimenum).AND.PRESENT(ktimeval))THEN
  ic = nf90_inquire(kncid,unlimiteddimid=iunlimid)
  IF(iunlimid/=-1)THEN
    ic = nf90_inquire_dimension(kncid,iunlimid,len=ilenght)
    IF(ktimenum/=ilenght)THEN
      ic = nf90_inq_varid(kncid,'time',itimeid)
      ic = nf90_put_var(kncid,itimeid,ktimeval,start=(/ktimenum/))
      IF(overbose)THEN
        WRITE(klisting,*)'NCSTORE : re-writing of time variable number=',&
                          ktimenum,' and value=',ktimeval  
      ENDIF
    ENDIF
  ENDIF
ENDIF
!
ywork = hvname(1:len_trim(hvname))
!
ic = nf90_inq_varid(kncid,ywork,ivar_id)
ic = nf90_inquire_variable(kncid,ivar_id,ndims=indim)
!
icount(1) = SIZE(pwrite,1)
icount(2) = SIZE(pwrite,2)
icount(3) = 1
icount(4) = 1
!  
istart(1) = 1
istart(2) = 1
!
zwrite(:,:) = pwrite(:,:)
!
IF(PRESENT(klevel).AND.ovarzdim)THEN
  istart(3) = klevel
  IF(PRESENT(ktimenum).AND.PRESENT(ktimeval))THEN
    istart(4) = ktimenum
    IF(ldouble)THEN
      ic = nf90_put_var(kncid,ivar_id,pwrite,start=istart(1:4),count=icount(1:4))
    ELSE
      ic = nf90_put_var(kncid,ivar_id,zwrite,start=istart(1:4),count=icount(1:4))
    ENDIF          
  ELSE
    IF(ldouble)THEN
      ic = nf90_put_var(kncid,ivar_id,pwrite,start=istart(1:3),count=icount(1:3))
    ELSE
      ic = nf90_put_var(kncid,ivar_id,zwrite,start=istart(1:3),count=icount(1:3))
    ENDIF          
  ENDIF 
ELSE
  IF(PRESENT(ktimenum).AND.PRESENT(ktimeval))THEN
    istart(3) = ktimenum
    IF(ldouble)THEN
      ic = nf90_put_var(kncid,ivar_id,pwrite,start=istart(1:3),count=icount(1:3))
    ELSE
      ic = nf90_put_var(kncid,ivar_id,zwrite,start=istart(1:3),count=icount(1:3))
    ENDIF          
  ELSE
    IF(ldouble)THEN
      ic = nf90_put_var(kncid,ivar_id,pwrite,start=istart(1:2),count=icount(1:2))
    ELSE
      ic = nf90_put_var(kncid,ivar_id,zwrite,start=istart(1:2),count=icount(1:2))
    ENDIF          
  ENDIF          
ENDIF
!
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCSTORE for TRIP : Error writing variable ',hvname(1:len_trim(hvname))
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCSTORE for TRIP : Error writing variable')
ELSEIF(overbose)THEN
  WRITE(klisting,*)'NCSTORE for TRIP : Success in writing variable ',hvname(1:len_trim(hvname))
  IF(PRESENT(klevel))WRITE(klisting,*)'                   level: ',klevel
ENDIF
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCSTORE',1,zhook_handle)
!
END SUBROUTINE ncstore
!
!-------------------------------------------------------------------------------
!
!#####################################################################
SUBROUTINE ncdate(KLISTING,KNCID,KYEAR,KMONTH,KDAY,PTIME,OVERBOSE)
!#####################################################################
!
!!    PURPOSE
!!    -------
!
!     Open a netcdf file name YFILENAME
!
IMPLICIT NONE
!
!*      declarations of arguments
!
INTEGER, INTENT(IN)          :: KLISTING
INTEGER, INTENT(IN)          :: KNCID
INTEGER, INTENT(IN)          :: KYEAR
INTEGER, INTENT(IN)          :: KMONTH
INTEGER, INTENT(IN)          :: KDAY
REAL,    INTENT(IN)          :: PTIME
!
LOGICAL, INTENT(IN)          :: OVERBOSE
!
!*      declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YDATE, YWORK
!
REAL*4, DIMENSION(4) :: ZDATE
REAL*4               :: ZMISSVAL
!
INTEGER :: IC, IWORK, ISIZE, IDATEID
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      procedure
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCDATE',0,zhook_handle)
!
ydate = 'date'
!
zdate(1) = REAL(kyear)
zdate(2) = REAL(kmonth)
zdate(3) = REAL(kday)
zdate(4) = REAL(ptime)
!
zmissval = xundef
!
ic = nf90_redef(kncid)
!
!Dimensions
iwork=4
ic = nf90_def_dim(kncid,ydate,iwork,isize)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCDATE for TRIP : Error creating date dimension '
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCDATE for TRIP : Error creating date dimension')
ENDIF
!
!Variable attributs
ic = nf90_def_var(kncid,ydate,nf90_float,isize,idateid)
ywork = 'current date: year month day time'
ic = nf90_put_att(kncid,idateid,'long_name',ywork)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCDATE for TRIP : Error creating date attributs'
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCDATE for TRIP : Error creating date attributs')
ENDIF
ic = nf90_put_att(kncid,idateid,'_FillValue',zmissval)
IF(ic/=nf90_noerr)THEN
  WRITE(klisting,*)'NCDATE for TRIP : Error creating date attributs'
  WRITE(klisting,*)nf90_strerror(ic)
  CALL abort_trip('NCDATE for TRIP : Error creating date attributs')
ENDIF
!
ic = nf90_enddef(kncid)
!    
ic = nf90_put_var(kncid,idateid,zdate)
!
IF(overbose)THEN
  WRITE(klisting,*)'NCDATE for TRIP : Sucess in writting current date'
ENDIF
!
IF (lhook) CALL dr_hook('MODE_TRIP_NETCDF:NCDATE',1,zhook_handle)
!
END SUBROUTINE ncdate
!
!-------------------------------------------------------------------------------
!
END MODULE mode_trip_netcdf