prep_watflux.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_watflux (DTCO, UG, U, GCP, WG, W, SB,  &
                         HPROGRAM,HATMFILE,HATMFILETYPE,HPGDFILE,HPGDFILETYPE,YDCTL)
!     #################################################################################
!
!!****  *PREP_WATFLUX* - prepares WATFLUX fields
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette   06/2009 PREP_WATFLUX_SBL has no more argument
!!      P. Marguinaud10/2014, Support for a 2-part PREP
!!------------------------------------------------------------------
!
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_watflux_n, ONLY : watflux_t
USE modd_canopy_n, ONLY : canopy_t
!
USE modd_data_cover_n, ONLY : data_cover_t
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modi_prep_hor_watflux_field
USE modi_prep_ver_watflux
USE modi_prep_output_grid
USE modi_get_luout
USE modi_prep_sbl
!
USE modd_read_namelist,  ONLY : lnam_read
USE modn_prep_watflux
USE modd_prep,           ONLY : xzs_ls
USE modd_surf_atm,       ONLY : lvertshift
!
USE mode_prep_ctl, ONLY : prep_ctl
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_clean_prep_output_grid
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
 TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
TYPE(grid_t), INTENT(INOUT) :: WG
TYPE(watflux_t), INTENT(INOUT) :: W
TYPE(canopy_t), INTENT(INOUT) :: SB
type(prep_ctl),    INTENT(INOUT) :: ydctl
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: HATMFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HATMFILETYPE! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: HPGDFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HPGDFILETYPE! type of the Atmospheric file
!
!*      0.2    declarations of local variables
!
INTEGER :: JMTH, INMTH
!
INTEGER :: ILUOUT
LOGICAL :: GFOUND         ! Return code when searching namelist
INTEGER :: ILUNAM         ! logical unit of namelist file
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
!*      1.     Default of configuration
!
!
IF (lhook) CALL dr_hook('PREP_WATFLUX',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL prep_output_grid(ug%G, wg, u%NSIZE_FULL, iluout)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations
!
!
!*      2.0    Large scale orography
!
 CALL prep_hor_watflux_field(dtco, u, gcp, SIZE(wg%XLAT), w, &
                             hprogram,'ZS     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,ydctl)
!
!*      2.1    Temperature
!
 CALL prep_hor_watflux_field(dtco, u, gcp, SIZE(wg%XLAT), w, &
                             hprogram,'TSWATER',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,ydctl)
!
 CALL clean_prep_output_grid
!
IF (ydctl%LPART6) THEN

!*      2.2    Roughness
!
  ALLOCATE(w%XZ0(SIZE(w%XTS)))
  w%XZ0 = 0.001
!
!-------------------------------------------------------------------------------------
!
!*      3.     Vertical interpolations of all variables
!
  IF(lvertshift)THEN
    CALL prep_ver_watflux(w)
  ENDIF
!
  DEALLOCATE(xzs_ls)
!-------------------------------------------------------------------------------------
!
!*      4.     Preparation of optional interpolation of monthly ts water
!
  w%LINTERPOL_TS=.false.
  IF(w%CINTERPOL_TS/='NONE  ')THEN
    w%LINTERPOL_TS=.true.
  ENDIF
!
  IF(w%LINTERPOL_TS)THEN
!
! Precedent, Current, Next, and Second-next Monthly TS water
    inmth=4
!
    ALLOCATE(w%XTS_MTH(SIZE(w%XTS),inmth))
    DO jmth=1,inmth
      w%XTS_MTH(:,jmth)=w%XTS(:)
    ENDDO
!
  ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      5.     Preparation of SBL air variables
!
  w%LSBL = lwat_sbl
  IF (w%LSBL) CALL prep_sbl(wg%NDIM, sb)
!
ENDIF
!
IF (lhook) CALL dr_hook('PREP_WATFLUX',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_watflux