teb_garden.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE teb_garden (DTCO, G, TOP, T, BOP, B, TPN, TIR, DMT, GDM, GRM, KTEB_P,              &
                           HIMPLICIT_WIND, PTSUN, PT_CAN, PQ_CAN, PU_CAN, PT_LOWCAN, PQ_LOWCAN,   &
                           PU_LOWCAN, PZ_LOWCAN, PPEW_A_COEF, PPEW_B_COEF, PPEW_A_COEF_LOWCAN,    &
                           PPEW_B_COEF_LOWCAN, PPS, PPA, PEXNS, PEXNA, PTA, PQA, PRHOA, PCO2,     &
                           PLW_RAD, PDIR_SW, PSCA_SW, PSW_BANDS, KSW, PZENITH, PAZIM, PRR, PSR,   &
                           PZREF, PUREF, PVMOD, PH_TRAFFIC, PLE_TRAFFIC, PTSTEP, PLEW_RF, PLEW_RD,&
                           PLE_WL_A, PLE_WL_B, PRNSN_RF, PHSN_RF, PLESN_RF, PGSN_RF, PMELT_RF,    &
                           PRNSN_RD, PHSN_RD, PLESN_RD, PGSN_RD, PMELT_RD, PRN_GRND, PH_GRND,     &
                           PLE_GRND, PGFLX_GRND, PRN_TWN, PH_TWN, PLE_TWN, PGFLX_TWN, PEVAP_TWN,  &
                           PSFCO2, PUW_GRND, PUW_RF, PDUWDU_GRND, PDUWDU_RF,                      &
                           PUSTAR_TWN, PCD, PCDN, PCH_TWN, PRI_TWN, PTS_TWN, PEMIS_TWN,           &
                           PDIR_ALB_TWN, PSCA_ALB_TWN, PRESA_TWN, PAC_RD, PAC_GD, PAC_GR,         &
                           PAC_RD_WAT, PAC_GD_WAT, PAC_GR_WAT, KDAY, PEMIT_LW_FAC, PEMIT_LW_GRND, &
                           PT_RAD_IND, PREF_SW_GRND, PREF_SW_FAC, PHU_BLD, PTIME, PPROD_BLD  )
!   ##########################################################################
!
!!****  *TEB_GARDEN*  
!!
!!    PURPOSE
!!    -------
!
!     
!!**  METHOD
!     ------
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      A. Lemonsu          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!    Original    05/2009
!!                04/2012 add B%XTRAN_WIN
!!    modified    08/2012 TOP%CCH_BEM/ ROUGH_WALL and ROUGH_ROOF for buildind conv coef.
!!    modified    10/2012 add B%XF_WIN_WIN as arg
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_teb_n, ONLY : teb_t
USE modd_bem_option_n, ONLY : bem_options_t
USE modd_bem_n, ONLY : bem_t
USE modd_teb_panel_n, ONLY : teb_panel_t
USE modd_teb_irrig_n, ONLY : teb_irrig_t
USE modd_diag_misc_teb_n, ONLY : diag_misc_teb_t
!
USE modd_diag_n, ONLY : diag_t
USE modd_diag_evap_isba_n, ONLY : diag_evap_isba_t
USE modd_diag_misc_isba_n, ONLY : diag_misc_isba_t
!
USE modd_surfex_n, ONLY : teb_garden_model_t
USE modd_surfex_n, ONLY : teb_greenroof_model_t
!
USE modd_type_date_surf,    ONLY: date_time
USE modd_csts,              ONLY: xtt, xstefan
USE modd_surf_par,          ONLY: xundef
USE modd_snow_par,          ONLY: xemissn, xansmax
!
USE mode_thermos
USE mode_surf_snow_frac
!
USE modi_solar_panel
USE modi_teb_veg_properties
USE modi_window_shading_availability
USE modi_urban_solar_abs
USE modi_urban_lw_coef
USE modi_garden
USE modi_greenroof
USE modi_teb
USE modi_avg_urban_fluxes
USE modi_bld_occ_calendar
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    Declarations of arguments
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
!
TYPE(grid_t), INTENT(INOUT) :: G
!
TYPE(teb_options_t), INTENT(INOUT) :: TOP
TYPE(teb_t), INTENT(INOUT) :: T
TYPE(bem_options_t), INTENT(INOUT) :: BOP
TYPE(bem_t), INTENT(INOUT) :: B
TYPE(teb_panel_t), INTENT(INOUT) :: TPN
TYPE(teb_irrig_t), INTENT(INOUT) :: TIR
TYPE(diag_misc_teb_t), INTENT(INOUT) :: DMT
!
TYPE(teb_garden_model_t), INTENT(INOUT) :: GDM
TYPE(teb_greenroof_model_t), INTENT(INOUT) :: GRM
!
INTEGER, INTENT(IN) :: KTEB_P                             ! TEB current patch number 
!
 CHARACTER(LEN=*),     INTENT(IN)  :: HIMPLICIT_WIND      ! wind implicitation option
!                                                         ! 'OLD' = direct
!                                                         ! 'NEW' = Taylor serie, order 1
REAL, DIMENSION(:),   INTENT(IN)    :: PTSUN              ! solar time   (s from midnight)
!                                                         
REAL, DIMENSION(:)  , INTENT(INOUT) :: PT_CAN             ! canyon air temperature
REAL, DIMENSION(:)  , INTENT(INOUT) :: PQ_CAN             ! canyon air specific humidity
REAL, DIMENSION(:)  , INTENT(IN)    :: PU_CAN             ! canyon hor. wind
REAL, DIMENSION(:)  , INTENT(IN)    :: PU_LOWCAN          ! wind near the road
REAL, DIMENSION(:)  , INTENT(IN)    :: PT_LOWCAN          ! temp. near the road
REAL, DIMENSION(:)  , INTENT(IN)    :: PQ_LOWCAN          ! hum. near the road
REAL, DIMENSION(:)  , INTENT(IN)    :: PZ_LOWCAN          ! height of atm. var. near the road
REAL, DIMENSION(:)  , INTENT(IN)    :: PPEW_A_COEF        ! implicit coefficients
REAL, DIMENSION(:)  , INTENT(IN)    :: PPEW_B_COEF        ! for wind coupling
REAL, DIMENSION(:)  , INTENT(IN)    :: PPEW_A_COEF_LOWCAN ! implicit coefficients for wind coupling
REAL, DIMENSION(:)  , INTENT(IN)    :: PPEW_B_COEF_LOWCAN ! between low canyon wind and road
REAL, DIMENSION(:)  , INTENT(IN)    :: PPS                ! pressure at the surface
REAL, DIMENSION(:)  , INTENT(IN)    :: PPA                ! pressure at the first atmospheric level
REAL, DIMENSION(:)  , INTENT(IN)    :: PEXNS              ! surface exner function
REAL, DIMENSION(:)  , INTENT(IN)    :: PTA                ! temperature at the lowest level
REAL, DIMENSION(:)  , INTENT(IN)    :: PQA                ! specific humidity at the lowest level
REAL, DIMENSION(:)  , INTENT(IN)    :: PVMOD              ! module of the horizontal wind
REAL, DIMENSION(:)  , INTENT(IN)    :: PEXNA              ! exner function at the lowest level
REAL, DIMENSION(:)  , INTENT(IN)    :: PRHOA              ! air density at the lowest level
REAL, DIMENSION(:)  , INTENT(IN)    :: PCO2               ! CO2 concentration in the air    (kg/m3)
REAL, DIMENSION(:)  , INTENT(IN)    :: PLW_RAD            ! atmospheric infrared radiation
REAL, DIMENSION(:,:), INTENT(IN)    :: PDIR_SW            ! incoming direct solar rad on an horizontal surface
REAL, DIMENSION(:,:), INTENT(IN)    :: PSCA_SW            ! scattered incoming solar rad.
REAL, DIMENSION(:)  , INTENT(IN)    :: PSW_BANDS          ! mean wavelength of each shortwave band (m)
INTEGER,              INTENT(IN)    :: KSW                ! number of short-wave spectral bands
REAL, DIMENSION(:)  , INTENT(IN)    :: PZENITH            ! solar zenithal angle
REAL, DIMENSION(:)  , INTENT(IN)    :: PAZIM              ! solar azimuthal angle
                                                          ! (radian form N, clockwise)
REAL, DIMENSION(:)  , INTENT(IN)    :: PRR                ! rain rate
REAL, DIMENSION(:)  , INTENT(IN)    :: PSR                ! snow rate
REAL, DIMENSION(:)  , INTENT(IN)    :: PH_TRAFFIC         ! anthropogenic sensible heat fluxes due to traffic
REAL, DIMENSION(:)  , INTENT(IN)    :: PLE_TRAFFIC        ! anthropogenic latent heat fluxes due to traffic
REAL, DIMENSION(:)  , INTENT(IN)    :: PZREF              ! reference height of the first atm level (temperature)
REAL, DIMENSION(:)  , INTENT(IN)    :: PUREF              ! reference height of the first atm level (wind)
REAL                , INTENT(IN)    :: PTSTEP             ! time step
!
REAL, DIMENSION(:)  , INTENT(OUT)   :: PLEW_RF          ! latent heat flux over roof (snow)
REAL, DIMENSION(:)  , INTENT(OUT)   :: PLEW_RD          ! latent heat flux over road (snow)
REAL, DIMENSION(:)  , INTENT(OUT)   :: PLE_WL_A         ! latent heat flux over wall
REAL, DIMENSION(:)  , INTENT(OUT)   :: PLE_WL_B         ! latent heat flux over wall

!
REAL, DIMENSION(:)  , INTENT(OUT)   :: PRNSN_RF       ! net radiation over snow
REAL, DIMENSION(:)  , INTENT(OUT)   :: PHSN_RF        ! sensible heat flux over snow
REAL, DIMENSION(:)  , INTENT(OUT)   :: PLESN_RF       ! latent heat flux over snow
REAL, DIMENSION(:)  , INTENT(OUT)   :: PGSN_RF        ! flux under the snow
REAL, DIMENSION(:)  , INTENT(OUT)   :: PMELT_RF         ! snow melt
REAL, DIMENSION(:)  , INTENT(OUT)   :: PRNSN_RD       ! net radiation over snow
REAL, DIMENSION(:)  , INTENT(OUT)   :: PHSN_RD        ! sensible heat flux over snow
REAL, DIMENSION(:)  , INTENT(OUT)   :: PLESN_RD       ! latent heat flux over snow
REAL, DIMENSION(:)  , INTENT(OUT)   :: PGSN_RD        ! flux under the snow
REAL, DIMENSION(:)  , INTENT(OUT)   :: PMELT_RD       ! snow melt
!
REAL, DIMENSION(:)  , INTENT(OUT)   :: PRN_GRND          ! net radiation over ground
REAL, DIMENSION(:)  , INTENT(OUT)   :: PH_GRND           ! sensible heat flux over ground
REAL, DIMENSION(:)  , INTENT(OUT)   :: PLE_GRND          ! latent heat flux over ground
REAL, DIMENSION(:)  , INTENT(OUT)   :: PGFLX_GRND        ! flux through the ground
REAL, DIMENSION(:)  , INTENT(OUT)   :: PRN_TWN           ! net radiation over town
REAL, DIMENSION(:)  , INTENT(OUT)   :: PH_TWN            ! sensible heat flux over town
REAL, DIMENSION(:)  , INTENT(OUT)   :: PLE_TWN           ! latent heat flux over town
REAL, DIMENSION(:)  , INTENT(OUT)   :: PGFLX_TWN         ! flux through the ground
REAL, DIMENSION(:)  , INTENT(OUT)   :: PEVAP_TWN         ! evaporation flux (kg/m2/s)
REAL, DIMENSION(:)  , INTENT(OUT)   :: PSFCO2            ! flux of CO2       (m/s*kg_CO2/kg_air)
REAL, DIMENSION(:)  , INTENT(OUT)   :: PUW_GRND          ! momentum flux for ground built surf
REAL, DIMENSION(:)  , INTENT(OUT)   :: PUW_RF            ! momentum flux for roofs
REAL, DIMENSION(:)  , INTENT(OUT)   :: PDUWDU_GRND       !
REAL, DIMENSION(:)  , INTENT(OUT)   :: PDUWDU_RF         !
REAL, DIMENSION(:)  , INTENT(OUT)   :: PUSTAR_TWN        ! friciton velocity over town
REAL, DIMENSION(:)  , INTENT(OUT)   :: PCD               ! town averaged drag coefficient
REAL, DIMENSION(:)  , INTENT(OUT)   :: PCDN              ! town averaged neutral drag coefficient
REAL, DIMENSION(:)  , INTENT(OUT)   :: PCH_TWN           ! town averaged heat transfer coefficient
REAL, DIMENSION(:)  , INTENT(OUT)   :: PRI_TWN           ! town averaged Richardson number
REAL, DIMENSION(:)  , INTENT(OUT)   :: PTS_TWN           ! town surface temperature
REAL, DIMENSION(:)  , INTENT(OUT)   :: PEMIS_TWN         ! town equivalent emissivity
REAL, DIMENSION(:)  , INTENT(OUT)   :: PDIR_ALB_TWN      ! town equivalent direct albedo
REAL, DIMENSION(:)  , INTENT(OUT)   :: PSCA_ALB_TWN      ! town equivalent diffuse albedo
REAL, DIMENSION(:)  , INTENT(OUT)   :: PRESA_TWN         ! town aerodynamical resistance
REAL, DIMENSION(:)  , INTENT(OUT)   :: PAC_RD            ! road conductance
REAL, DIMENSION(:)  , INTENT(OUT)   :: PAC_GD            ! green area conductance
REAL, DIMENSION(:)  , INTENT(OUT)   :: PAC_GR            ! green roof conductance
REAL, DIMENSION(:)  , INTENT(OUT)   :: PAC_RD_WAT        ! road conductance for latent heat
REAL, DIMENSION(:)  , INTENT(OUT)   :: PAC_GD_WAT        ! green area conductance for latent heat
REAL, DIMENSION(:)  , INTENT(OUT)   :: PAC_GR_WAT        ! green roof conductance for latent heat
!
! new arguments created after BEM
!
INTEGER             , INTENT(IN)    :: KDAY               ! Simulation day
! new argument for the UTCI calculation
REAL, DIMENSION(:)  , INTENT(OUT)    :: PEMIT_LW_GRND     ! LW flux emitted by the ground (W/m2 ground)
REAL, DIMENSION(:)  , INTENT(OUT)    :: PEMIT_LW_FAC      ! LW flux emitted by the facade (W/m2 ground)
REAL, DIMENSION(:)  , INTENT(OUT)    :: PT_RAD_IND        ! Indoor mean radiant temperature [K]
REAL, DIMENSION(:)  , INTENT(OUT)    :: PREF_SW_GRND      ! total solar rad reflected from ground
REAL, DIMENSION(:)  , INTENT(OUT)    :: PREF_SW_FAC       ! total solar rad reflected from facade
REAL, DIMENSION(:)  , INTENT(OUT)    :: PHU_BLD           ! Indoor relative humidity 0 < (-) < 1
!
! new arguments for shading, schedule or natural ventilation
REAL                , INTENT(IN)     :: PTIME             ! current time since midnight (UTC, s)
!
!* arguments for solar panels
!
REAL, DIMENSION(:),   INTENT(OUT)     :: PPROD_BLD        ! Averaged     Energy production of solar panel on roofs (W/m2 bld  )
!
!*      0.2    Declarations of local variables
!
TYPE(diag_t), POINTER :: GDDK
TYPE(diag_evap_isba_t), POINTER :: GDDEK
TYPE(diag_misc_isba_t), POINTER :: GDDMK
!
TYPE(diag_t), POINTER :: GRDK
TYPE(diag_evap_isba_t), POINTER :: GRDEK
TYPE(diag_misc_isba_t), POINTER :: GRDMK
!
REAL, DIMENSION(SIZE(PTA)) :: ZTA            ! air temperature extrapolated at roof level
REAL, DIMENSION(SIZE(PTA)) :: ZQA            ! air humidity extrapolated at roof level
!
REAL, DIMENSION(SIZE(PTA)) :: ZDN_RF       ! snow fraction on roofs
REAL, DIMENSION(SIZE(PTA)) :: ZDN_RD       ! snow fraction on roads
REAL, DIMENSION(SIZE(PTA)) :: ZDF_RF       ! free-snow fraction on roofs
REAL, DIMENSION(SIZE(PTA)) :: ZDF_RD       ! free-snow fraction on roads
REAL, DIMENSION(SIZE(PTA)) :: ZDELT_RD     ! fraction of water on roads
REAL, DIMENSION(SIZE(PTA)) :: ZDELT_RF     ! fraction of water on roofs
REAL, DIMENSION(SIZE(PTA)) :: ZAC_RF       ! roof conductance
REAL, DIMENSION(SIZE(PTA)) :: ZAC_RF_WAT   ! roof water conductance
REAL, DIMENSION(SIZE(PTA)) :: ZAC_WL       ! wall conductance
REAL, DIMENSION(SIZE(PTA)) :: ZAC_TOP      ! top conductance
REAL, DIMENSION(SIZE(PTA)) :: ZQSAT_RD     ! hum of saturation for roads
REAL, DIMENSION(SIZE(PTA)) :: ZQSAT_GD     ! hum of saturation for green areas
REAL, DIMENSION(SIZE(PTA)) :: ZQSAT_RF     ! hum of saturation for roofs
REAL, DIMENSION(SIZE(PTA)) :: ZQSAT_GR     ! hum of saturation for green roofs
!
! coefficients for LW computations over snow (from previous time-step)
!
REAL, DIMENSION(SIZE(PTA)) :: ZTSSN_RF   ! roof snow temp at previous time-step
REAL, DIMENSION(SIZE(PTA)) :: ZTSSN_RD   ! road snow temp at previous time-step
REAL, DIMENSION(SIZE(PTA)) :: ZESN_RF    ! snow emissivity at previous time-step
REAL, DIMENSION(SIZE(PTA)) :: ZESN_RD    ! snow emissivity at previous time-step
!
! incoming shortwave radiation
!
REAL, DIMENSION(SIZE(PTA)) :: ZDIR_SW             ! direct  solar rad
REAL, DIMENSION(SIZE(PTA)) :: ZSCA_SW             ! diffuse solar rad
INTEGER                    :: JSWB
!
! albedo & emissivity
!
REAL, DIMENSION(SIZE(PTA)) :: ZALB_GD    ! albedo     for green areas
REAL, DIMENSION(SIZE(PTA)) :: ZEMIS_GD   ! emissivity for green areas
REAL, DIMENSION(SIZE(PTA)) :: ZALB_GR    ! albedo     for green roofs
REAL, DIMENSION(SIZE(PTA)) :: ZEMIS_GR   ! emissivity for green roofs
!
REAL, DIMENSION(SIZE(PTA)) :: ZALBNIR_TVEG_GD      ! nearIR  veg tot albedo
REAL, DIMENSION(SIZE(PTA)) :: ZALBVIS_TVEG_GD      ! visible veg tot albedo
REAL, DIMENSION(SIZE(PTA)) :: ZALBNIR_TSOIL_GD     ! nearIR  soil tot albedo
REAL, DIMENSION(SIZE(PTA)) :: ZALBVIS_TSOIL_GD     ! visible soil tot albedo
!
REAL, DIMENSION(SIZE(PTA)) :: ZALBNIR_TVEG_GR      ! nearIR  veg tot albedo
REAL, DIMENSION(SIZE(PTA)) :: ZALBVIS_TVEG_GR      ! visible veg tot albedo
REAL, DIMENSION(SIZE(PTA)) :: ZALBNIR_TSOIL_GR     ! nearIR  soil tot albedo
REAL, DIMENSION(SIZE(PTA)) :: ZALBVIS_TSOIL_GR     ! visible soil tot albedo
!
! radiation received by surfaces
!
REAL, DIMENSION(SIZE(PTA)) :: ZREC_SW_RD      ! solar rad received by roads
REAL, DIMENSION(SIZE(PTA)) :: ZREC_SW_WL_A    ! solar rad received by walls
REAL, DIMENSION(SIZE(PTA)) :: ZREC_SW_WL_B    ! solar rad received by walls
REAL, DIMENSION(SIZE(PTA)) :: ZREC_SW_GD      ! solar rad received by gardens
REAL, DIMENSION(SIZE(PTA)) :: ZREC_SW_SN_RD   ! solar rad received by snow on roads
!
REAL, DIMENSION(SIZE(PTA)) :: ZREC_LW_GD      ! IR rad received by gardens
!
REAL, DIMENSION(SIZE(PTA)) :: ZSW_RAD_GD      ! solar radiation reaching urban green areas
REAL, DIMENSION(SIZE(PTA)) :: ZREC_SW_RF      ! solar rad received by roofs in presence of solar panels
!
! coefficients for LW contributions
!
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WA_TO_WB        ! LW contrib. wall       -> opposite wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WA_TO_R         ! LW contrib. wall       -> road
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WB_TO_R         ! LW contrib. wall       -> road
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WA_TO_G         ! LW contrib. wall       -> green
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WB_TO_G         ! LW contrib. wall       -> green
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WA_TO_WIN       ! Radiative heat trasfer coeff wall-window 
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WB_TO_WIN       ! Radiative heat trasfer coeff wall-window 
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WA_TO_NR        ! LW contrib. wall       -> road(snow)
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WB_TO_NR        ! LW contrib. wall       -> road(snow)
REAL, DIMENSION(SIZE(PTA)) :: ZLW_R_TO_WA         ! LW contrib. road       -> wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_R_TO_WB         ! LW contrib. road       -> wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_R_TO_WIN        ! Radiative heat trasfer coeff road-window 
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(SIZE(PTA)) :: ZLW_G_TO_WA         ! LW contrib. green      -> wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_G_TO_WB         ! LW contrib. green      -> wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_G_TO_WIN        ! L.W. interactions GARDEN areas->road
                                                  !
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WIN_TO_WA       ! Radiative heat trasfer coeff window-wall
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WIN_TO_WB       ! Radiative heat trasfer coeff window-wall
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WIN_TO_R        ! Radiative heat trasfer coeff window-road 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WIN_TO_G        ! Radiative heat trasfer coeff window-garden 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(SIZE(PTA)) :: ZLW_WIN_TO_NR       ! Radiative heat trasfer coeff window-road(snow) 
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(SIZE(PTA)) :: ZLW_S_TO_WA         ! LW contrib. sky        -> wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_S_TO_WB         ! LW contrib. sky        -> wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_S_TO_R          ! LW contrib. sky        -> road
REAL, DIMENSION(SIZE(PTA)) :: ZLW_S_TO_G          ! LW contrib. sky        -> green
REAL, DIMENSION(SIZE(PTA)) :: ZLW_S_TO_WIN        ! Radiative heat trasfer coeff window-sky 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(SIZE(PTA)) :: ZLW_S_TO_NR         ! LW contrib. sky        -> road(snow)
REAL, DIMENSION(SIZE(PTA)) :: ZLW_NR_TO_WA        ! LW contrib. road(snow) -> wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_NR_TO_WB        ! LW contrib. road(snow) -> wall
REAL, DIMENSION(SIZE(PTA)) :: ZLW_NR_TO_WIN       ! L.W. interactions snow(road)->GARDEN areas
                                                  !
REAL, DIMENSION(SIZE(PTA)) :: ZREC_SW_WIN         ! solar received by windows [W m-2(win)]
REAL, DIMENSION(SIZE(PTA)) :: ZT_SKY              ! sky temperature [K]
REAL, DIMENSION(SIZE(PTA)) :: ZREC_LW_RF          ! Incoming LW on roofs in presence of solar panels
!
! local variable at previous time-step
!
REAL, DIMENSION(SIZE(PTA)) :: ZPET_A_COEF          
REAL, DIMENSION(SIZE(PTA)) :: ZPET_B_COEF          
REAL, DIMENSION(SIZE(PTA)) :: ZPEQ_A_COEF          
REAL, DIMENSION(SIZE(PTA)) :: ZPEQ_B_COEF          
!
REAL, DIMENSION(SIZE(PTA)) :: ZUW_RD       ! momentum flux for roads
REAL, DIMENSION(SIZE(PTA)) :: ZUW_GD       ! momentum flux for green areas
REAL, DIMENSION(SIZE(PTA)) :: ZUW_GR       ! momentum flux for green roofs
REAL, DIMENSION(SIZE(PTA)) :: ZDUWDU_RD    !
!
REAL, DIMENSION(SIZE(PTA)) :: ZAC_AGG_GD   ! aggreg. aeodynamic resistance for green areas
REAL, DIMENSION(SIZE(PTA)) :: ZHU_AGG_GD   ! aggreg. relative humidity for green areas
REAL, DIMENSION(SIZE(PTA)) :: ZAC_AGG_GR   ! aggreg. aeodynamic resistance for green roofs
REAL, DIMENSION(SIZE(PTA)) :: ZHU_AGG_GR   ! aggreg. relative humidity for green roofs
!
!  surfaces relative fractions
!
REAL, DIMENSION(SIZE(PTA)) :: ZRF_FRAC        ! roof, wall and
REAL, DIMENSION(SIZE(PTA)) :: ZWL_FRAC        ! road fractions
REAL, DIMENSION(SIZE(PTA)) :: ZRD_FRAC        ! of exchange surf.
REAL, DIMENSION(SIZE(PTA)) :: ZGD_FRAC        !                  
REAL, DIMENSION(SIZE(PTA)) :: ZTOTS_O_HORS    ! total canyon+roof surface
!                                             ! over horizontal surface
REAL, DIMENSION(SIZE(PTA)) :: ZWL_O_RD        ! wall surface over road surface
REAL, DIMENSION(SIZE(PTA)) :: ZWL_O_GRND      ! wall surface over (road+green area) surface
!
! surface temperatures
!
REAL, DIMENSION(SIZE(PTA)) :: ZMTC_O_GR_R1 ! mean thermal conductivity over distance 
!                                          ! between two layers (bottom GR & roof)
!
! fluxes from green surfaces
!
REAL, DIMENSION(SIZE(PTA)) :: ZSFCO2_GD      ! CO2 fluxes (m/s*kg_CO2/kg_air)
REAL, DIMENSION(SIZE(PTA)) :: ZEMIT_LW_GD    ! LW flux emitted by the garden (W/m2 garden)
REAL, DIMENSION(SIZE(PTA)) :: ZSFCO2_GR      ! CO2 fluxes over greenroofs (m/s*kg_CO2/kg_air)
!
! fluxes from built surfaces
REAL, DIMENSION(SIZE(PTA)) :: ZEMIT_LW_RD    ! LW flux emitted by the road (W/m2 road)
!
! fluxes from/to solar panel
REAL, DIMENSION(SIZE(PTA)) :: ZEMIT_LWDN_PANEL  ! LW flux emitted DOWNWARDS by the solar panel (W/m2 panel)
REAL, DIMENSION(SIZE(PTA)) :: ZEMIT_LWUP_PANEL  ! LW flux emitted UPWARDS   by the solar panel (W/m2 panel)
REAL, DIMENSION(SIZE(PTA)) :: ZEMIT_LW_RF       ! LW flux emitted UPWARDS   by the roof        (W/m2 roof )
!
REAL, DIMENSION(SIZE(PTA)) :: ZRN_GD, ZH_GD, ZLE_GD, ZGFLUX_GD, ZEVAP_GD, ZTSRAD_GD, ZRUNOFF_GD
REAL, DIMENSIOn(SIZE(PTA)) :: ZRN_GR, ZH_GR, ZLE_GR, ZGFLUX_GR
REAL, DIMENSION(SIZE(PTA)) :: ZEVAP_GR, ZTSRAD_GR, ZRUNOFF_GR, ZDRAIN_GR 
!
!new local variables for shading
REAL, DIMENSION(SIZE(PTA)) :: ZE_SHADING          ! energy not ref., nor absorbed, nor
                                                  ! trans. by glazing [Wm-2(win)]
LOGICAL, DIMENSION(SIZE(PTA)) :: GSHADE           ! describes if one encounters the
!                                                 ! conditions to close windows
INTEGER :: JJ

REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*      1.     Initializations
!              ---------------
!
!*      1.0    broadband radiative fluxes
!              --------------------------
!
IF (lhook) CALL dr_hook('TEB_GARDEN',0,zhook_handle)
!
gddk   => gdm%VD%ND%AL(kteb_p)
gddek  => gdm%VD%NDE%AL(kteb_p)
gddmk  => gdm%VD%NDM%AL(kteb_p)
!
grdk   => grm%VD%ND%AL(kteb_p)
grdek  => grm%VD%NDE%AL(kteb_p)
grdmk  => grm%VD%NDM%AL(kteb_p)
!
zdir_sw(:) = 0.
zsca_sw(:) = 0.
!
DO jswb=1,ksw
  DO jj=1,SIZE(pdir_sw,1)
    zdir_sw(jj) = zdir_sw(jj) + pdir_sw(jj,jswb)
    zsca_sw(jj) = zsca_sw(jj) + psca_sw(jj,jswb)
  ENDDO
END DO
!
!
!*      1.1    surfaces relative fractions
!              ---------------------------
!
DO jj=1,SIZE(t%XROAD)
  IF (t%XROAD(jj) .GT. 0.) THEN
    ztots_o_hors(jj) = 1. + t%XWALL_O_HOR(jj)
    zrf_frac(jj) = t%XBLD       (jj) / ztots_o_hors(jj)
    zwl_frac(jj) = t%XWALL_O_HOR(jj) / ztots_o_hors(jj)
    zrd_frac(jj) = t%XROAD      (jj) / ztots_o_hors(jj)
    zgd_frac(jj) = t%XGARDEN    (jj) / ztots_o_hors(jj)
    zwl_o_rd(jj) = zwl_frac(jj) / zrd_frac(jj)
    zwl_o_grnd(jj) = zwl_frac(jj) / (zrd_frac(jj)+zgd_frac(jj))
  ELSEIF (t%XBLD(jj) .EQ. 0. .AND. t%XROAD(jj) .EQ. 0.) THEN
    ztots_o_hors(jj) = 1. + t%XWALL_O_HOR(jj)
    zrf_frac(jj) = 0.
    zwl_frac(jj) = t%XWALL_O_HOR(jj) / ztots_o_hors(jj)
    zrd_frac(jj) = 0.
    zgd_frac(jj) = t%XGARDEN    (jj) / ztots_o_hors(jj)
    zwl_o_rd(jj) = 0.
    zwl_o_grnd(jj) = zwl_frac(jj) / zgd_frac(jj)
  ENDIF
ENDDO
!
!-------------------------------------------------------------------------------
!
!*      2.     Snow-covered surfaces relative effects
!              --------------------------------------
!
!*      2.1    Snow-covered surfaces relative fractions (at previous time-step)
!              ----------------------------------------
 CALL snow_frac_road(t%TSNOW_ROAD%WSNOW(:,1),psr(:)>0.,zdn_rd,zdf_rd)
 CALL snow_frac_roof(t%TSNOW_ROOF%WSNOW(:,1),psr(:)>0.,zdn_rf,zdf_rf)
!
!* new snow albedo
!
WHERE (t%TSNOW_ROAD%WSNOW(:,1)==0. .AND. psr(:)>0.) t%TSNOW_ROAD%ALB(:) = xansmax
WHERE (t%TSNOW_ROOF%WSNOW(:,1)==0. .AND. psr(:)>0.) t%TSNOW_ROOF%ALB(:) = xansmax
!
!*      2.2    If snow was not present at previous time-step but is falling
!              ------------------------------------------------------------
!
WHERE (t%TSNOW_ROAD%WSNOW(:,1)==0. .AND. psr(:)>0.)
  t%TSNOW_ROAD%ALB (:) = xansmax
  t%TSNOW_ROAD%EMIS(:) = xemissn
  t%TSNOW_ROAD%TS  (:) = min(t%XT_ROAD(:,1), xtt)
END WHERE
WHERE (t%TSNOW_ROOF%WSNOW(:,1)==0. .AND. psr(:)>0.)
  t%TSNOW_ROOF%ALB (:) = xansmax
  t%TSNOW_ROOF%EMIS(:) = xemissn
  t%TSNOW_ROOF%TS  (:) = min(t%XT_ROOF(:,1), xtt)
END WHERE
!
!*      2.3    Radiative snow variables at previous time-step
!              ----------------------------------------------
!
zesn_rf(:) = t%TSNOW_ROOF%EMIS(:)
zesn_rd(:) = t%TSNOW_ROAD%EMIS(:)
ztssn_rf(:) = t%TSNOW_ROOF%TS  (:)
ztssn_rd(:) = t%TSNOW_ROAD%TS  (:)
!
!-------------------------------------------------------------------------------
!
!*      3.     Extrapolation of atmospheric T and q at roof level (for fluxes computation)
!              --------------------------------------------------
!
zta(:) = pta(:) * pexns(:) / pexna(:)
zqa(:) = pqa(:) * qsat(zta(:),pps(:)) / qsat(pta(:),ppa(:))
!
!-------------------------------------------------------------------------------
!

!*      4.     Grid-averaged albedo and emissivity of green areas
!              --------------------------------------------------
!
zalb_gd   = xundef
zemis_gd  = xundef
ztsrad_gd = xundef
!
IF (top%LGARDEN) THEN
 CALL teb_veg_properties(t%XGARDEN, gdm%O, gdm%NPE%AL(kteb_p), &
                        pdir_sw, psca_sw, psw_bands, ksw,   &
                        ztsrad_gd, zemis_gd, zalb_gd,       &
                        pta=pt_lowcan,                      &
                        palbnir_tveg=zalbnir_tveg_gd,       &
                        palbvis_tveg=zalbvis_tveg_gd,       &
                        palbnir_tsoil=zalbnir_tsoil_gd,     &
                        palbvis_tsoil=zalbvis_tsoil_gd     )
ENDIF
!
! for greenroofs :
!
zalb_gr   = xundef
zemis_gr  = xundef
ztsrad_gr = xundef
!
IF (top%LGREENROOF) THEN
 CALL teb_veg_properties(t%XGREENROOF, grm%O, grm%NPE%AL(kteb_p), &
                           pdir_sw, psca_sw, psw_bands, ksw,    &
                           ztsrad_gr, zemis_gr, zalb_gr,        &
                           pta=pta,                             &
                           palbnir_tveg=zalbnir_tveg_gr,        &
                           palbvis_tveg=zalbvis_tveg_gr,        &
                           palbnir_tsoil=zalbnir_tsoil_gr,      &
                           palbvis_tsoil=zalbvis_tsoil_gr  ) 
ENDIF
!
!-------------------------------------------------------------------------------
!
!*      5.     Occupation of buildings
!              -----------------------
!
!* when building in unoccupied, target temperature is modified
!
IF (top%CBEM=="BEM") THEN
  CALL bld_occ_calendar(top%TTIME, ptsun, t, b, 1., dmt%XTCOOL_TARGET, dmt%XTHEAT_TARGET, dmt%XQIN )
ENDIF
!
!-------------------------------------------------------------------------------
!
!*      5.     Solar radiation
!              ---------------
!
!
!*       5.1   Windows management
!              ------------------
!
!* checks if one encouters the conditions for closing the windows at day
!  (needs to be equiped of solar protections and not to be confortable inside)
!  
gshade(:) = .false.
IF (top%CBEM=="BEM") THEN
 CALL window_shading_availability(b%LSHADE, b%XTI_BLD, dmt%XTCOOL_TARGET, gshade)
!
!* Reinitialize shading of windows when changing day
!
  WHERE (ptsun .LT. ptstep + 1e-3) b%LSHAD_DAY(:) = .false.
END IF
!
!
!*       5.2   computes solar radiation exchanges
!              ----------------------------------
!
 CALL urban_solar_abs(top, t, b, dmt, zdir_sw, zsca_sw, pzenith, pazim,  &
                      tpn%XFRAC_PANEL, tpn%XALB_PANEL, zalb_gd,     &
                      t%XSVF_GARDEN, zalb_gr, zdn_rf, zdf_rf,       &
                      zdn_rd, zdf_rd, zrec_sw_rd, zrec_sw_sn_rd,    &
                      zrec_sw_wl_a, zrec_sw_wl_b, zrec_sw_gd,       &
                      zrec_sw_rf, pdir_alb_twn, psca_alb_twn,       &
                      zsw_rad_gd, zrec_sw_win,pref_sw_grnd,         &
                      pref_sw_fac, ze_shading, b%LSHAD_DAY, gshade )
!
!-------------------------------------------------------------------------------
!
!*      6.     LW properties
!              -------------
!
  CALL urban_lw_coef(b, t, plw_rad, zemis_gd, t%TSNOW_ROAD%TS, ztsrad_gd,  &
                     zlw_wa_to_wb, zlw_wa_to_r, zlw_wb_to_r,            &
                     zlw_wa_to_nr, zlw_wb_to_nr, zlw_wa_to_g,           &
                     zlw_wb_to_g, zlw_wa_to_win, zlw_wb_to_win,         &
                     zlw_r_to_wa, zlw_r_to_wb, zlw_r_to_win,            &
                     zlw_g_to_wa, zlw_g_to_wb, zlw_g_to_win,            &
                     zlw_s_to_wa, zlw_s_to_wb, zlw_s_to_r,              &
                     zlw_s_to_nr, zlw_s_to_g,zlw_s_to_win,              &
                     zlw_win_to_wa, zlw_win_to_wb, zlw_win_to_r,        &
                     zlw_win_to_nr, zlw_win_to_g, zlw_nr_to_wa,         &
                     zlw_nr_to_wb, zlw_nr_to_win          )
!
!-------------------------------------------------------------------------------
!
! The subroutine is splitted in 2 because of compilation optimization issues
 CALL teb_garden2
 CALL teb_garden3
!
IF (lhook) CALL dr_hook('TEB_GARDEN',1,zhook_handle)
!-------------------------------------------------------------------------------
CONTAINS
!-------------------------------------------------------------------------------
SUBROUTINE teb_garden2
!
!*      7.     Terms of radiation absorption
!              -----------------------------
!
!*      7.1    IR rad received by gardens (snow free and snow covered separately)
!              --------------------------
!
IF (top%LGARDEN) THEN
  zt_sky(:) = (plw_rad(:)/xstefan)**0.25
  zrec_lw_gd(:) = (zlw_s_to_g(:) * (zt_sky(:)       - ztsrad_gd(:))   &
                 + zlw_wa_to_g(:) * (t%XT_WALL_A(:,1)- ztsrad_gd(:))   &
                 + zlw_wb_to_g(:) * (t%XT_WALL_B(:,1)- ztsrad_gd(:))   &
                 + zlw_win_to_g(:) * (b%XT_WIN1(:)    - ztsrad_gd(:)) ) &
                   / zemis_gd(:) + xstefan * ztsrad_gd(:)**4
ELSE
  zrec_lw_gd(:) = xundef
END IF
!
!*     7.2     Effect of solar panels on incoming LW on roofs
!              ----------------------------------------------
!
IF (top%LSOLAR_PANEL) THEN
  !
  ! solar panels downwards surface is supposed to be at air temperature
  ! and to be have an emissivity of 1.
  !
  zemit_lwdn_panel = xstefan * pta**4
  !
  ! note that, for the time being, one considers that the solar panel 
  ! intercept radiation both above roof and greenroofs (if any)
  zrec_lw_rf = (1.-tpn%XFRAC_PANEL(:)) * plw_rad + tpn%XFRAC_PANEL(:) * zemit_lwdn_panel
ELSE
  zemit_lwdn_panel = xundef
  zrec_lw_rf       = plw_rad
END IF
!
!-------------------------------------------------------------------------------
!
!*      8.     Treatment of green areas
!              ------------------------
!
!*      8.1    Implicit coeefs for T and Q
!              ---------------------------
!
!* explicit coupling for the time being.
!  canopy may need implicitation if there is a lot a garden in the grid mesh
!
zpet_a_coef(:) = 0.
zpet_b_coef(:) = pt_lowcan(:) / pexns(:)
zpeq_a_coef(:) = 0.
zpeq_b_coef(:) = pq_lowcan(:)
!
!*      8.2    Call ISBA for green areas
!              -------------------------
!
IF (top%LGARDEN) THEN
!
  CALL garden(dtco, g, t, top, tir, gdm%DTV, gdm%GB, gddk, gddek, gddmk,                &
              gdm%O, gdm%S, gdm%K, gdm%P, gdm%NPE%AL(kteb_p),                           &
              himplicit_wind, top%TTIME, ptsun, ppew_a_coef_lowcan, ppew_b_coef_lowcan, &
              zpet_a_coef, zpeq_a_coef, zpet_b_coef, zpeq_b_coef, ptstep, pz_lowcan,    &
              pt_lowcan, pq_lowcan, pexns, prhoa, pco2, pps, prr, psr, pzenith,         &
              zrec_sw_gd, zrec_lw_gd, pu_lowcan, zalbnir_tveg_gd, zalbvis_tveg_gd,      &
              zalbnir_tsoil_gd, zalbvis_tsoil_gd, zrn_gd, zh_gd, zle_gd, zgflux_gd,     &
              zsfco2_gd, zevap_gd, zuw_gd, zrunoff_gd, pac_gd, zqsat_gd, ztsrad_gd,     &
              zac_agg_gd, zhu_agg_gd, dmt%XIRRIG_GARDEN )  

  pac_gd_wat(:) = pac_gd(:)
  dmt%XABS_SW_GARDEN(:) = (1.-zalb_gd(:)) * zrec_sw_gd
  dmt%XABS_LW_GARDEN(:) = zemis_gd(:) * zrec_lw_gd(:) - xstefan * zemis_gd(:) * ztsrad_gd(:)**4 
  zemit_lw_gd(:) = xstefan * ztsrad_gd(:)**4 + (1 - zemis_gd(:)) / zemis_gd(:) * dmt%XABS_LW_GARDEN(:)

ELSE
  !
  zrn_gd(:) = 0.
  zh_gd(:) = 0.
  zle_gd(:) = 0.
  zgflux_gd(:) = 0.
  zevap_gd(:) = 0.
  zrunoff_gd(:) = 0. 
  ! 
  ztsrad_gd(:) = xundef
  !
  zuw_gd(:) = 0.
  pac_gd(:) = 0.
  zsfco2_gd(:) = 0.
  zqsat_gd(:) = xundef
  zac_agg_gd(:) = xundef
  zhu_agg_gd(:) = xundef
  pac_gd_wat(:) = xundef 
  zemit_lw_gd(:) = 0.
  !
  dmt%XABS_SW_GARDEN (:) = xundef
  dmt%XABS_LW_GARDEN (:) = xundef
  !
  dmt%XIRRIG_GARDEN  (:) = 0.
  !
ENDIF
!
!*      8.3    Call ISBA for greenroofs
!              -------------------------
!
IF (top%LGREENROOF) THEN
  !
  CALL greenroof(dtco, g, t, top, tir, grm%DTV, grm%GB, grdk, grdek,                 &
                 grdmk, grm%O, grm%S, grm%K, grm%P, grm%NPE%AL(kteb_p),              &
                 himplicit_wind, top%TTIME, ptsun, ppew_a_coef, ppew_b_coef,         &
                 zpet_a_coef, zpeq_a_coef, zpet_b_coef, zpeq_b_coef, ptstep, pzref,  &
                 puref, pta, pqa, pexns, pexna,prhoa, pco2, pps, prr, psr, pzenith,  &
                 zrec_sw_rf, zrec_lw_rf, pvmod,zalbnir_tveg_gr, zalbvis_tveg_gr,     &
                 zalbnir_tsoil_gr, zalbvis_tsoil_gr, zrn_gr, zh_gr, zle_gr,          &
                 zgflux_gr, zsfco2_gr, zevap_gr, zuw_gr, zrunoff_gr, zdrain_gr,      &
                 pac_gr, zqsat_gr, ztsrad_gr, zac_agg_gr, zhu_agg_gr,                &
                 dmt%XG_GREENROOF_ROOF, dmt%XIRRIG_GREENROOF ) 
  !
  pac_gr_wat(:) = pac_gr(:)
  dmt%XABS_SW_GREENROOF(:) = (1.-zalb_gr(:)) * zrec_sw_rf
  dmt%XABS_LW_GREENROOF(:) = zemis_gr * zrec_lw_rf - xstefan * zemis_gr * ztsrad_gr**4

ELSE
  !
  zrn_gr(:) = 0.
  zh_gr(:) = 0.
  zle_gr(:) = 0.
  zgflux_gr(:) = 0.
  zevap_gr(:) = 0.
  zrunoff_gr(:) = 0.
  zdrain_gr(:) = 0.  
  !
  ztsrad_gr(:) = xundef
  !
  zuw_gr(:) = 0.
  pac_gr(:) = 0.
  zsfco2_gr(:) = 0.
  zqsat_gr(:) = xundef
  zac_agg_gr(:) = xundef
  zhu_agg_gr(:) = xundef 
  zmtc_o_gr_r1(:) = xundef 
  !
  dmt%XIRRIG_GREENROOF (:) = 0.
  dmt%XABS_SW_GREENROOF(:) = xundef
  dmt%XABS_LW_GREENROOF(:) = xundef
  dmt%XG_GREENROOF_ROOF(:) = xundef
  !
ENDIF

END SUBROUTINE teb_garden2
!-------------------------------------------------------------------------------
SUBROUTINE teb_garden3
!
!*     9.      Treatment of built covers
!              -------------------------
!
  CALL teb  (top, t, bop, b, tir, dmt, himplicit_wind,                             &
             ptsun, pt_can, pq_can, pu_can, pt_lowcan, pq_lowcan, pu_lowcan,       &
             pz_lowcan, ppew_a_coef, ppew_b_coef, ppew_a_coef_lowcan,              &
             ppew_b_coef_lowcan, pps, ppa, pexns, pexna, pta, pqa, prhoa, plw_rad, &
             prr, psr, pzref, puref, pvmod, ph_traffic, ple_traffic, ptstep,       &
             zdf_rf, zdn_rf, zdf_rd, zdn_rd, zqsat_rf, zqsat_rd, zdelt_rf,         &
             zdelt_rd, ztsrad_gd, plew_rf, zuw_gr, plew_rd, ple_wl_a,              &
             ple_wl_b, prnsn_rf, phsn_rf, plesn_rf, pgsn_rf, pmelt_rf,             &
             zrn_gr, zh_gr, zle_gr, zgflux_gr, zdrain_gr, zrunoff_gr,              &
             prnsn_rd, phsn_rd, plesn_rd, pgsn_rd, pmelt_rd, zuw_rd, puw_rf,       &
             zduwdu_rd, pduwdu_rf, pustar_twn, pcd, pcdn, pch_twn, pri_twn, presa_twn, &
             zac_rf, pac_rd, zac_wl, zac_top, pac_gd, zac_rf_wat, pac_rd_wat,      &
             zlw_wa_to_wb, zlw_wa_to_r, zlw_wb_to_r, zlw_wa_to_nr, zlw_wb_to_nr,   &
             zlw_r_to_wa, zlw_r_to_wb, zlw_g_to_wa, zlw_g_to_wb, zlw_s_to_wa,      &
             zlw_s_to_wb, zlw_s_to_r, zlw_s_to_nr, zlw_nr_to_wa, zlw_nr_to_wb,     &
             zlw_nr_to_win, zlw_wa_to_win, zlw_wb_to_win, zlw_g_to_win,            &
             zlw_r_to_win, zlw_s_to_win, zlw_win_to_wa, zlw_win_to_wb,             &
             zlw_win_to_r, zlw_win_to_nr, kday, pemit_lw_fac, zemit_lw_rd,         &
             pt_rad_ind, phu_bld, ptime, ze_shading )
!
!-------------------------------------------------------------------------------
!
!*    10.      Treatment of solar panels
!              -------------------------
!
IF (top%LSOLAR_PANEL) THEN
  ! 
  !* LW radiation coming upwards from roofs
  !
  zemit_lw_rf =  zrec_lw_rf   &
     - (        t%XGREENROOF(:)  *             dmt%XABS_LW_GREENROOF(:)  &
          + (1.-t%XGREENROOF(:)) * zdf_rf(:) * dmt%XABS_LW_ROOF(:)       &
          + (1.-t%XGREENROOF(:)) * zdn_rf(:) * dmt%XABS_LW_SNOW_ROOF(:) )
  !
  ! note that, for the time being, one considers that the solar panel 
  ! intercept radiation both above roof and greenroofs (if any)
  CALL solar_panel(tpn, dmt, ptstep, ptsun, t%XRESIDENTIAL, zemit_lw_rf, zemit_lwdn_panel, &
                   plw_rad, pta, b%XN_FLOOR, pprod_bld   )
ELSE
  pprod_bld        = xundef  
END IF
!-------------------------------------------------------------------------------
!
!*     11.     Aggregation
!              -----------
!
 CALL avg_urban_fluxes(top, t, b, tpn, dmt,                                               &
                       pts_twn, pemis_twn, pt_can, pq_can, pt_lowcan, pq_lowcan,          &
                       zta, zqa, prhoa, pps, ph_traffic,  ple_traffic, zwl_o_grnd,        &
                       zesn_rf, zemis_gr, plw_rad,  zac_rf, zac_rf_wat, zac_wl, pac_rd,  &
                       pac_rd_wat, zac_top, pac_gd, zqsat_gd, zac_agg_gd, zhu_agg_gd,     &
                       zqsat_rf, zqsat_rd, zdelt_rf, zdelt_rd, zrf_frac, zwl_frac,        &
                       zrd_frac, zgd_frac, ztots_o_hors, zdf_rf, zdn_rf, zdf_rd, zdn_rd,  &
                       ple_wl_a, ple_wl_b, plew_rf, plesn_rf, plew_rd, plesn_rd, phsn_rd, &
                       ztsrad_gd, zrn_gd, zh_gd, zle_gd, zgflux_gd, zevap_gd,             &
                       zrunoff_gd, zevap_gr, zrunoff_gr, zdrain_gr,                       &
                       prn_grnd, ph_grnd, ple_grnd, pgflx_grnd, prn_twn, ph_twn, ple_twn, &
                       pgflx_twn, pevap_twn, zemit_lw_rd,zemit_lw_gd, pemit_lw_grnd, zemis_gd )
!
psfco2(:) = t%XGARDEN(:) * zsfco2_gd(:) + t%XBLD(:) * t%XGREENROOF(:) * zsfco2_gr(:) ! no CO2 flux from built and road yet.
!
!-------------------------------------------------------------------------------
!
!*     12.     Momentum flux for ground built surfaces
!              ---------------------------------------
!
puw_grnd(:)     = (t%XROAD(:)*zuw_rd(:) + t%XGARDEN(:)*zuw_gd(:)) / (t%XROAD(:)+t%XGARDEN(:))
!
pduwdu_grnd(:)  = 0.
!
END SUBROUTINE teb_garden3
!
!-------------------------------------------------------------------------------
!
!
END SUBROUTINE teb_garden