read_sbln.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_sbl_n (DTCO, U, SB, OSBL, HPROGRAM, HSURF)
!     #########################################
!
!!****  *READ_SBL_n* - reads TEB fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      E. Martin   01/2012 Add LSBL_COLD_START
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_canopy_n, ONLY : canopy_t
!
USE modd_surf_par,       ONLY : xundef
!
USE modi_read_surf
USE modi_canopy_grid
USE modi_get_type_dim_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(canopy_t), INTENT(INOUT) :: SB
LOGICAL, INTENT(INOUT) :: OSBL
!
 CHARACTER(LEN=6), INTENT(IN) :: HPROGRAM ! calling program
 CHARACTER(LEN=6), INTENT(IN) :: HSURF
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!
 CHARACTER(LEN=8) :: YBASE
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
 CHARACTER(LEN=13) :: YFORMAT
 CHARACTER(LEN=3)  :: YREAD
INTEGER :: JLAYER  ! loop counter on layers
INTEGER :: ILU     ! 1D physical dimension
INTEGER :: IRESP   ! Error code after redding
INTEGER           :: IVERSION, IBUGFIX   ! surface version
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_SBL_N',0,zhook_handle)
!
 CALL get_type_dim_n(dtco, u, hsurf, ilu)
!
!* flag to use or not canopy levels
!
yrecfm='VERSION'
 CALL read_surf(hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(hprogram,yrecfm,ibugfix,iresp)
!
IF (iversion<3) THEN
  osbl = .false.
ELSE
  IF (hsurf=="TOWN  ") THEN
    yrecfm='TEB_CANOPY'
  ELSEIF (hsurf=="WATER ") THEN
    yrecfm='WAT_SBL'
  ELSEIF (hsurf=="NATURE") THEN
    yrecfm='ISBA_CANOPY'
  ELSEIF (hsurf=="SEA   ") THEN
    yrecfm='SEA_SBL'
  ENDIF
  CALL read_surf(hprogram,yrecfm,osbl,iresp)
END IF
!
IF (.NOT.osbl) THEN
  ALLOCATE(sb%XZ  (0,0))
  ALLOCATE(sb%XU  (0,0))
  ALLOCATE(sb%XT  (0,0))
  ALLOCATE(sb%XQ  (0,0))
  ALLOCATE(sb%XTKE(0,0))
  ALLOCATE(sb%XLMO(0,0))
  ALLOCATE(sb%XP  (0,0))
  IF (hsurf=="TOWN  ") THEN
    ALLOCATE(sb%XLM (0,0))
    ALLOCATE(sb%XLEPS(0,0))  
  ENDIF
  ALLOCATE(sb%XDZ (0,0))
  ALLOCATE(sb%XZF (0,0))
  ALLOCATE(sb%XDZF(0,0))
  IF (lhook) CALL dr_hook('READ_SBL_N',1,zhook_handle)
  RETURN
ENDIF
!
!* number of vertical levels
!
IF (hsurf=="TOWN  ") THEN
  ybase = "TEB_CAN "
ELSEIF (hsurf=="WATER ") THEN
  ybase = "WAT_SBL "
ELSEIF (hsurf=="NATURE") THEN
  ybase = "ISBA_CAN"
ELSEIF (hsurf=="SEA   ") THEN
  ybase = "SEA_SBL "
ENDIF
!
IF (hsurf=="NATURE") THEN
  yformat='(A10,I2.2)'
ELSE
  yformat='(A9,I2.2) '
ENDIF
!
yrecfm=trim(ybase)//'_LVL'
 CALL read_surf(hprogram,yrecfm,sb%NLVL,iresp)
!
!*       2.     Prognostic fields:
!               -----------------
!
!* altitudes
!
ALLOCATE(sb%XZ(ilu,sb%NLVL))
!
DO jlayer=1,sb%NLVL
  WRITE(yrecfm,yformat) trim(ybase)//'_Z',jlayer
  CALL read_surf(hprogram,yrecfm,sb%XZ(:,jlayer),iresp)
END DO
!
ALLOCATE(sb%XU  (ilu,sb%NLVL))
ALLOCATE(sb%XT  (ilu,sb%NLVL))
ALLOCATE(sb%XQ  (ilu,sb%NLVL))
ALLOCATE(sb%XTKE(ilu,sb%NLVL))
ALLOCATE(sb%XLMO(ilu,sb%NLVL))
ALLOCATE(sb%XP  (ilu,sb%NLVL))
!
IF (iversion>7 .OR. iversion==7 .AND.ibugfix>=2) THEN
  yrecfm='STORAGETYPE'
  CALL read_surf(hprogram,yrecfm,yread,iresp)
ELSE
  yread = 'ALL'
ENDIF
!
IF(yread=='ALL') THEN
  !
  !* wind in SBL
  DO jlayer=1,sb%NLVL
    WRITE(yrecfm,yformat) trim(ybase)//'_U',jlayer
    CALL read_surf(hprogram,yrecfm,sb%XU(:,jlayer),iresp)
  END DO
  !
  !* theta in SBL
  DO jlayer=1,sb%NLVL
    WRITE(yrecfm,yformat) trim(ybase)//'_T',jlayer
    CALL read_surf(hprogram,yrecfm,sb%XT(:,jlayer),iresp)
  END DO
  !
  !* humidity in SBL
  DO jlayer=1,sb%NLVL
    WRITE(yrecfm,yformat) trim(ybase)//'_Q',jlayer
    CALL read_surf( hprogram,yrecfm,sb%XQ(:,jlayer),iresp)
  END DO
  !
  !* Tke in SBL
  DO jlayer=1,sb%NLVL
    WRITE(yrecfm,yformat) trim(ybase)//'_E',jlayer
    CALL read_surf(hprogram,yrecfm,sb%XTKE(:,jlayer),iresp)
  END DO
  !
  !* Monin-Obhukov length
  IF (iversion<7 .OR. hsurf/="TOWN  ") THEN
    yrecfm=trim(ybase)//'_LMO ' 
    CALL read_surf(hprogram,yrecfm,sb%XLMO(:,1),iresp) 
    DO jlayer = 2,sb%NLVL
      sb%XLMO(:,jlayer) = sb%XLMO(:,1)
    ENDDO    
  ELSE
    DO jlayer=1,sb%NLVL
      WRITE(yrecfm,'(A10,I2.2)') trim(ybase)//'_MO',jlayer
      CALL read_surf(hprogram,yrecfm,sb%XLMO(:,jlayer),iresp)
    ENDDO
  ENDIF    
  !
  !* Pressure
  DO jlayer=1,sb%NLVL
    WRITE(yrecfm,yformat) trim(ybase)//'_P',jlayer
    CALL read_surf(hprogram,yrecfm,sb%XP(:,jlayer),iresp)
  END DO
  !
ELSE
  sb%XU  (:,:) = xundef
  sb%XT  (:,:) = xundef
  sb%XQ  (:,:) = xundef
  sb%XTKE(:,:) = xundef
  sb%XLMO(:,:) = xundef
  sb%XP  (:,:) = xundef
ENDIF
!
IF (hsurf=="TOWN  ") THEN
  !
  !* mixing length
  !
  ALLOCATE(sb%XLM(ilu,sb%NLVL))
  !
  !* dissipative length
  !
  ALLOCATE(sb%XLEPS(ilu,sb%NLVL))
  !
ENDIF
!
!
!* Grid characteristics
!
!
!  --------------------------------- XZ(k+1)                     XDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - XZf(k+1)                               | XDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- XZ(k), XU, XT, XQ, XTKE   | XDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - XZf(k)                    V            | XDZf(k)
!  --------------------------------- XZ(k-1)                     XDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - XZf(k-1)
!
ALLOCATE(sb%XDZ (ilu,sb%NLVL))
ALLOCATE(sb%XZF (ilu,sb%NLVL))
ALLOCATE(sb%XDZF(ilu,sb%NLVL))
!
 CALL canopy_grid(ilu,sb)
!
IF (lhook) CALL dr_hook('READ_SBL_N',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_sbl_n