canopy_grid.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################################
      SUBROUTINE canopy_grid(KI,SB)
!     #########################################
!
!!****  *CANOPY_GRID* - computation of vertical grid coordinatesa at 
!!                      half levels and grid depths at half and full
!!                      levels
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!
!
!  --------------------------------- PZ(k+1)                     PDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - PZf(k+1)                               | PDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- PZ(k), XU, XT, XQ, XTKE   | PDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - PZf(k)                    V            | PDZf(k)
!  --------------------------------- PZ(k-1)                     PDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - PZf(k-1)
!

!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_canopy_n, ONLY : canopy_t
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
INTEGER,                  INTENT(IN)    :: KI     ! number of horizontal points
!
TYPE(canopy_t), INTENT(INOUT) :: SB
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: JLAYER                 ! loop counter on layers
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('CANOPY_GRID',0,zhook_handle)
!
!*    1. Geometric computations
!        ----------------------
!
!
!*    1.1 layer depths (variable located at half levels below full levels)
!         ------------
!
sb%XDZF(:,:) = -999.
sb%XDZF(:,1) = 2.*sb%XZ(:,1)
DO jlayer=2,sb%NLVL
  sb%XDZF(:,jlayer) = sb%XZ(:,jlayer) - sb%XZ(:,jlayer-1)
END DO
!
!*    1.2 Layer heights (variable located at half levels below full levels)
!         -------------
!
sb%XZF(:,:) = -999.
sb%XZF(:,1) = 0.
DO jlayer=2,sb%NLVL
  sb%XZF(:,jlayer) = 2.*sb%XZ(:,jlayer-1) - sb%XZF(:,jlayer-1)
END DO
!
!
!*    1.3 layer depths (variable located at full levels)
!         ------------
!
sb%XDZ(:,:) = -999.
DO jlayer=1,sb%NLVL-1
  sb%XDZ(:,jlayer) = sb%XZF(:,jlayer+1) - sb%XZF(:,jlayer)
END DO
!
sb%XDZ(:,sb%NLVL) = 2.*(sb%XZ(:,sb%NLVL)-sb%XZF(:,sb%NLVL))
!
IF (lhook) CALL dr_hook('CANOPY_GRID',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE canopy_grid