read_sso_canopyn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################################
      SUBROUTINE read_sso_canopy_n (DTCO, SB, U, HPROGRAM,HINIT)
!     #########################################
!
!!****  *READ_SSO_CANOPY_n* - reads SSO fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    05/2010 
!!      B. Decharme 07/2011  initialize sso_canopy in prep
!!      E. Martin   01/2012  Avoid writing of XUNDEF canopy fields
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_canopy_n, ONLY : canopy_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par,        ONLY : xundef
!
USE modi_read_surf
USE modi_set_sso_levels
USE modi_canopy_grid
USE modi_get_type_dim_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(canopy_t), INTENT(INOUT) :: SB
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! calling program
 CHARACTER(LEN=3),  INTENT(IN)  :: HINIT    ! choice of fields to initialize
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
 CHARACTER(LEN=12) :: YRECFM       ! Name of the article to be read
 CHARACTER(LEN=3)  :: YREAD
INTEGER :: ILU     ! 1D physical dimension
INTEGER :: IRESP   ! Error code after redding
INTEGER :: JLAYER  ! loop counter on layers
INTEGER :: IVERSION, IBUGFIX   ! surface version
LOGICAL :: GCANOPY    ! flag to test if SSO canopy fields are in the file
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_SSO_CANOPY_N',0,zhook_handle)
 CALL get_type_dim_n(dtco, u, 'FULL  ',ilu)
!
!* flag to use or not canopy levels
!
yrecfm='VERSION'
 CALL read_surf(hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(hprogram,yrecfm,ibugfix,iresp)
!
IF (iversion<6.OR.hinit=='PGD'.OR. hinit=='PRE') THEN
  gcanopy = .false.
ELSE
  IF (iversion>7 .OR. iversion==7 .AND.ibugfix>=2) THEN
    yrecfm='STORAGETYPE'
    CALL read_surf(hprogram,yrecfm,yread,iresp)
  ELSE
    yread = 'ALL'
  ENDIF
  IF (yread/='ALL') THEN
    gcanopy = .false.
  ELSE
    yrecfm='SSO_CANOPY'
    CALL read_surf(hprogram,yrecfm,gcanopy,iresp)
  ENDIF
END IF
!
!*       2.     Allocation of Prognostic fields:
!               --------------------------------
!
!* number of vertical levels
!
IF (.NOT. gcanopy) THEN
  CALL set_sso_levels(sb, ilu)
ELSE
  !
  yrecfm='SSO_CAN_LVL'
  CALL read_surf(hprogram,yrecfm,sb%NLVL,iresp)
  !
  !
  !*       3.     Reading of Prognostic fields:
  !               -----------------------------
  !
  ALLOCATE(sb%XZ(ilu,sb%NLVL))  
  ALLOCATE(sb%XU(ilu,sb%NLVL))
  ALLOCATE(sb%XTKE(ilu,sb%NLVL))
  !
  !* altitudes
  DO jlayer=1,sb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'SSO_CAN_Z',jlayer,' '
    CALL read_surf(hprogram,yrecfm,sb%XZ(:,jlayer),iresp)
  END DO
  !    
  !* wind in canopy
  DO jlayer=1,sb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'SSO_CAN_U',jlayer,' '
    CALL read_surf(hprogram,yrecfm,sb%XU(:,jlayer),iresp)
  END DO
  !
  !* Tke in canopy
  DO jlayer=1,sb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'SSO_CAN_E',jlayer,' '
    CALL read_surf(hprogram,yrecfm,sb%XTKE(:,jlayer),iresp)
  END DO
  !
ENDIF
!
!
!* Grid characteristics
!
!
!  --------------------------------- XZ(k+1)                     XDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - XZf(k+1)                               | XDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- XZ(k), XU, XT, XQ, XTKE   | XDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - XZf(k)                    V            | XDZf(k)
!  --------------------------------- XZ(k-1)                     XDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - XZf(k-1)
!
ALLOCATE(sb%XDZ (ilu,sb%NLVL))
ALLOCATE(sb%XZF (ilu,sb%NLVL))
ALLOCATE(sb%XDZF(ilu,sb%NLVL))
 CALL canopy_grid(ilu,sb)
!
IF (lhook) CALL dr_hook('READ_SSO_CANOPY_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_sso_canopy_n