prep_sst_init.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE prep_sst_init (DTS, TPTIME, KSX, PSST)
!   ###############################################################
!!****  *SST_UPDATE*
!!
!!    PURPOSE
!!    -------
!
!     performs the time evolution of sst
!              
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      P. Le Moigne          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    09/2007
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_type_date_surf, ONLY : date_time
!
USE modd_data_seaflux_n, ONLY : data_seaflux_t
!
USE modd_type_date_surf
USE modi_temporal_dists
USE modi_temporal_lts
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(data_seaflux_t), INTENT(INOUT) :: DTS
!
TYPE(date_time), INTENT(IN) :: TPTIME
INTEGER, INTENT(INOUT) :: KSX
!
REAL,   DIMENSION(:), INTENT(INOUT) :: PSST    ! sst
!
!*      0.2    declarations of local variables
!
INTEGER                                  :: IDECADE  ! decade of simulation
INTEGER                                  :: JTIME    ! decade of simulation
INTEGER, SAVE                            :: JI
INTEGER                                  :: JXP
REAL, DIMENSION(SIZE(PSST))              :: ZSST
REAL, SAVE                               :: ZSDTJX
REAL                                     :: ZDT, ZALPHA
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-----------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('PREP_SST_INIT',0,zhook_handle)
loop: DO ji = dts%NTIME-1,1,-1
         ksx = ji
         IF (.NOT.temporal_lts(tptime,dts%TDATA_SST(ksx))) EXIT loop
      ENDDO loop

IF ( temporal_lts( tptime, dts%TDATA_SST(ksx) ) ) THEN
   zsst(:) = dts%XDATA_SST(:,ksx)     
ELSE IF ( .NOT. temporal_lts( tptime, dts%TDATA_SST(dts%NTIME) ) ) THEN
  zsst(:) = dts%XDATA_SST(:,dts%NTIME)
ELSE

   CALL temporal_dists ( dts%TDATA_SST(ksx+1)%TDATE%YEAR,dts%TDATA_SST(ksx+1)%TDATE%MONTH,   &
                         dts%TDATA_SST(ksx+1)%TDATE%DAY ,dts%TDATA_SST(ksx+1)%TIME,          &
                         dts%TDATA_SST(ksx)%TDATE%YEAR,dts%TDATA_SST(ksx)%TDATE%MONTH,       &
                         dts%TDATA_SST(ksx)%TDATE%DAY ,dts%TDATA_SST(ksx)%TIME,              &
                         zsdtjx                                                      )  

   CALL temporal_dists ( tptime%TDATE%YEAR   ,tptime%TDATE%MONTH,                      &
                         tptime%TDATE%DAY    ,tptime%TIME,                             &
                         dts%TDATA_SST(ksx)%TDATE%YEAR,dts%TDATA_SST(ksx)%TDATE%MONTH,       &
                         dts%TDATA_SST(ksx)%TDATE%DAY ,dts%TDATA_SST(ksx)%TIME,              &
                         zdt                                                         )  
!
    zalpha = zdt / zsdtjx
!
    zsst(:)= dts%XDATA_SST(:,ksx)+(dts%XDATA_SST(:,ksx+1)-dts%XDATA_SST(:,ksx))*zalpha
                       
END IF

psst(:) = zsst(:)
IF (lhook) CALL dr_hook('PREP_SST_INIT',1,zhook_handle)
!
!-----------------------------------------------------------------
!
END SUBROUTINE prep_sst_init