sfx_oasis_recv_ol.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE sfx_oasis_recv_ol (F, IM, S, U, W, &
                              HPROGRAM,KI,KSW,PTIMEC,PTSTEP_SURF,   &
                              PZENITH,PSW_BANDS,          &
                              PTSRAD,PDIR_ALB,PSCA_ALB,PEMIS,PTSURF )
!#############################################
!
!!****  *SFX_OASIS_RECV_OL* - Offline driver that receive coupling fields from oasis
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modn_sfx_oasis,  ONLY : xtstep_cpl_land, &
                            xtstep_cpl_sea,  &
                            lwater
!
USE modd_sfx_oasis,  ONLY : lcpl_land,         &
                            lcpl_gw,lcpl_flood,&
                            lcpl_sea,          &
                            lcpl_seaice
!
USE modd_off_surfex_n, ONLY : goto_model
!
USE modd_flake_n, ONLY : flake_t
USE modd_surfex_n, ONLY : isba_model_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_surf_par,   ONLY : xundef
!
USE modi_get_luout
USE modi_sfx_oasis_recv
USE modi_put_sfx_land
USE modi_put_sfx_sea
USE modi_update_esm_surf_atm_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
#ifdef AIX64
!$ USE OMP_LIB
#endif
!
IMPLICIT NONE
!
#ifndef AIX64
!$ INCLUDE 'omp_lib.h'
#endif
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(flake_t), INTENT(INOUT) :: F
TYPE(isba_model_t), INTENT(INOUT) :: IM
TYPE(seaflux_t), INTENT(INOUT) :: S
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(watflux_t), INTENT(INOUT) :: W
!
 CHARACTER(LEN=6),       INTENT(IN)  :: HPROGRAM    ! program calling surf. schemes
!
INTEGER,                INTENT(IN)  :: KI          ! number of points on this proc
INTEGER,                INTENT(IN)  :: KSW         ! number of short-wave spectral bands
REAL,                   INTENT(IN)  :: PTIMEC      ! Cumulated run time step (s)
REAL,                   INTENT(IN)  :: PTSTEP_SURF ! Surfex time step
!
REAL, DIMENSION(KI),    INTENT(IN)  :: PZENITH   ! zenithal angle       (radian from the vertical)
REAL, DIMENSION(KSW),   INTENT(IN)  :: PSW_BANDS ! mean wavelength of each shortwave band (m)
!
REAL, DIMENSION(KI),    INTENT(OUT) :: PTSRAD    ! radiative temperature                 (K)
REAL, DIMENSION(KI,KSW),INTENT(OUT) :: PDIR_ALB  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(KI,KSW),INTENT(OUT) :: PSCA_ALB  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(KI),    INTENT(OUT) :: PEMIS     ! emissivity                            (-)
REAL, DIMENSION(KI),    INTENT(OUT) :: PTSURF    ! surface effective temperature         (K)
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI) :: ZLAND_WTD     ! Land water table depth (m)
REAL, DIMENSION(KI) :: ZLAND_FWTD    ! Land grid-cell fraction of water table rise (-)
REAL, DIMENSION(KI) :: ZLAND_FFLOOD  ! Land Floodplains fraction (-)
REAL, DIMENSION(KI) :: ZLAND_PIFLOOD ! Land Potential flood infiltration (kg/m2/s)
REAL, DIMENSION(KI) :: ZSEA_SST      ! Sea surface temperature (K)
REAL, DIMENSION(KI) :: ZSEA_UCU      ! Sea u-current stress (Pa)
REAL, DIMENSION(KI) :: ZSEA_VCU      ! Sea v-current stress (Pa)
REAL, DIMENSION(KI) :: ZSEAICE_SIT   ! Sea-ice Temperature (K)
REAL, DIMENSION(KI) :: ZSEAICE_CVR   ! Sea-ice cover (-)
REAL, DIMENSION(KI) :: ZSEAICE_ALB   ! Sea-ice albedo (-)
!
REAL                :: ZTIME_CPL
!
LOGICAL             :: GRECV_LAND
LOGICAL             :: GRECV_FLOOD
LOGICAL             :: GRECV_SEA
!
INTEGER             :: ILUOUT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_RECV_OL',0,zhook_handle)
!
!-------------------------------------------------------------------------------
!
!*       1.     init coupling fields:
!               ----------------------------------
!
ztime_cpl = ptimec-ptstep_surf
!
grecv_land=(lcpl_land.AND.mod(ztime_cpl,xtstep_cpl_land)==0.0)
grecv_sea =(lcpl_sea .AND.mod(ztime_cpl,xtstep_cpl_sea )==0.0)
!
IF(.NOT.(grecv_land.OR.grecv_sea))THEN
  IF (lhook) CALL dr_hook('SFX_OASIS_RECV_OL',1,zhook_handle)
  RETURN
ENDIF
!
 CALL get_luout(hprogram,iluout)
!
IF(grecv_land)THEN
  zland_wtd(:) = xundef
  zland_fwtd(:) = xundef
  zland_fflood(:) = xundef
  zland_piflood(:) = xundef
ENDIF
!
IF(grecv_sea)THEN
  zsea_sst(:) = xundef
  zsea_ucu(:) = xundef
  zsea_vcu(:) = xundef
  zseaice_sit(:) = xundef
  zseaice_cvr(:) = xundef
  zseaice_alb(:) = xundef
ENDIF
!
!*       2.     Receive fields to other models proc by proc:
!               --------------------------------------------
!
 CALL sfx_oasis_recv(hprogram,ki,ksw,ztime_cpl,         &
                    grecv_land, grecv_sea,             &
                    zland_wtd(:),zland_fwtd(:), &
                    zland_fflood(:),zland_piflood(:), &
                    zsea_sst(:),zsea_ucu(:), &
                    zsea_vcu(:),zseaice_sit(:), &
                    zseaice_cvr(:),zseaice_alb(:)  )
!
!-------------------------------------------------------------------------------
! Put variable over land tile
!-------------------------------------------------------------------------------
!
IF(grecv_land)THEN
  CALL put_sfx_land(im%O, im%S, im%K, im%NK, im%NP, u, iluout,lcpl_gw,lcpl_flood, zland_wtd(:),&
                    zland_fwtd(:), zland_fflood(:),zland_piflood(:)  )        
ENDIF
!
!-------------------------------------------------------------------------------
! Put variable over sea and/or water tile
!-------------------------------------------------------------------------------
!
IF(grecv_sea)THEN
  CALL put_sfx_sea(s, u, w, iluout,lcpl_seaice,lwater, zsea_sst(:),zsea_ucu(:), &
                   zsea_vcu(:),zseaice_sit(:), zseaice_cvr(:),zseaice_alb(:)  )
ENDIF
!
!-------------------------------------------------------------------------------
! Update radiative properties at time t+1 for radiative scheme
!-------------------------------------------------------------------------------
!
grecv_flood=(grecv_land.AND.lcpl_flood)
!
IF(grecv_sea.OR.grecv_flood)THEN     
  CALL update_esm_surf_atm_n(f, im, s, u, w, hprogram, ki, ksw, pzenith, psw_bands, &
                             ptsrad, pdir_alb, psca_alb, pemis, ptsurf )                    
ENDIF
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_RECV_OL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE sfx_oasis_recv_ol