temporal_dists.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE temporal_dists(KYEARF, KMONTHF, KDAYF, PSECF,     &
                                 KYEARI, KMONTHI, KDAYI, PSECI,     &
                                 PDIST                              )  
!     #############################################################
!
!!****  *TEMPORAL_DISTS* - finds the number of secunds between 2 dates
!!
!!    PURPOSE
!!    -------
!!
!!                                WARNING
!!
!!      -----> Only correct for dates between 19900301 and 21000228   <-----
!!
!!  The correct test should be:
!! IF( ((MOD(KYEAR,4)==0).AND.(MOD(KYEAR,100)/=0)) .OR. (MOD(KYEAR,400)==0))THEN
!!
!!**  METHOD
!!    ------
!!
!!      A comparison term by term of the elements of the 2 dates is performed.
!!    and the temporal distance between the 2 dates is then deduced.
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    Book 2
!!
!!    AUTHOR
!!    ------
!!
!     J.Stein  Meteo-France
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    02/01/96
!!    PP. 06/08: Add case where differents years and same month 
!!    for more-than-1year simulations
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surf_par
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declaration of arguments
!              ------------------------
INTEGER, INTENT(IN) :: KYEARF  ! year of Final date
INTEGER, INTENT(IN) :: KMONTHF ! month of Final date
INTEGER, INTENT(IN) :: KDAYF   ! day of Final date
REAL,    INTENT(IN) :: PSECF   ! number of seconds since date at 00 UTC
                               ! of Final date
INTEGER, INTENT(IN) :: KYEARI  ! year of Initial date
INTEGER, INTENT(IN) :: KMONTHI ! month of Initial date
INTEGER, INTENT(IN) :: KDAYI   ! day of Initial date
REAL,    INTENT(IN) :: PSECI   ! number of seconds since date at 00 UTC
                               ! of Initial date
REAL,    INTENT(OUT):: PDIST   ! temporal distance in secunds between the final 
                               ! and initial date
!
!*       0.2   Declaration of local variables
!              ------------------------------
!
INTEGER :: IDAYS  ! number of days between the two dates
INTEGER :: JMONTH,JYEAR ! loop index on months or years 
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!*       1.    SAME YEARS AND SAME MONTHS
!              --------------------------
!
IF (lhook) CALL dr_hook('TEMPORAL_DISTS',0,zhook_handle)
IF ( (kyearf==kyeari) .AND. (kmonthf==kmonthi) ) THEN
  pdist = ( kdayf-kdayi) * 86400. + psecf - pseci
  ! check chronological order
  IF (pdist < 0.) pdist=xundef
END IF
!
!-------------------------------------------------------------------------------
!
!*       2.    SAME YEARS AND DIFFERENT MONTHS
!              -------------------------------
!
IF ( (kyearf==kyeari) .AND. (kmonthf/=kmonthi) ) THEN
  ! check chronological order
  IF ( kmonthf < kmonthi ) THEN
    pdist=xundef
    IF (lhook) CALL dr_hook('TEMPORAL_DISTS',1,zhook_handle)
    RETURN
  END IF
  !
  ! cumulate the number of days for the months in between KMONTHF-1 and 
  ! KMONTHI
  idays = 0
  DO jmonth = kmonthi, kmonthf-1
    SELECT CASE (jmonth)
      CASE(4,6,9,11)
        idays=idays+30
      CASE(1,3,5,7:8,10,12)
        idays=idays+31
      CASE(2)
        IF (mod(kyeari,4)==0) THEN 
          idays=idays+29
        ELSE
          idays=idays+28
        ENDIF
    END SELECT
  END DO  
  !
  ! compute the temporal distance
  pdist = ( idays + kdayf - kdayi) * 86400. + psecf - pseci
  !
END IF
!
!-------------------------------------------------------------------------------
!
!*       3.    DIFFERENT YEARS AND DIFFERENT MONTHS
!              ------------------------------------
!
IF ( (kyearf/=kyeari) .AND. (kmonthf/=kmonthi) ) THEN
  ! check chronological order
  IF ( kyearf < kyeari ) THEN
    pdist=xundef
    IF (lhook) CALL dr_hook('TEMPORAL_DISTS',1,zhook_handle)
    RETURN
  END IF
  !
  ! cumulate the number of days for the months in between KMONTHI and 
  ! December
  idays = 0
  DO jmonth = kmonthi, 12
    SELECT CASE (jmonth)
      CASE(4,6,9,11)
        idays=idays+30
      CASE(1,3,5,7:8,10,12)
        idays=idays+31
      CASE(2)
        IF (mod(kyeari,4)==0) THEN 
          idays=idays+29
        ELSE
          idays=idays+28
        ENDIF
    END SELECT
  END DO  
  DO jmonth = 1,kmonthf-1
    SELECT CASE (jmonth)
      CASE(4,6,9,11)
        idays=idays+30
      CASE(1,3,5,7:8,10,12)
        idays=idays+31
      CASE(2)
        IF (mod(kyearf,4)==0) THEN 
          idays=idays+29
        ELSE
          idays=idays+28
        ENDIF
    END SELECT
  END DO  
  ! add the number of days corresponding to full years between the two dates
  DO jyear=kyeari+1, kyearf-1
    IF (mod(jyear,4)==0) THEN 
      idays=idays+366
    ELSE
      idays=idays+365
    END IF
  END DO
  !
  ! compute the temporal distance
  pdist = ( idays + kdayf - kdayi) * 86400. + psecf - pseci
  !
END IF
!
!
!!            4. SUPPLEMENTARY CASE FOR DIFFERENT YEARS AND SAME MONTH 
!           ------------------------------------------------------------
IF ( (kyearf/=kyeari) .AND. (kmonthf==kmonthi) ) THEN
  ! check chronological order
  IF ( kyearf < kyeari ) THEN
    pdist=xundef
    IF (lhook) CALL dr_hook('TEMPORAL_DISTS',1,zhook_handle)
    RETURN
  END IF
  !
  ! cumulate the number of days for the months in between KMONTHI and 
  ! December => IDAYS = 0 here
  idays = 0
  ! add the number of days corresponding to full years between the two dates
  DO jyear=kyeari+1, kyearf-1
    IF (mod(jyear,4)==0) THEN 
      idays=idays+366
    ELSE
      idays=idays+365
    END IF
  END DO
  !
  ! compute the temporal distance
  pdist = ( idays + kdayf - kdayi) * 86400. + psecf - pseci
  !
END IF
IF (lhook) CALL dr_hook('TEMPORAL_DISTS',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE temporal_dists