prep_seaice.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_seaice (UG, DTCO, DTS, O, OR, KLAT, S, U, GCP, &
                        HPROGRAM,HATMFILE,HATMFILETYPE,HPGDFILE,HPGDFILETYPE,YDCTL)
!     #################################################################################
!
!!****  *PREP_SEAICE* - prepares variables for SEAICE scheme (for now : Gelato only)
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Sénési 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2014
!!------------------------------------------------------------------
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_seaflux_n, ONLY : data_seaflux_t
USE modd_ocean_n, ONLY : ocean_t
USE modd_ocean_rel_n, ONLY : ocean_rel_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_surf_par,   ONLY : xundef
USE modi_get_luout
USE modi_get_type_dim_n
USE modi_gltools_readnam
!
USE modd_types_glt,   ONLY : t_glt
!
USE mode_prep_ctl, ONLY : prep_ctl
!
USE modn_prep_seaflux,   ONLY : cprep_seaice_scheme => cseaice_scheme
USE modi_prep_hor_seaflux_field
!
USE modd_glt_param, ONLY : nl, nt, nx, ny, nxglo, nyglo 
USE modi_gltools_alloc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(data_seaflux_t), INTENT(INOUT) :: DTS
TYPE(ocean_t), INTENT(INOUT) :: O
TYPE(ocean_rel_t), INTENT(INOUT) :: OR
INTEGER, INTENT(IN) :: KLAT
TYPE(seaflux_t), INTENT(INOUT) :: S
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
type(prep_ctl),    INTENT(INOUT) :: ydctl
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: HATMFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HATMFILETYPE! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: HPGDFILE    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: HPGDFILETYPE! type of the Atmospheric file
!
!*      0.2    declarations of local variables
!
INTEGER :: IK,IL  ! loop counter on ice categories and layers 
INTEGER :: JMTH,INMTH
INTEGER :: ILUOUT
LOGICAL :: GFOUND         ! Return code when searching namelist
INTEGER :: ILUNAM         ! logical unit of namelist file
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PREP_SEAICE',0,zhook_handle)
!
!*      0.     Default of configuration
!
!
 CALL get_luout(hprogram,iluout)
!
!-------------------------------------------------------------------------------------
!
!*      1.     Interpret namelist
!
s%CSEAICE_SCHEME=cprep_seaice_scheme
IF ( s%CSEAICE_SCHEME == 'GELATO' ) THEN
  CALL gltools_readnam(.false.,iluout)
ENDIF
!
s%LHANDLE_SIC = .false.
IF(trim(s%CSEAICE_SCHEME)/='NONE' .OR. trim(s%CINTERPOL_SIC)/='NONE' )THEN
  s%LHANDLE_SIC=.true.
ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations of Seaice cover
!
IF (s%LHANDLE_SIC) THEN 
   CALL prep_hor_seaflux_field(dtco, ug, u, gcp, dts, o, or, klat, s, &
                               hprogram,'SIC    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,ydctl)
ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      3.     Optional preparation of interpolation of monthly sea ice cover and sea 
!              ice thickness 
!
s%LINTERPOL_SIC=.false.
IF(trim(s%CINTERPOL_SIC)/='NONE')THEN
   s%LINTERPOL_SIC=.true.
ENDIF
!
IF(trim(s%CINTERPOL_SIT)/='NONE')THEN
   s%LINTERPOL_SIT=.true.
ENDIF
!
IF(s%LINTERPOL_SIC)THEN
   !
   ! Precedent, Current, Next, and Second-next Monthly SIC
   inmth=4
   !
   ALLOCATE(s%XSIC_MTH(SIZE(s%XSIC),inmth))
   DO jmth=1,inmth
      s%XSIC_MTH(:,jmth)=s%XSIC(:)
   ENDDO
!
ENDIF
!
IF(s%LINTERPOL_SIT)THEN
   !
   !Precedent, Current, Next, and Second-next Monthly SIT
   inmth=4
   !
   ALLOCATE(s%XSIT_MTH(SIZE(s%XSIC),inmth))
   DO jmth=1,inmth
      s%XSIT_MTH(:,jmth)=xundef
   ENDDO
!
ENDIF
!-------------------------------------------------------------------------------------
!
!*      Creating default initial state for Gelato 
!
!
 CALL get_type_dim_n(dtco, u, 'SEA   ',nx)
ny=1
nyglo=1
nxglo=nx
 CALL gltools_alloc(s%TGLT)
!
!*       G1    Prognostic fields with only space dimension(s) :
!
s%TGLT%ust(:,1)=0.
!
!*       G2     Prognostic fields with space and ice-category dimension(s) :
!
! sea ice age 
s%TGLT%sit(:,:,1)%age=0.
! melt pond volume 
s%TGLT%sit(:,:,1)%vmp=0.
! sea ice surface albedo 
s%TGLT%sit(:,:,1)%asn=0.
! sea ice fraction 
s%TGLT%sit(:,:,1)%fsi=0.
! sea ice thickness 
s%TGLT%sit(:,:,1)%hsi=1.*s%TGLT%sit(:,:,1)%fsi
! sea ice salinity 
s%TGLT%sit(:,:,1)%ssi=0.
! sea ice surface temperature 
s%TGLT%sit(:,:,1)%tsf=260.
! snow thickness 
s%TGLT%sit(:,:,1)%hsn=0.
! snow density 
s%TGLT%sit(:,:,1)%rsn=100.
!
!*       G3     Prognostic fields with space, ice-category and layer dimensions :
!
! sea ice vertical gltools_enthalpy profile for all types and levels
s%TGLT%sil(:,:,:,1)%ent=-1000. 
!
IF (lhook) CALL dr_hook('PREP_SEAICE',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_seaice