sfx_oasis_recv.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE sfx_oasis_recv(HPROGRAM,KI,KSW,PTIMEC,                &
                          ORECV_LAND, ORECV_SEA,                 &
                          PLAND_WTD,PLAND_FWTD,                  &
                          PLAND_FFLOOD, PLAND_PIFLOOD,           &
                          PSEA_SST,PSEA_UCU,PSEA_VCU,            &
                          PSEAICE_SIT,PSEAICE_CVR,PSEAICE_ALB    )
!########################################
!
!!****  *SFX_OASIS_RECV* - Receive coupling fields from oasis
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surf_par,   ONLY : xundef
!
USE modd_sfx_oasis
!
USE modi_get_luout
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
#ifdef CPLOASIS
USE mod_oasis
#endif
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
 CHARACTER(LEN=*),       INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
INTEGER,                INTENT(IN)  :: KI        ! number of points on this proc
INTEGER,                INTENT(IN)  :: KSW       ! number of short-wave spectral bands
REAL,                   INTENT(IN)  :: PTIMEC    ! Cumulated run time step (s)
!
LOGICAL,                INTENT(IN)  :: ORECV_LAND
LOGICAL,                INTENT(IN)  :: ORECV_SEA
!
REAL, DIMENSION(KI),    INTENT(OUT) :: PLAND_WTD     ! Land water table depth (m)
REAL, DIMENSION(KI),    INTENT(OUT) :: PLAND_FWTD    ! Land grid-cell fraction of water table rise (-)
REAL, DIMENSION(KI),    INTENT(OUT) :: PLAND_FFLOOD  ! Land Floodplains fraction (-)
REAL, DIMENSION(KI),    INTENT(OUT) :: PLAND_PIFLOOD ! Land Potential flood infiltration (kg/m2/s)
!
REAL, DIMENSION(KI),    INTENT(OUT) :: PSEA_SST ! Sea surface temperature (K)
REAL, DIMENSION(KI),    INTENT(OUT) :: PSEA_UCU ! Sea u-current stress (Pa)
REAL, DIMENSION(KI),    INTENT(OUT) :: PSEA_VCU ! Sea v-current stress (Pa)
!
REAL, DIMENSION(KI),    INTENT(OUT) :: PSEAICE_SIT ! Sea-ice Temperature (K)
REAL, DIMENSION(KI),    INTENT(OUT) :: PSEAICE_CVR ! Sea-ice cover (-)
REAL, DIMENSION(KI),    INTENT(OUT) :: PSEAICE_ALB ! Sea-ice albedo (-)
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI,1) :: ZREAD
!
INTEGER               :: IDATE  ! current coupling time step (s)
INTEGER               :: IERR   ! Error info
INTEGER               :: ILUOUT
 CHARACTER(LEN=50)     :: YCOMMENT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
#ifdef CPLOASIS
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_RECV',0,zhook_handle)
!
!*       1.     Initialize :
!               ------------
!
 CALL get_luout(hprogram,iluout)
!
idate = int(ptimec)
!
!-------------------------------------------------------------------------------
!
!*       2.     Get Land surface variable :
!               ------------------------------------
!
IF(orecv_land)THEN
!
! * Init river input fields
!
  zread(:,:) = xundef
!
  pland_wtd(:) = xundef
  pland_fwtd(:) = xundef
  pland_fflood(:) = xundef
  pland_piflood(:) = xundef
!
! * Receive river input fields
!
  IF(lcpl_gw)THEN
!
    ycomment='water table depth'
    CALL oasis_get(nwtd_id,idate,zread(:,:),ierr)
    CALL check_recv(iluout,ierr,ycomment)
    pland_wtd(:)=zread(:,1)
!
    ycomment='fraction of water table rise'
    CALL oasis_get(nfwtd_id,idate,zread(:,:),ierr)
    CALL check_recv(iluout,ierr,ycomment)
    pland_fwtd(:)=zread(:,1)
!
  ENDIF
!
  IF(lcpl_flood)THEN
!
    ycomment='Flood fraction'
    CALL oasis_get(nfflood_id,idate,zread(:,:),ierr)
    CALL check_recv(iluout,ierr,ycomment)
    pland_fflood(:)=zread(:,1)
!
    ycomment='Potential flood infiltration'
    CALL oasis_get(npiflood_id,idate,zread(:,:),ierr)
    CALL check_recv(iluout,ierr,ycomment)
    pland_piflood(:)=zread(:,1)
!
    WHERE(pland_piflood(:)==0.0)pland_fflood(:)=0.0
!
  ENDIF
!
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       3.     Get Sea variables :
!               -----------------------------
!
!
IF(orecv_sea)THEN
!
! * Init ocean input fields
!
  zread(:,:) = xundef
!
  psea_sst(:) = xundef
  psea_ucu(:) = xundef
  psea_vcu(:) = xundef
!
  pseaice_sit(:) = xundef
  pseaice_cvr(:) = xundef
  pseaice_alb(:) = xundef
!
! * Receive ocean input fields
!
  ycomment='Sea surface temperature'
  CALL oasis_get(nsea_sst_id,idate,zread(:,:),ierr)
  CALL check_recv(iluout,ierr,ycomment)
  psea_sst(:)=zread(:,1)
!
  ycomment='Sea u-current stress'
  CALL oasis_get(nsea_ucu_id,idate,zread(:,:),ierr)
  CALL check_recv(iluout,ierr,ycomment)
  psea_ucu(:)=zread(:,1)
!
  ycomment='Sea v-current stress'
  CALL oasis_get(nsea_vcu_id,idate,zread(:,:),ierr)
  CALL check_recv(iluout,ierr,ycomment)
  psea_vcu(:)=zread(:,1)
!
  IF(lcpl_seaice)THEN
!
    ycomment='Sea-ice Temperature'
    CALL oasis_get(nseaice_sit_id,idate,zread(:,:),ierr)
    CALL check_recv(iluout,ierr,ycomment)
    pseaice_sit(:)=zread(:,1)
!
    ycomment='Sea-ice cover'
    CALL oasis_get(nseaice_cvr_id,idate,zread(:,:),ierr)
    CALL check_recv(iluout,ierr,ycomment)
    pseaice_cvr(:)=zread(:,1)
!
    ycomment='Sea-ice albedo'
    CALL oasis_get(nseaice_alb_id,idate,zread(:,:),ierr)
    CALL check_recv(iluout,ierr,ycomment)
    pseaice_alb(:)=zread(:,1)
!
  ENDIF
!
ENDIF
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_RECV',1,zhook_handle)
!
!-------------------------------------------------------------------------------
CONTAINS
!-------------------------------------------------------------------------------
!
SUBROUTINE check_recv(KLUOUT,KERR,HCOMMENT)
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
INTEGER,          INTENT(IN)  :: KLUOUT
INTEGER,          INTENT(IN)  :: KERR
 CHARACTER(LEN=*), INTENT(IN)  :: HCOMMENT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('SFX_OASIS_RECV:CHECK_RECV',0,zhook_handle)
!
IF (kerr/=oasis_ok.AND.kerr<oasis_recvd) THEN
   WRITE(kluout,'(A,I4)')'Return OASIS code receiving '//trim(hcomment)//' : ',kerr
   CALL abor1_sfx('SFX_OASIS_RECV: problem receiving '//trim(hcomment)//' from OASIS')
ENDIF
!
IF (lhook) CALL dr_hook('SFX_OASIS_RECV:CHECK_RECV',1,zhook_handle)
!
END SUBROUTINE check_recv
!
!-------------------------------------------------------------------------------
#endif
!-------------------------------------------------------------------------------
!
END SUBROUTINE sfx_oasis_recv