split_grid_conf_proj.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################
      SUBROUTINE split_grid_conf_proj(HPROGRAM,KDIM_FULL,KSIZE_FULL,KGRID_PAR,PGRID_PAR,KHALO)
!     ###########################################################
!!
!!    PURPOSE
!!    -------
!!   This program splits a PGD grid on several processors (according to host program)
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson                   Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original     08/11
!!      M.Moge     02/15  using PGRID_PAR(11) instead of KDIM_FULL
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_conf_proj
USE mode_split_grid_parameter
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
!
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
 CHARACTER(LEN=6),   INTENT(IN)    :: HPROGRAM  ! host program 
INTEGER,            INTENT(IN)    :: KDIM_FULL ! total number of points
INTEGER,            INTENT(OUT)   :: KSIZE_FULL! number of points on this processor
INTEGER,            INTENT(INOUT) :: KGRID_PAR ! size of PGRID_PAR pointer
REAL, DIMENSION(:), POINTER       :: PGRID_PAR ! parameters defining this grid
INTEGER, OPTIONAL,  INTENT(IN)    :: KHALO ! size of the Halo
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!* original grid
REAL                            :: ZLAT0, ZLON0, ZRPK, ZBETA, ZLATOR, ZLONOR
INTEGER                         :: IIMAX, IJMAX
REAL, DIMENSION(INT(PGRID_PAR(11)))   :: ZX, ZY, ZDX, ZDY
!
!* splitted grid on processor
INTEGER                         :: IIMAX_SPLIT, IJMAX_SPLIT
REAL, DIMENSION(:), ALLOCATABLE :: ZX_SPLIT, ZY_SPLIT, ZDX_SPLIT, ZDY_SPLIT
!
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('SPLIT_GRID_CONF_PROJ',0,zhook_handle)
!
!*    1.      Gets Parameters of the Grid
!
 CALL get_gridtype_conf_proj(pgrid_par,zlat0,zlon0,zrpk,zbeta,&
                            zlator,zlonor,iimax,ijmax,       &
                            zx,zy,zdx,zdy                    )
!
!
!*    2.      Splits the (pertinent) parameters of the grid
!
IF (PRESENT(khalo)) THEN
  CALL split_grid_parametern0(hprogram,'CONF PROJ ','IMAX  ',iimax,iimax_split,khalo)
  CALL split_grid_parametern0(hprogram,'CONF PROJ ','JMAX  ',ijmax,ijmax_split,khalo)
ELSE
  CALL split_grid_parametern0(hprogram,'CONF PROJ ','IMAX  ',iimax,iimax_split)
  CALL split_grid_parametern0(hprogram,'CONF PROJ ','JMAX  ',ijmax,ijmax_split)
ENDIF
!
ksize_full = iimax_split * ijmax_split
!
ALLOCATE(zx_split(ksize_full))
ALLOCATE(zy_split(ksize_full))
ALLOCATE(zdx_split(ksize_full))
ALLOCATE(zdy_split(ksize_full))
!
IF (PRESENT(khalo)) THEN
  CALL split_grid_parameterx1(hprogram,'CONF PROJ ','XX    ',SIZE(zx),ksize_full,zx,zx_split,iimax,ijmax,khalo)
  CALL split_grid_parameterx1(hprogram,'CONF PROJ ','YY    ',SIZE(zy),ksize_full,zy,zy_split,iimax,ijmax,khalo)
  CALL split_grid_parameterx1(hprogram,'CONF PROJ ','DX    ',SIZE(zdx),ksize_full,zdx,zdx_split,iimax,ijmax,khalo)
  CALL split_grid_parameterx1(hprogram,'CONF PROJ ','DY    ',SIZE(zdy),ksize_full,zdy,zdy_split,iimax,ijmax,khalo)
ELSE
  CALL split_grid_parameterx1(hprogram,'CONF PROJ ','XX    ',kdim_full,ksize_full,zx,zx_split)
  CALL split_grid_parameterx1(hprogram,'CONF PROJ ','YY    ',kdim_full,ksize_full,zy,zy_split)
  CALL split_grid_parameterx1(hprogram,'CONF PROJ ','DX    ',kdim_full,ksize_full,zdx,zdx_split)
  CALL split_grid_parameterx1(hprogram,'CONF PROJ ','DY    ',kdim_full,ksize_full,zdy,zdy_split)
ENDIF
!
!
!*    3.      Stores Parameters of the Grid in grid pointer
!
NULLIFY(pgrid_par)
 CALL put_gridtype_conf_proj(pgrid_par,zlat0,zlon0,zrpk,zbeta,       &
                            zlator,zlonor,iimax_split,ijmax_split,  &
                            zx_split,zy_split,zdx_split,zdy_split   )
                            !
!
kgrid_par = SIZE(pgrid_par)
!
DEALLOCATE(zx_split )
DEALLOCATE(zy_split )
DEALLOCATE(zdx_split)
DEALLOCATE(zdy_split)
!
IF (lhook) CALL dr_hook('SPLIT_GRID_CONF_PROJ',1,zhook_handle)
!_______________________________________________________________________________
!
END SUBROUTINE split_grid_conf_proj