prep_hor_watflux_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_hor_watflux_field (DTCO, U, GCP, KLAT, W, &
                                   HPROGRAM,HSURF,HATMFILE,HATMFILETYPE,HPGDFILE,HPGDFILETYPE,YDCTL)
!     #################################################################################
!
!!****  *PREP_HOR_WATFLUX_FIELD* - Reads, interpolates and prepares a water field
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      P. Le Moigne 10/2005, Phasage Arome
!!      P. Marguinaud10/2014, Support for a 2-part PREP
!!------------------------------------------------------------------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_type_date_surf, ONLY : date_time
USE modd_surfex_mpi, ONLY : nrank, npio, ncomm, nproc
!
USE modd_prep,          ONLY : cingrid_type, cinterp_type, xzs_ls, cmask
!
USE modd_grid_grib, ONLY : cinmodel
!
USE mode_prep_ctl, ONLY : prep_ctl, prep_ctl_int_part2, prep_ctl_int_part4
!
USE modi_prep_grib_grid
USE modi_read_prep_watflux_conf
USE modi_prep_watflux_grib
USE modi_prep_watflux_unif
USE modi_prep_watflux_buffer
USE modi_hor_interpol
USE modi_get_luout
USE modi_prep_watflux_extern
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1    declarations of arguments
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
INTEGER, INTENT(IN) :: KLAT
TYPE(watflux_t), INTENT(INOUT) :: W
type(prep_ctl),    INTENT (INOUT) :: ydctl
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: HSURF     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: HATMFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HATMFILETYPE! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: HPGDFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HPGDFILETYPE! type of the Atmospheric file
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=6)              :: YFILETYPE ! type of input file
 CHARACTER(LEN=28)             :: YFILE     ! name of file
 CHARACTER(LEN=6)              :: YFILEPGDTYPE ! type of input file
 CHARACTER(LEN=28)             :: YFILEPGD     ! name of file
 type(date_time)                :: tztime_grib    ! current date and time
REAL, POINTER, DIMENSION(:,:) :: ZFIELDIN  ! field to interpolate horizontally
REAL, POINTER, DIMENSION(:,:) :: ZFIELDOUT ! field interpolated   horizontally
INTEGER                       :: ILUOUT    ! output listing logical unit
!
LOGICAL                       :: GUNIF     ! flag for prescribed uniform field
INTEGER :: INFOMPI, INL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
!
!*      1.     Reading of input file name and type
!
IF (lhook) CALL dr_hook('PREP_HOR_WATFLUX_FIELD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL read_prep_watflux_conf(hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,&
                            hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,iluout,gunif)
!
cmask = 'WATER'
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading of input  configuration (Grid and interpolation type)
!
NULLIFY (zfieldin, zfieldout)
!
IF (ydctl%LPART1) THEN
  IF (gunif) THEN
    CALL prep_watflux_unif(iluout,hsurf,zfieldin)
  ELSE IF (yfiletype=='GRIB  ') THEN
    CALL prep_grib_grid(yfile,iluout,cinmodel,cingrid_type,cinterp_type,tztime_grib)
    IF (nrank==npio) CALL prep_watflux_grib(hprogram,hsurf,yfile,iluout,zfieldin)         
  ELSE IF (yfiletype=='MESONH' .OR. yfiletype=='ASCII ' .OR. yfiletype=='LFI   '&
          .OR. yfiletype=='FA    '.OR. yfiletype=='AROME '.OR.yfiletype=='NC    ') THEN
     CALL prep_watflux_extern(gcp,hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,iluout,zfieldin)
  ELSE IF (yfiletype=='BUFFER') THEN
     CALL prep_watflux_buffer(hprogram,hsurf,iluout,zfieldin)
  ELSE
    CALL abor1_sfx('PREP_HOR_WATFLUX_FIELD: data file type not supported : '//yfiletype)
  END IF
ENDIF
!
!
!*      4.     Horizontal interpolation
!
 CALL prep_ctl_int_part2 (ydctl, hsurf, 'WATER', cmask, zfieldin)
!
IF (ydctl%LPART3) THEN
!
  IF (nrank==npio) THEN
    inl = SIZE(zfieldin,2)
  ELSEIF (.NOT.ASSOCIATED(zfieldin)) THEN
   ALLOCATE(zfieldin(0,0))
  ENDIF
  !
  IF (nproc>1) THEN
#ifdef SFX_MPI
    CALL mpi_bcast(inl,kind(inl)/4,mpi_integer,npio,ncomm,infompi)
#endif
  ENDIF
  ALLOCATE(zfieldout(klat,inl))
  !
  CALL hor_interpol(dtco, u, gcp, iluout,zfieldin,zfieldout)
  !
ENDIF
!
 CALL prep_ctl_int_part4 (ydctl, hsurf, 'WATER', cmask, zfieldin, zfieldout)
!
IF (ydctl%LPART5) THEN
!
!*      5.     Return to historical variable
!
  SELECT CASE (hsurf)
    CASE('ZS     ') 
      ALLOCATE(xzs_ls(SIZE(zfieldout,1)))
      xzs_ls(:) = zfieldout(:,1)
    CASE('TSWATER')
      ALLOCATE(w%XTS(SIZE(zfieldout,1)))
      w%XTS(:) = zfieldout(:,1)
  END SELECT
!
ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      6.     Deallocations
!
IF (ASSOCIATED (zfieldin)) DEALLOCATE(zfieldin )
IF (ASSOCIATED (zfieldout)) DEALLOCATE(zfieldout)
IF (lhook) CALL dr_hook('PREP_HOR_WATFLUX_FIELD',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_hor_watflux_field