split_grid.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################
      SUBROUTINE split_grid(UG, U, HPROGRAM,KGRID_PAR,PGRID_PAR,KHALO)
!     ###########################################################
!!
!!    PURPOSE
!!    -------
!!   This program splits a PGD grid on several processors (according to host program)
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson                   Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original     08/11
!!    Modification 01/03/2015 pass KGRID_PAR,PGRID_PAR,KHALO as arguments (M.Moge)
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modi_split_grid_conf_proj
USE modi_split_grid_cartesian
USE modi_get_size_full_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
!
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
 CHARACTER(LEN=6),     INTENT(IN)  :: HPROGRAM ! program calling
!
INTEGER, OPTIONAL,           INTENT(INOUT)  :: KGRID_PAR ! size of PGRID_PAR pointer
REAL, DIMENSION(:), OPTIONAL, POINTER, INTENT(INOUT) :: PGRID_PAR ! parameters defining this grid
INTEGER,            INTENT(IN), OPTIONAL   :: KHALO ! size of the Halo
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
 CHARACTER(LEN=100) :: YCOMMENT
INTEGER :: IRESP, ISIZE_FULL ! error return code
INTEGER :: IHALO
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('SPLIT_GRID',0,zhook_handle)
!
#ifdef MNH_PARALLEL
IF (PRESENT(khalo)) THEN
  ihalo = khalo
ELSE
  ihalo = 0
ENDIF
#else
ihalo = 0
#endif
!
SELECT CASE(ug%G%CGRID)

  CASE('CONF PROJ ')
    IF (PRESENT(kgrid_par).AND.PRESENT(pgrid_par)) THEN
      CALL split_grid_conf_proj(hprogram,u%NDIM_FULL,u%NSIZE_FULL,kgrid_par,pgrid_par,ihalo)
    ELSE
      CALL split_grid_conf_proj(hprogram,u%NDIM_FULL,u%NSIZE_FULL,ug%G%NGRID_PAR,ug%G%XGRID_PAR)
    ENDIF

  CASE('CARTESIAN ')
    IF (PRESENT(kgrid_par).AND.PRESENT(pgrid_par)) THEN
      CALL split_grid_cartesian(hprogram,u%NDIM_FULL,u%NSIZE_FULL,kgrid_par,pgrid_par,ihalo)
    ELSE
      CALL split_grid_cartesian(hprogram,u%NDIM_FULL,u%NSIZE_FULL,ug%G%NGRID_PAR,ug%G%XGRID_PAR)
    ENDIF

  CASE DEFAULT
    CALL get_size_full_n(hprogram,u%NDIM_FULL,u%NSIZE_FULL,isize_full)
    u%NSIZE_FULL = isize_full

END SELECT
!

IF (lhook) CALL dr_hook('SPLIT_GRID',1,zhook_handle)
!_______________________________________________________________________________
!
END SUBROUTINE split_grid