prep_seaflux.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_seaflux (DTCO, UG, U, GCP, SG, SB, S, DTS, O, OR, &
                        HPROGRAM,HATMFILE,HATMFILETYPE,HPGDFILE,HPGDFILETYPE,YDCTL)
!     #################################################################################
!
!!****  *PREP_SEAFLUX* - prepares variables for SEAFLUX scheme
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette   06/2009 PREP_SEAFLUX_SBL has no more argument
!!      Modified    07/2012, P. Le Moigne : CMO1D phasing
!!      Modified    01/2014, S. Senesi : introduce sea-ice model 
!!      Modified    01/2015, R. Séférian : introduce ocean surface albedo 
!!      P. Marguinaud10/2014, Support for a 2-part PREP
!!------------------------------------------------------------------
!
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_canopy_n, ONLY : canopy_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_data_seaflux_n, ONLY : data_seaflux_t
USE modd_ocean_n, ONLY : ocean_t
USE modd_ocean_rel_n, ONLY : ocean_rel_t
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modi_prep_hor_seaflux_field
USE modi_prep_ver_seaflux
USE modi_prep_output_grid
USE modi_prep_sbl
USE modi_prep_seaice
USE modi_get_luout
!
USE modn_prep_seaflux
USE modd_read_namelist,  ONLY : lnam_read
USE modd_prep,           ONLY : xzs_ls
USE modd_surf_atm,       ONLY : lvertshift
!
USE mode_prep_ctl, ONLY : prep_ctl
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_clean_prep_output_grid
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
TYPE(grid_t), INTENT(INOUT) :: SG
TYPE(canopy_t), INTENT(INOUT) :: SB
TYPE(seaflux_t), INTENT(INOUT) :: S
TYPE(data_seaflux_t), INTENT(INOUT) :: DTS
TYPE(ocean_t), INTENT(INOUT) :: O
TYPE(ocean_rel_t), INTENT(INOUT) :: OR
type(prep_ctl),    INTENT(INOUT) :: ydctl
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: HATMFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HATMFILETYPE! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: HPGDFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HPGDFILETYPE! type of the Atmospheric file
!
!*      0.2    declarations of local variables
!
INTEGER :: JMTH,INMTH
INTEGER :: ILUOUT
LOGICAL :: GFOUND         ! Return code when searching namelist
INTEGER :: ILUNAM         ! logical unit of namelist file
REAL(KIND=JPRB) :: ZHOOK_HANDLE

!-------------------------------------------------------------------------------------
!
!*      0.     Default of configuration
!
!
IF (lhook) CALL dr_hook('PREP_SEAFLUX',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL prep_output_grid(ug%G, sg, u%NSIZE_FULL, iluout)
!
!-------------------------------------------------------------------------------------
!
!*      1.     Read namelist
!
s%LSBL = lsea_sbl
!
o%LMERCATOR = locean_mercator
o%LCURRENT  = locean_current
!
! Relaxation-forcing parameters
or%XTAU_REL   = xtime_rel
or%XQCORR     = xcorflx
!
or%LREL_CUR   = lcur_rel
or%LREL_TS    = lts_rel
or%LFLUX_NULL = lzero_flux
or%LFLX_CORR  = lcorr_flux
or%LDIAPYCNAL = ldiapyc
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations
!
!
!*      2.0    Large scale orography
!
 CALL prep_hor_seaflux_field(dtco, ug, u, gcp, dts, o, or, SIZE(sg%XLAT), s, &
                            hprogram,'ZS     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,ydctl)
!
!*      2.1.1    Temperature
!
 CALL prep_hor_seaflux_field(dtco, ug, u, gcp, dts, o, or, SIZE(sg%XLAT), s, &
                            hprogram,'SST    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,ydctl)
!
!*      2.1.2    Salinity
!

 CALL prep_hor_seaflux_field(dtco, ug, u, gcp, dts, o, or, SIZE(sg%XLAT), s, &
                            hprogram,'SSS    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,ydctl)
!
!*      2.1.3   Sea-ice
!
IF (cseaice_scheme /= 'NONE  ') THEN 
   CALL prep_seaice(ug, dtco, dts, o, or, SIZE(sg%XLAT), s, u, gcp, &
                    hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,ydctl)
ENDIF
!
 CALL clean_prep_output_grid

IF (ydctl%LPART6) THEN
!
!*      2.2    Roughness
!
  ALLOCATE(s%XZ0(SIZE(s%XSST)))
  s%XZ0 = 0.001
!
  ALLOCATE(s%XZ0H(SIZE(s%XSST)))
  s%XZ0H = s%XZ0
!
!*      2.3   Ocean Surface Albedo
!
  IF(s%CSEA_ALB=='RS14')THEN
    ALLOCATE(s%XDIR_ALB(SIZE(s%XSST)))
    ALLOCATE(s%XSCA_ALB(SIZE(s%XSST)))
    s%XDIR_ALB = 0.065
    s%XSCA_ALB = 0.065
  ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      3.     Vertical interpolations of all variables
!
  IF(lvertshift)THEN
    CALL prep_ver_seaflux(s)
  ENDIF
!
  DEALLOCATE(xzs_ls)
!
!-------------------------------------------------------------------------------------
!
!*      4.     Preparation of optional interpolation of monthly sst
!
  s%LINTERPOL_SST=.false.
  IF(trim(s%CINTERPOL_SST)/='NONE')THEN
!
    s%LINTERPOL_SST=.true.
!
! Precedent, Current, Next, and Second-next Monthly SST
    inmth=4
!
    ALLOCATE(s%XSST_MTH(SIZE(s%XSST),inmth))
    DO jmth=1,inmth
      s%XSST_MTH(:,jmth)=s%XSST(:)
    ENDDO
!
  ENDIF
!
!-------------------------------------------------------------------------------------
!
!
!*      5.     Optional preparation of interpolation of monthly Sea Surface salinity
!
  s%LINTERPOL_SSS=.false.
  IF(trim(s%CINTERPOL_SSS)/='NONE')THEN
!
     s%LINTERPOL_SSS=.true.
   !
   ! Precedent, Current, Next, and Second-next Monthly SSS
     inmth=4
   !
     ALLOCATE(s%XSSS_MTH(SIZE(s%XSSS),inmth))
     DO jmth=1,inmth
       s%XSSS_MTH(:,jmth)=s%XSSS(:)
     ENDDO
   !
  ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      6.     Preparation of SBL air variables
!
!
  IF (s%LSBL) CALL prep_sbl(sg%NDIM, sb)
!
ENDIF
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PREP_SEAFLUX',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_seaflux