prep_ver_teb_veg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_ver_teb_veg (P, PEK, IO, PZS)
!     #################################################################################
!
!!****  *PREP_VER_TEB_GARDEN* - change in ISBA fields due to altitude change
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      Modified by B. Decharme  (01/2009), Optional Arpege deep soil temperature initialization
!!------------------------------------------------------------------
!
USE modd_isba_n, ONLY : isba_pe_t, isba_p_t
USE modd_isba_options_n, ONLY : isba_options_t
!
USE modd_isba_par,       ONLY : xwgmin
USE modd_surf_par,       ONLY : xundef
USE modd_prep,           ONLY : xzs_ls, xt_clim_grad
USE modd_csts,           ONLY : xtt, xday, xlmtt, xrholw
!
USE mode_thermos
USE modi_prep_ver_snow
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!*      0.2    declarations of local variables
!
!
TYPE(isba_p_t), INTENT(INOUT) :: P
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
TYPE(isba_options_t), INTENT(INOUT) :: IO
REAL, DIMENSION(:), INTENT(IN) :: PZS
!
INTEGER                         :: JL        ! loop counter on layers
INTEGER                         :: IWORK     ! Work integer
!
REAL, DIMENSION(:), ALLOCATABLE :: ZWGTOT    ! total water content
REAL, DIMENSION(:), ALLOCATABLE :: ZDW       ! variation of water in soil
REAL, DIMENSION(:), ALLOCATABLE :: ZZSFREEZE ! altitude where soil temperature equals XTT
INTEGER                         :: IDEEP_SOIL! layer corresponding to deep soil temperature
!
REAL, DIMENSION(:,:), ALLOCATABLE :: ZWGI_CLIM_GRAD ! ice content vertical gradient
!
REAL, DIMENSION(:,:), ALLOCATABLE :: ZTG_LS! temperature on initial orography
!
REAL                            :: ZGRADX = 5.e-4 ! slope of ice content gradient
REAL                            :: ZH0    = 5.e-1 ! constant used to define ice content gradient
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
!*      1.0    Ice content climatologic gradient
!
IF (lhook) CALL dr_hook('PREP_VER_TEB_VEG',0,zhook_handle)
ALLOCATE(zwgi_clim_grad(SIZE(pek%XWG,1),SIZE(pek%XWG,2)))
!
zwgi_clim_grad(:,:) = zgradx * exp( - p%XDG(:,:) / zh0 )
!-------------------------------------------------------------------------------------
!
!*      1.1    Temperature profile
!
ALLOCATE(ztg_ls(SIZE(pek%XTG,1),SIZE(pek%XTG,2)))
ztg_ls(:,:) = pek%XTG(:,:)
!
DO jl=1,SIZE(pek%XTG,2)
  WHERE(pek%XTG(:,jl)/=xundef) &
    pek%XTG(:,jl) = pek%XTG(:,jl) + xt_clim_grad  * (pzs - xzs_ls)  
END DO
!
!-------------------------------------------------------------------------------------
!
!*      1.2    Water and ice in the soil
!
ALLOCATE(zzsfreeze(SIZE(pek%XWG,1)))
ALLOCATE(zwgtot(SIZE(pek%XWG,1)))
ALLOCATE(zdw(SIZE(pek%XWG,1)))
!
!* general case
!
iwork=SIZE(pek%XTG,2)
!
DO jl=1,iwork
  !
  zdw(:) = 0.
  ! altitude where deep soil freezes (diurnal surface response is not treated)
  zzsfreeze(:) = pzs + (xtt - pek%XTG(:,jl)) / xt_clim_grad
  !
  WHERE(pek%XTG(:,jl)/=xundef) 
    !
    WHERE (ztg_ls(:,jl) < xtt)
      !
      WHERE (pzs <= xzs_ls)
        !
        WHERE (pzs > zzsfreeze) 
          zdw(:) = zwgi_clim_grad(:,jl) * (pzs - xzs_ls)
        ELSEWHERE
          zdw(:) = zwgi_clim_grad(:,jl) * (zzsfreeze - xzs_ls) + zgradx * (pzs - zzsfreeze)
        ENDWHERE
        !
      ELSEWHERE
        !
        zdw(:) = zwgi_clim_grad(:,jl) * (pzs - xzs_ls)
        !
      ENDWHERE
      !
    ELSEWHERE
      !
      WHERE (pzs <= xzs_ls)
        !
        zdw(:) = zgradx * (pzs - xzs_ls)
        !
      ELSEWHERE
        !
        zdw(:) = zwgi_clim_grad(:,jl) * (pzs - zzsfreeze)
        !
      END WHERE
      !
    END WHERE
    !
    zwgtot(:) = xundef
    !
    WHERE(pek%XWG(:,jl)/=xundef)         
      zwgtot(:) = pek%XWG(:,jl) + pek%XWGI(:,jl)
    ENDWHERE        
    !
    WHERE(pek%XWG(:,jl)/=xundef)      
      pek%XWGI(:,jl) = pek%XWGI(:,jl) + zdw(:)
      pek%XWG (:,jl) = pek%XWG (:,jl) - zdw(:)
    ENDWHERE
    !
    WHERE (pek%XWGI(:,jl) < 0..AND.pek%XWGI(:,jl)/=xundef) 
      pek%XWGI(:,jl) = 0.
      pek%XWG (:,jl) = zwgtot(:)
    END WHERE
    !
    WHERE (pek%XWG(:,jl) < xwgmin.AND.pek%XWG(:,jl)/=xundef)
      pek%XWG (:,jl) = xwgmin
      pek%XWGI(:,jl) = zwgtot(:) - xwgmin
    END WHERE
    !
    WHERE(pek%XWGI(:,jl) > 0..AND.pek%XWGI(:,jl)/=xundef)
      pek%XTG(:,jl) = min(xtt,pek%XTG(:,jl))
    ELSEWHERE
      pek%XTG(:,jl) = max(xtt,pek%XTG(:,jl))
    ENDWHERE
    !
  ENDWHERE
  !
END DO
!
!* limits in force-restore case
!
IF (io%CISBA=='3-L') THEN 
  WHERE (pek%XWGI(:,3) /= xundef)
    pek%XWG (:,3) = pek%XWG(:,3)+pek%XWGI(:,3)
    pek%XWGI(:,3) = 0.
    pek%XTG (:,3) = ztg_ls(:,3)
  END WHERE
END IF
!
DEALLOCATE(zzsfreeze)
DEALLOCATE(zwgi_clim_grad)
DEALLOCATE(zwgtot   )
DEALLOCATE(zdw      )
!
!* masks where fields are not defined
WHERE (pek%XTG(:,1:SIZE(pek%XWG,2)) == xundef)
  pek%XWG (:,:) = xundef
  pek%XWGI(:,:) = xundef
END WHERE
!
!-------------------------------------------------------------------------------------
!
!*      1.4    Snow variables
!
!* vertical shift
IF (io%CISBA=='DIF') THEN
  ideep_soil = io%NGROUND_LAYER
ELSE
  ideep_soil = 2
END IF
 CALL prep_ver_snow(pek%TSNOW,xzs_ls,pzs,ztg_ls,pek%XTG,ideep_soil)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Deallocation of large-scale orography
!
DEALLOCATE(ztg_ls)
IF (lhook) CALL dr_hook('PREP_VER_TEB_VEG',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_ver_teb_veg