prep_teb_garden.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_teb_garden (DTCO, UG, U, USS, GCP, TG, TOP, IO, S, K, P, PEK, &
                            HPROGRAM,HATMFILE,HATMFILETYPE,HPGDFILE,HPGDFILETYPE,KPATCH,YDCTL)
!     #################################################################################
!
!!****  *PREP_TEB_GARDEN* - Prepares ISBA fields
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      Modified by P. Le Moigne (11/2004): AGS fields
!!      Modified by B. Decharme   (2008)  : Floodplains
!!      Modified by B. Decharme  (01/2009): Consistency with Arpege deep soil
!!                                          temperature
!!      Modified by B. Decharme  (03/2009): Consistency with Arpege permanent
!!                                          snow/ice treatment
!!      P. Marguinaud10/2014, Support for a 2-part PREP
!!------------------------------------------------------------------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_sfx_grid_n, ONLY : grid_t
!
USE modd_teb_option_n, ONLY : teb_options_t
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_s_t, isba_k_t, isba_p_t, isba_pe_t
!
USE modi_prep_hor_teb_garden_field
USE modi_prep_ver_teb_veg
!
USE modd_surf_atm,       ONLY : lvertshift
!
                                ! A FAIRE :
                                ! IL FAUT RAJOUTER TSNOW
                                ! ----------------------
USE modd_csts,        ONLY : xtt
USE modd_snow_par,    ONLY : xz0sn
USE modd_isba_par,    ONLY : xwgmin
USE modd_co2v_par,    ONLY : xanfminit, xca_nit, xcc_nit
USE modd_surf_par,    ONLY : xundef
!
USE mode_prep_ctl, ONLY : prep_ctl
!
USE modn_prep_isba
USE mode_pos_surf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
TYPE(grid_t), INTENT(INOUT) :: TG
TYPE(teb_options_t), INTENT(INOUT) :: TOP
!
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_s_t), INTENT(INOUT) :: S
TYPE(isba_k_t), INTENT(INOUT) :: K
TYPE(isba_p_t), INTENT(INOUT) :: P
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
!
type(prep_ctl),    INTENT(INOUT) :: ydctl
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: HATMFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HATMFILETYPE! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: HPGDFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HPGDFILETYPE! type of the Atmospheric file
!
INTEGER,            INTENT(IN)  :: KPATCH
!
!*      0.2    declarations of local variables
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
!*      1.     Default of configuration
!
!*      1.1    Default
!
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations
!
!
!*      2.1    Soil Water reservoirs
!
IF (lhook) CALL dr_hook('PREP_TEB_GARDEN',0,zhook_handle)
 CALL prep_hor_teb_garden_field(dtco, ug, u, uss, gcp, io, s, k, p, pek, tg, top, &
                                hprogram,'WG     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch,ydctl)
!
!*      2.2    Soil ice reservoirs
!
 CALL prep_hor_teb_garden_field(dtco, ug, u, uss, gcp, io, s, k, p, pek, tg, top, &         
                                hprogram,'WGI    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch,ydctl)
!
!*      2.3    Leaves interception water reservoir
!
 CALL prep_hor_teb_garden_field(dtco, ug, u, uss, gcp, io, s, k, p, pek, tg, top, &
                                hprogram,'WR     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch,ydctl)
!
!*      2.4    Temperature profile
!
 CALL prep_hor_teb_garden_field(dtco, ug, u, uss, gcp, io, s, k, p, pek, tg, top, &
                                hprogram,'TG     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch,ydctl)
!
!*      2.5    Snow variables
!
 CALL prep_hor_teb_garden_field(dtco, ug, u, uss, gcp, io, s, k, p, pek, tg, top, &
                                hprogram,'SN_VEG ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch,ydctl)

!
!*      2.6    LAI
!
IF (io%CPHOTO/='NON')  &
 CALL prep_hor_teb_garden_field(dtco, ug, u, uss, gcp, io, s, k, p, pek, tg, top, &
                                hprogram,'LAI    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch,ydctl)
!
!-------------------------------------------------------------------------------------
!
!*      3.    Physical limitation: 
!
! If whole ice reservoir is empty (grib from ecmwf case) and surface temperature is
! lower than -10C, then ice content is maximum and water content minimum
!
IF (all(pek%XWGI(:,:)==0.)) THEN
   WHERE(pek%XTG(:,1:SIZE(pek%XWG,2)) < xtt-10.)
       pek%XWGI(:,:) = k%XWSAT(:,:)-xwgmin
       pek%XWG (:,:) = xwgmin
   END WHERE
ENDIF
!
! No ice for force restore third layer:
IF (io%CISBA == '3-L') THEN
      WHERE(pek%XWG(:,3)/=xundef.AND.pek%XWGI(:,3)/=xundef)
        pek%XWG(:,3)  = min(pek%XWG(:,3)+pek%XWGI(:,3),k%XWSAT(:,3))
        pek%XWGI(:,3) = 0.
      END WHERE
ENDIF
!
! Total water content should not exceed saturation:
WHERE(pek%XWG(:,:) /= xundef .AND. (pek%XWG(:,:) + pek%XWGI(:,:)) > k%XWSAT(:,:) )
     pek%XWGI(:,:) = k%XWSAT(:,:) - pek%XWG(:,:)
END WHERE
!
!-------------------------------------------------------------------------------------
!
!*      3.     Vertical interpolations of all variables
!
IF(lvertshift)THEN
  CALL prep_ver_teb_veg(p, pek, io, top%XZS)
ENDIF
!
!
!-------------------------------------------------------------------------------------
!
!*      5.     Half prognostic fields
!
ALLOCATE(pek%XRESA(SIZE(pek%XLAI)))
pek%XRESA = 100.
!
!-------------------------------------------------------------------------------------
!
!*      6.     Isba-Ags prognostic fields
!
IF (io%CPHOTO /= 'NON') THEN
!
   ALLOCATE(pek%XAN(SIZE(pek%XLAI)))
   pek%XAN = 0.
!
   ALLOCATE(pek%XANDAY(SIZE(pek%XLAI)))
   pek%XANDAY = 0.
!
   ALLOCATE(pek%XANFM(SIZE(pek%XLAI)))
   pek%XANFM = xanfminit
!
   ALLOCATE(pek%XLE(SIZE(pek%XLAI)))
   pek%XLE = 0.
!
ENDIF
!
IF (io%CPHOTO == 'AST') THEN
!
   ALLOCATE(pek%XBIOMASS(SIZE(pek%XLAI),io%NNBIOMASS))
   pek%XBIOMASS(:,1) = 0.
!
   ALLOCATE(pek%XRESP_BIOMASS(SIZE(pek%XLAI),io%NNBIOMASS))
   pek%XRESP_BIOMASS(:,:) = 0.
!
ELSEIF (io%CPHOTO == 'NIT' .OR. io%CPHOTO == 'NCB') THEN
!
   ALLOCATE(pek%XBIOMASS(SIZE(pek%XLAI),io%NNBIOMASS))
   pek%XBIOMASS(:,1) = pek%XLAI(:) * p%XBSLAI_NITRO(:)
   pek%XBIOMASS(:,2) = max( 0., (pek%XBIOMASS(:,1)/ (xcc_nit/10.**xca_nit))  &
                              **(1.0/(1.0-xca_nit)) - pek%XBIOMASS(:,1) )  
   pek%XBIOMASS(:,3:io%NNBIOMASS) = 0.
!
   ALLOCATE(pek%XRESP_BIOMASS(SIZE(pek%XLAI),io%NNBIOMASS))
   pek%XRESP_BIOMASS(:,:) = 0.
!
ENDIF
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PREP_TEB_GARDEN',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_teb_garden