read_forcing_date.F90

Go to the documentation of this file.

!     ######
SUBROUTINE read_forcing_date(KLISTING,HFILE,KNB_TSTEP_RUN, &
                             KYEAR,KMONTH,KDAY,PTIME       )
!#############################################################
!
USE modd_trip_par, ONLY : lncprint
!
USE mode_trip_netcdf
USE mode_trip_date_netcdf
!
USE modi_abort_trip
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
INTEGER,          INTENT(IN)       :: KLISTING
 CHARACTER(LEN=*), INTENT(IN)       :: HFILE
INTEGER,          INTENT(IN)       :: KNB_TSTEP_RUN
!
INTEGER,          INTENT(OUT)      :: KYEAR
INTEGER,          INTENT(OUT)      :: KMONTH
INTEGER,          INTENT(OUT)      :: KDAY
REAL,             INTENT(OUT)      :: PTIME
!
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=NF90_MAX_NAME) :: YFNAME
 CHARACTER(LEN=NF90_MAX_NAME) :: YVAR
 CHARACTER(LEN=NF90_MAX_NAME) :: YUNITS
!
REAL, DIMENSION(KNB_TSTEP_RUN) :: ZTIME
!
INTEGER :: IFILE_ID
INTEGER :: IVAR_ID
INTEGER :: IRET
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('READ_FORCING_DATE',0,zhook_handle)
!
yfname = hfile(1:len_trim(hfile))   
yvar   = 'time'
!
iret=nf90_open(yfname,nf90_nowrite,ifile_id)
IF(iret/=nf90_noerr)THEN
  WRITE(klisting,*)'READ_FORCING_DATE : error in NF90_OPEN'
  CALL abort_trip('READ_FORCING_DATE : error in NF90_OPEN')
ENDIF
!
iret=nf90_inq_varid(ifile_id,yvar,ivar_id)
IF(iret/=nf90_noerr)THEN
  WRITE(klisting,*)'READ_FORCING_DATE : error in NF90_INQ_VARID'
  CALL abort_trip('READ_FORCING_DATE : error in NF90_INQ_VARID')
ENDIF
!
iret=nf90_get_att(ifile_id,ivar_id,'units',yunits)
IF(iret/=nf90_noerr)THEN
  WRITE(klisting,*)'READ_FORCING_DATE : error in NF90_GET_ATT'
  CALL abort_trip('READ_FORCING_DATE : error in NF90_GET_ATT')
ENDIF
!
 CALL ncread(klisting,ifile_id,yvar,ztime,lncprint)
!
iret=nf90_close(ifile_id)
IF(iret/=nf90_noerr)THEN
  WRITE(klisting,*)'READ_FORCING_DATE : error in NF90_CLOSE'
  CALL abort_trip('READ_FORCING_DATE : error in NF90_CLOSE')
ENDIF
!
 CALL read_date(ztime,yunits,kyear,kmonth,kday,ptime)
!
IF (lhook) CALL dr_hook('READ_FORCING_DATE',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE read_forcing_date