urban_lw_coef.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!   ##########################################################################
    SUBROUTINE urban_lw_coef(B, T, PLW_RAD, PEMIS_G, PTS_SR, PTS_G,              &  
                             PLW_WA_TO_WB, PLW_WA_TO_R, PLW_WB_TO_R,             &
                             PLW_WA_TO_NR,PLW_WB_TO_NR,                          &
                             PLW_WA_TO_G, PLW_WB_TO_G,                           &
                             PLW_WA_TO_WIN, PLW_WB_TO_WIN,                       &
                             PLW_R_TO_WA, PLW_R_TO_WB, PLW_R_TO_WIN,             &
                             PLW_G_TO_WA, PLW_G_TO_WB, PLW_G_TO_WIN,             &
                             PLW_S_TO_WA, PLW_S_TO_WB, PLW_S_TO_R,               &
                             PLW_S_TO_NR, PLW_S_TO_G, PLW_S_TO_WIN,              &
                             PLW_WIN_TO_WA, PLW_WIN_TO_WB, PLW_WIN_TO_R,         &
                             PLW_WIN_TO_NR, PLW_WIN_TO_G,                        &
                             PLW_NR_TO_WA, PLW_NR_TO_WB, PLW_NR_TO_WIN           )
!   ##########################################################################
!
!!****  *URBAN_LW_COEF*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the coefficients before each of the temperatures in the
!     radiative budgets
!         
!     
!!**  METHOD
!     ------
!
!
!
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    08/09/98 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_bem_n, ONLY : bem_t
USE modd_teb_n, ONLY : teb_t
!
USE modd_csts,ONLY : xstefan
USE modd_surf_par,ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(bem_t), INTENT(INOUT) :: B
TYPE(teb_t), INTENT(INOUT) :: T
!
REAL, DIMENSION(:), INTENT(IN)  :: PLW_RAD  ! incoming LW radiation
REAL, DIMENSION(:), INTENT(IN)  :: PEMIS_G  ! GARDEN area emissivity
!
REAL, DIMENSION(:), INTENT(IN)  :: PTS_G    ! garden surface temperature
REAL, DIMENSION(:), INTENT(IN)  :: PTS_SR   ! snow surface temperature
!
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WA_TO_WB! L.W. interactions wall->opposite wall
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WA_TO_R  ! L.W. interactions wall->road for road balance 
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WB_TO_R  ! L.W. interactions wall->road for road balance 
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WA_TO_NR ! L.W. interactions wall->snow for snow balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WB_TO_NR ! L.W. interactions wall->snow for snow balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WA_TO_G  ! L.W. interactions wall->GARDEN areas for garden balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WB_TO_G  ! L.W. interactions wall->GARDEN areas for garden balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WA_TO_WIN! L.W. interactions wall->win for window balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WB_TO_WIN! L.W. interactions wall->win for window balance
!
REAL, DIMENSION(:), INTENT(OUT) :: PLW_R_TO_WA ! L.W. interactions road->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_R_TO_WB ! L.W. interactions road->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_R_TO_WIN  ! L.W. interactions road->win for win balance
!
REAL, DIMENSION(:), INTENT(OUT) :: PLW_G_TO_WA ! L.W. interactions GARDEN areas->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_G_TO_WB ! L.W. interactions GARDEN areas->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_G_TO_WIN  ! L.W. interactions GARDEN areas->road for window balance
!
REAL, DIMENSION(:), INTENT(OUT) :: PLW_S_TO_WA ! L.W. interactions sky->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_S_TO_WB ! L.W. interactions sky->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_S_TO_R  ! L.W. interactions sky->road for raod balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_S_TO_NR ! L.W. interactions sky->snow for snow balance 
REAL, DIMENSION(:), INTENT(OUT) :: PLW_S_TO_G  ! L.W. interactions sky->GARDEN areas for garden balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_S_TO_WIN ! L.W. interactions sky->win for window balance
!
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WIN_TO_WA ! L.W. interactions win->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WIN_TO_WB ! L.W. interactions win->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WIN_TO_R  ! L.W. interactions win->road for road balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WIN_TO_NR ! L.W. interactions win->GARDEN areas for snow balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_WIN_TO_G  ! L.W. interactions win->GARDEN areas for garden balance
!
REAL, DIMENSION(:), INTENT(OUT) :: PLW_NR_TO_WA! L.W. interactions snow(road)->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_NR_TO_WB! L.W. interactions snow(road)->wall for wall balance
REAL, DIMENSION(:), INTENT(OUT) :: PLW_NR_TO_WIN ! L.W. interactions snow(road)->WIN areas for window balance
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(T%XBLD))  :: ZT_S        ! sky temperature
!
REAL, DIMENSION(SIZE(T%XBLD))  :: ZEMIS_WIN
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_W_W
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_R_W
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_R_WIN
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_W_R
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_W_G
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_W_WIN
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_W_NR
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_WIN_W
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_WIN_R
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_WIN_G
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_WIN_NR
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_G_W
REAL, DIMENSION(SIZE(T%XBLD))  :: ZF_G_WIN
!
REAL :: ZE1, ZE2, ZF, ZT1, ZT2, ZLW
zlw(ze1,ze2,zf,zt1,zt2) = 4.*xstefan*ze1*ze2*zf*((zt1+zt2)/2.)**3
!
INTEGER :: JJ
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('URBAN_LW_COEF',0,zhook_handle)
!
zt_s(:) = (plw_rad(:)/xstefan)**0.25
!
DO jj=1,SIZE(t%XROAD)
  !
  zemis_win(jj) = 0.84 !from Energy Plus Engineering Reference, p219
    ! see http://apps1.eere.energy.gov/buildings/energyplus/
  !
  zf_w_r(jj)     = t%XSVF_WALL(jj) * (t%XROAD(jj)    /(1.-t%XBLD(jj)))
  zf_w_g(jj)     = t%XSVF_WALL(jj) * (t%XGARDEN(jj)  /(1.-t%XBLD(jj)))
  zf_w_nr(jj)    = t%XSVF_WALL(jj)    
  !  
  zf_win_r(jj)   = zf_w_r(jj)
  zf_win_g(jj)   = zf_w_g(jj)
  zf_win_nr(jj)  = zf_w_nr(jj)
  !
  zf_r_w(jj)     = (1 - t%XSVF_ROAD(jj))*(1.-b%XGR(jj)) * 0.5
  zf_r_win(jj)   = (1 - t%XSVF_ROAD(jj))*b%XGR(jj)
  !
  zf_g_w(jj)     = zf_r_w(jj) 
  zf_g_win(jj)   = zf_r_win(jj)    
  !
  zf_win_w(jj)   = (1.-2.*t%XSVF_WALL(jj))*(1.-b%XGR(jj))
  zf_w_w(jj)   = (1.-2.*t%XSVF_WALL(jj))*(1.-b%XGR(jj))
  zf_w_win(jj)   = (1.-2.*t%XSVF_WALL(jj))*b%XGR(jj)
  !
  !
  plw_wa_to_wb(jj)=zlw(t%XEMIS_WALL(jj),t%XEMIS_WALL(jj),zf_w_w(jj),t%XT_WALL_A(jj,1),t%XT_WALL_B(jj,1))
  !
  plw_wa_to_r(jj) = zlw(t%XEMIS_WALL(jj),t%XEMIS_ROAD(jj),zf_r_w(jj),t%XT_WALL_A(jj,1),t%XT_ROAD(jj,1))
  plw_wb_to_r(jj) = zlw(t%XEMIS_WALL(jj),t%XEMIS_ROAD(jj),zf_r_w(jj),t%XT_WALL_B(jj,1),t%XT_ROAD(jj,1))
  plw_r_to_wa(jj) = zlw(t%XEMIS_ROAD(jj),t%XEMIS_WALL(jj),zf_w_r(jj),t%XT_ROAD(jj,1),t%XT_WALL_A(jj,1))
  plw_r_to_wb(jj) = zlw(t%XEMIS_ROAD(jj),t%XEMIS_WALL(jj),zf_w_r(jj),t%XT_ROAD(jj,1),t%XT_WALL_B(jj,1))
  !
  IF (SIZE(pts_g)>0) THEN
    plw_wa_to_g(jj) = zlw(t%XEMIS_WALL(jj),pemis_g(jj),zf_g_w(jj),t%XT_WALL_A(jj,1),pts_g(jj))
    plw_wb_to_g(jj) = zlw(t%XEMIS_WALL(jj),pemis_g(jj),zf_g_w(jj),t%XT_WALL_B(jj,1),pts_g(jj))
    plw_g_to_wa(jj) = zlw(pemis_g(jj),t%XEMIS_WALL(jj),zf_w_g(jj),pts_g(jj),t%XT_WALL_A(jj,1))
    plw_g_to_wb(jj) = zlw(pemis_g(jj),t%XEMIS_WALL(jj),zf_w_g(jj),pts_g(jj),t%XT_WALL_B(jj,1))
  ELSE
    plw_wa_to_g(jj) = 0.
    plw_wb_to_g(jj) = 0.
    plw_g_to_wa(jj) = 0.
    plw_g_to_wb(jj) = 0.
  ENDIF
  !
  !
  IF (pts_sr(jj) .EQ. xundef) THEN
    plw_wa_to_nr(jj) = 0.
    plw_wb_to_nr(jj) = 0.
    plw_nr_to_wa(jj) = 0.
    plw_nr_to_wb(jj) = 0.
    !
    plw_win_to_nr(jj) = 0.
    plw_nr_to_win(jj) = 0
    !     
    plw_s_to_nr(jj) = 0.
  ELSE
    plw_wa_to_nr(jj) = zlw(t%XEMIS_WALL(jj),t%TSNOW_ROAD%EMIS(jj),zf_r_w(jj),t%XT_WALL_A(jj,1),pts_sr(jj))
    plw_wb_to_nr(jj) = zlw(t%XEMIS_WALL(jj),t%TSNOW_ROAD%EMIS(jj),zf_r_w(jj),t%XT_WALL_B(jj,1),pts_sr(jj))
    plw_nr_to_wa(jj) = zlw(t%TSNOW_ROAD%EMIS(jj),t%XEMIS_WALL(jj),zf_w_nr(jj),pts_sr(jj),t%XT_WALL_A(jj,1))    
    plw_nr_to_wb(jj) = zlw(t%TSNOW_ROAD%EMIS(jj),t%XEMIS_WALL(jj),zf_w_nr(jj),pts_sr(jj),t%XT_WALL_B(jj,1))    
    !
    plw_win_to_nr(jj)= zlw(zemis_win(jj),t%TSNOW_ROAD%EMIS(jj),zf_r_win(jj),b%XT_WIN1(jj),pts_sr(jj))
    plw_nr_to_win(jj)= zlw(t%TSNOW_ROAD%EMIS(jj),zemis_win(jj),zf_win_nr(jj),pts_sr(jj),b%XT_WIN1(jj))
    !
    plw_s_to_nr(jj) = zlw(1.,t%TSNOW_ROAD%EMIS(jj),t%XSVF_ROAD(jj),zt_s(jj),pts_sr(jj))
  ENDIF
  !
  plw_win_to_r(jj)= zlw(zemis_win(jj),t%XEMIS_ROAD(jj),zf_r_win(jj),b%XT_WIN1(jj),t%XT_ROAD(jj,1))
  plw_r_to_win(jj)= zlw(t%XEMIS_ROAD(jj),zemis_win(jj),zf_win_r(jj),t%XT_ROAD(jj,1),b%XT_WIN1(jj))
  !
  IF (SIZE(pts_g)>0) THEN
    plw_win_to_g(jj)= zlw(zemis_win(jj),pemis_g(jj),zf_g_win(jj),b%XT_WIN1(jj),pts_g(jj))
    plw_g_to_win(jj)= zlw(pemis_g(jj),zemis_win(jj),zf_win_g(jj),pts_g(jj),b%XT_WIN1(jj))
  ELSE
    plw_win_to_g(jj) = 0.
    plw_g_to_win(jj) = 0.
  ENDIF
  !  
  plw_win_to_wa(jj) = zlw(zemis_win(jj),t%XEMIS_WALL(jj),zf_w_win(jj),b%XT_WIN1(jj),t%XT_WALL_A(jj,1))
  plw_win_to_wb(jj) = zlw(zemis_win(jj),t%XEMIS_WALL(jj),zf_w_win(jj),b%XT_WIN1(jj),t%XT_WALL_B(jj,1))
  plw_wa_to_win(jj) = zlw(t%XEMIS_WALL(jj),zemis_win(jj),zf_win_w(jj),t%XT_WALL_A(jj,1),b%XT_WIN1(jj))
  plw_wb_to_win(jj) = zlw(t%XEMIS_WALL(jj),zemis_win(jj),zf_win_w(jj),t%XT_WALL_B(jj,1),b%XT_WIN1(jj))
  !
  plw_s_to_win(jj) = zlw(1.,zemis_win(jj),t%XSVF_WALL(jj),zt_s(jj),b%XT_WIN1(jj))
  !
  plw_s_to_wa(jj)  = zlw(1.,t%XEMIS_WALL(jj),t%XSVF_WALL(jj),zt_s(jj),t%XT_WALL_A(jj,1))
  plw_s_to_wb(jj)  = zlw(1.,t%XEMIS_WALL(jj),t%XSVF_WALL(jj),zt_s(jj),t%XT_WALL_B(jj,1))
  !
  IF (SIZE(pts_g)>0) THEN
    plw_s_to_g(jj)  = zlw(1.,pemis_g(jj),t%XSVF_ROAD(jj),zt_s(jj),pts_g(jj))
  ENDIF
  plw_s_to_r(jj)  = zlw(1.,t%XEMIS_ROAD(jj),t%XSVF_ROAD(jj),zt_s(jj),t%XT_ROAD(jj,1))  
  plw_s_to_nr(jj) = zlw(1.,t%TSNOW_ROAD%EMIS(jj),t%XSVF_ROAD(jj),zt_s(jj),pts_sr(jj))
  !
ENDDO
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('URBAN_LW_COEF',1,zhook_handle)
!
END SUBROUTINE urban_lw_coef