sfx_xios_setup.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
SUBROUTINE sfx_xios_setup(YSC, KCOMM, KLUOUT, KYEAR, KMONTH, KDAY, PTIME, PTSTEP, &
     KDIM1, KDIM2, KEXT1, PCLAT, PCLON, KXINDEX, ODXMASK,&
     KMASKNAT, KMASKSEA, KMASKWAT, KMASKTOWN)
!!
!!
!!     PURPOSE
!!     --------
!!
!!     Initialize all Surfex context for XIOS (calendar, grids, masks, model time step, ...)
!!
!!
!!     IMPLICIT ARGUMENTS :
!!     -------------------- 
!!
!!     LXIOS, YXIOS_CONTEXT, TXIOS_CONTEXT
!!
!!
!!     EXTERNAL
!!     --------
!!
!!     XIOS LIBRARY
!!
!!
!!     REFERENCE
!!     ---------
!!
!!     XIOS Reference guide - Yann Meurdesoif - 10/10/2014 - 
!!     svn co -r 515 http://forge.ipsl.jussieu.fr/ioserver/svn/XIOS/branchs/xios-1.0 <dir> ; cd <dir>/doc ; ....
!!
!!     AUTHOR
!!     ------
!!
!!     S.Sénési, CNRM
!!
!!     MODIFICATION
!!     --------------
!!
!!     Original    08/2015
!!
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surfex_n, ONLY : surfex_t

USE modd_csts,  ONLY : xpi
USE modd_surfex_mpi, ONLY     : nrank, nindex
!
USE modd_xios      , ONLY : lxios,txios_context,yxios_context, &
     lxios_def_closed, yground_layer_dim_name, &
     ywground_layer_dim_name, ywiground_layer_dim_name, nbase_xios_freq, &
     yswband_dim_name, ypatch_dim_name
!
#ifdef WXIOS 
USE xios, ONLY : xios_context_initialize, xios_get_handle,   &
     xios_set_current_context, xios_set_timestep, xios_date, &
     xios_duration, xios_define_calendar, xios_getvar,       &
     xios_solve_inheritance
!
USE modi_abor1_sfx
USE modi_sfx_xios_set_domain
USE modi_set_axis
!
#endif
!
USE yomhook           , ONLY : lhook,   dr_hook
USE parkind1          , ONLY : jprb
!
IMPLICIT NONE
!
!
!   Arguments
!
type(surfex_t),    INTENT(IN) :: ysc
!
INTEGER,            INTENT(INOUT) :: KCOMM  ! Communicator
INTEGER,            INTENT(IN) :: KLUOUT    ! Listing logical unit number
INTEGER,            INTENT(IN) :: KYEAR     ! current year (UTC)
INTEGER,            INTENT(IN) :: KMONTH    ! current month (UTC)
INTEGER,            INTENT(IN) :: KDAY      ! current day (UTC)
REAL,               INTENT(IN) :: PTIME     ! current time since midnight (UTC,s)
REAL,               INTENT(IN) :: PTSTEP    ! model time step 
INTEGER,            INTENT(IN) :: KDIM1     ! Geometry param. (see  sfx_set_domain)
INTEGER,            INTENT(IN) :: KDIM2     ! Geometry param. (see  sfx_set_domain)
INTEGER,            INTENT(IN) :: KEXT1     ! Geometry param. (see  sfx_set_domain)
REAL   ,   INTENT(IN) , DIMENSION(:,:) :: PCLAT      ! Lat corners "
REAL   ,   INTENT(IN) , DIMENSION(:,:) :: PCLON      ! Lon corners "
INTEGER,   INTENT(IN) , DIMENSION(:)   :: KXINDEX    ! index of proc cells in global grid
LOGICAL,   INTENT(IN) , DIMENSION(:)   :: ODXMASK    ! Cells mask
INTEGER,   INTENT(IN) , DIMENSION(:)   :: KMASKNAT   ! Masks for the whole MPI task
INTEGER,   INTENT(IN) , DIMENSION(:)   :: KMASKSEA
INTEGER,   INTENT(IN) , DIMENSION(:)   :: KMASKWAT
INTEGER,   INTENT(IN) , DIMENSION(:)   :: KMASKTOWN

!
!  Local variables
!
#ifdef WXIOS
TYPE(xios_duration)   :: TDTIME ! Time-step 'a la XIOS'
INTEGER               :: INHOURS,INMINUTES,INSECONDS
#endif
!
INTEGER            :: ITMP
!
REAL(KIND=JPRB)    :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('SFX_XIOS_SETUP',0,zhook_handle)
!
IF (.NOT. lxios ) THEN 
   CALL dr_hook('SFX_XIOS_SETUP',1,zhook_handle)
   RETURN
ENDIF
!
#ifndef WXIOS
!
IF (lxios) THEN 
   CALL abor1_sfx('SFX_XIOS_INIT_CONTEXT : cannot setup : Surfex was compiled without XIOS support')
ELSE
   lxios_def_closed=.true.
ENDIF
!
#else 
!
lxios_def_closed=.false.
!
! -----------------------------------------------------------------------------
!
!       Set Xios context to Surfex's one
!
! -----------------------------------------------------------------------------
!
!$OMP SINGLE
!
!#ifndef CPLOASIS
!  CALL XIOS_INITIALIZE('surfex', return_comm=KCOMM)
!#endif

 CALL xios_context_initialize(yxios_context, kcomm)
 CALL xios_get_handle(yxios_context, txios_context)
 CALL xios_set_current_context(txios_context)
! 

! -----------------------------------------------------------------------------
!
!      Set date for XIOS
!
! -----------------------------------------------------------------------------
!
inhours   = int(ptime/3600)
inminutes = int((ptime - inhours*3600)/60)
inseconds = int(ptime - inhours*3600 - inminutes*60)
!
!WRITE(KLUOUT,*) 'initializing xios calendar '

! For XIOS-2.0 :
 CALL xios_define_calendar("Gregorian", &
     start_date  = xios_date(kyear,kmonth,kday,inhours,inminutes,inseconds), &
     time_origin = xios_date(kyear,kmonth,kday,inhours,inminutes,inseconds))
!
! -----------------------------------------------------------------------------
!
!   Set duration between 2 calls to write_diag_surf
!
! -----------------------------------------------------------------------------
!
IF (xios_getvar("timesteps_between_samples",itmp)) nbase_xios_freq=itmp
!
tdtime%SECOND = int(ptstep*nbase_xios_freq)
 CALL xios_set_timestep(tdtime)
!
!$OMP END SINGLE
!
!
! ---------------------------------------------------------------------------------
!
!   Declare a 'full' domain and one domain per tile 
!
! ---------------------------------------------------------------------------------
!
 CALL sfx_xios_set_domain(ysc%UG%G%CGRID, "FULL"  , kdim1, kdim2, kext1, kxindex, odxmask, &
     ysc%UG%G%XLON, ysc%UG%G%XLAT, pclon, pclat )
 CALL sfx_xios_set_domain(ysc%UG%G%CGRID, "SEA"   , kdim1, kdim2, kext1, kxindex, odxmask, &
     ysc%UG%G%XLON, ysc%UG%G%XLAT, pclon, pclat, kmask=kmasksea )
 CALL sfx_xios_set_domain(ysc%UG%G%CGRID, "NATURE", kdim1, kdim2, kext1, kxindex, odxmask, &
     ysc%UG%G%XLON, ysc%UG%G%XLAT, pclon, pclat, kmask=kmasknat)
 CALL sfx_xios_set_domain(ysc%UG%G%CGRID, "WATER" , kdim1, kdim2, kext1, kxindex, odxmask, &
     ysc%UG%G%XLON, ysc%UG%G%XLAT , pclon, pclat, kmask=kmaskwat )
 CALL sfx_xios_set_domain(ysc%UG%G%CGRID, "TOWN"  , kdim1, kdim2, kext1, kxindex, odxmask, &
     ysc%UG%G%XLON, ysc%UG%G%XLAT , pclon, pclat, kmask=kmasktown )
!
! Declare axes, depending on activated schemes
!
!IF (YSC%U%NDIM_NATURE>0) THEN
   CALL set_axis(ypatch_dim_name , ksize=SIZE(ysc%IM%NPE%AL))
   CALL set_axis(yground_layer_dim_name , ksize=SIZE(ysc%IM%NPE%AL(1)%XTG,2))
   CALL set_axis(ywground_layer_dim_name, ksize=SIZE(ysc%IM%NPE%AL(1)%XWG,2))
   CALL set_axis(ywiground_layer_dim_name, ksize=SIZE(ysc%IM%NPE%AL(1)%XWG,2))
   CALL set_axis(yswband_dim_name, ksize=SIZE(ysc%IM%ID%D%XSWBD,2))
   ! CALL SET_AXIS(YSNOW_PATCH_DIM_NAME, KSIZE=)
!ENDIF
!IF (YSC%U%NDIM_SEA>0) THEN
   ! CALL SET_AXIS(YSEAICE_LAYER_DIM_NAME, KSIZE=)
!ENDIF
!
!  Force XIOS inheritance inorder that fields declarations can 
!  fully account for user settings
!
!   CALL XIOS_SOLVE_INHERITANCE()
#endif
!
IF (lhook) CALL dr_hook('SFX_XIOS_SETUP',1,zhook_handle)
!
END SUBROUTINE sfx_xios_setup