pgd_chemistry.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_chemistry (CHE, DTCO, UG, U, USS, &
                                HPROGRAM,OCH_EMIS)
!     ##############################################################
!
!!**** *PGD_CHEMISTRY* monitor for averaging and interpolations of physiographic fields
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/12/97
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
!
USE modd_ch_emis_field_n, ONLY : ch_emis_field_t
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_pgd_grid,           ONLY : nl
USE modd_pgdwork,            ONLY : catype
USE modd_surf_par,           ONLY : xundef
USE modd_ch_surf,            ONLY : jpemismax_f
!
USE modi_get_luout
USE modi_pgd_field
USE modi_open_namelist
USE modi_close_namelist
USE modi_get_surf_size_n
USE modi_unpack_same_rank
!
USE mode_pos_surf
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
USE modi_get_surf_mask_n
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(ch_emis_field_t), INTENT(INOUT) :: CHE
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
!
 CHARACTER(LEN=6),    INTENT(IN)    :: HPROGRAM     ! Type of program
LOGICAL,             INTENT(OUT)   :: OCH_EMIS     ! emission flag
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                           :: ILUOUT    ! output listing logical unit
INTEGER                           :: ILUNAM    ! namelist file logical unit
LOGICAL                           :: GFOUND    ! flag when namelist is present
INTEGER                           :: JNBR      ! loop counter on dummy fields
INTEGER                           :: ILU, IL_SEA, IL_LAND, IL
!
!*    0.3    Declaration of namelists
!            ------------------------
!
INTEGER                                :: NEMIS_PGD_NBR
 CHARACTER(LEN=40), DIMENSION(JPEMISMAX_F):: CEMIS_PGD_NAME
 CHARACTER(LEN=40), DIMENSION(JPEMISMAX_F):: CEMIS_PGD_COMMENT
INTEGER,           DIMENSION(JPEMISMAX_F):: NEMIS_PGD_TIME
 CHARACTER(LEN=3),  DIMENSION(JPEMISMAX_F):: CEMIS_PGD_AREA
 CHARACTER(LEN=3),  DIMENSION(JPEMISMAX_F):: CEMIS_PGD_ATYPE
 CHARACTER(LEN=28), DIMENSION(JPEMISMAX_F):: CEMIS_PGD_FILE
 CHARACTER(LEN=6),  DIMENSION(JPEMISMAX_F):: CEMIS_PGD_FILETYPE
 CHARACTER(LEN=6)                       :: YMASK
REAL, DIMENSION(:), ALLOCATABLE :: ZEMIS_FIELD, ZEMIS_FIELDS
INTEGER, DIMENSION(:), ALLOCATABLE :: IMASK
REAL(KIND=JPRB) :: ZHOOK_HANDLE

!
NAMELIST/nam_ch_emis_pgd/ nemis_pgd_nbr,cemis_pgd_name,nemis_pgd_time,&
       cemis_pgd_comment,cemis_pgd_area,cemis_pgd_atype,cemis_pgd_file,&
       cemis_pgd_filetype  
!-------------------------------------------------------------------------------
!
!*    1.      Initializations of defaults
!             ---------------------------
!
!
IF (lhook) CALL dr_hook('PGD_CHEMISTRY',0,zhook_handle)
nemis_pgd_nbr = 0  
CEMIS_PGD_NAME(:)    = '                           '
nemis_pgd_time(:)    = 0
CEMIS_PGD_COMMENT(:) = ''
CEMIS_PGD_AREA(:)    = 'ALL'
CEMIS_PGD_FILETYPE(:)= 'DIRECT'
CEMIS_PGD_FILE(:)    = '                           '
CEMIS_PGD_ATYPE(:)   = 'ARI'
!
 CALL get_luout(hprogram,iluout)
!
!-------------------------------------------------------------------------------
!
!*    2.      Reading of namelist
!             -------------------
!
!
 CALL open_namelist(hprogram,ilunam)
!
 CALL posnam(ilunam,'NAM_CH_EMIS_PGD',gfound,iluout)
IF (gfound) READ(unit=ilunam,nml=nam_ch_emis_pgd)
!
 CALL close_namelist(hprogram,ilunam)
!
!-------------------------------------------------------------------------------
!
!*    3.      Allocation
!             ----------
!
CHE%NEMIS_NBR = NEMIS_PGD_NBR
!
 CALL get_surf_size_n(dtco, u, &
                      'LAND', il_land)
 CALL get_surf_size_n(dtco, u, &
                      'SEA   ',il_sea)
!
!
ALLOCATE(zemis_fields(nl))
!
ALLOCATE(che%XEMIS_FIELDS (nl,che%NEMIS_NBR))
ALLOCATE(che%CEMIS_AREA   (che%NEMIS_NBR))
ALLOCATE(che%CEMIS_COMMENT(che%NEMIS_NBR))
ALLOCATE(che%CEMIS_NAME   (che%NEMIS_NBR))
ALLOCATE(che%NEMIS_TIME   (che%NEMIS_NBR))
!
CHE%CEMIS_AREA   (:) = CEMIS_PGD_AREA   (1:CHE%NEMIS_NBR)
CHE%CEMIS_NAME   (:) = CEMIS_PGD_NAME   (1:CHE%NEMIS_NBR)
CHE%NEMIS_TIME   (:) = NEMIS_PGD_TIME   (1:CHE%NEMIS_NBR)
CHE%CEMIS_COMMENT(:) = CEMIS_PGD_COMMENT(1:CHE%NEMIS_NBR)
!
CHE%NTIME_MAX = MAXVAL(CHE%NEMIS_TIME)
!
!-------------------------------------------------------------------------------
och_emis = che%NEMIS_NBR > 0
!-------------------------------------------------------------------------------
!
!*    4.      Computations
!             ------------
!
DO jnbr=1,che%NEMIS_NBR
  catype = cemis_pgd_atype(jnbr)
  SELECT CASE (che%CEMIS_AREA(jnbr))
    CASE ('LAN')
      il = il_land
      ymask='LAND  '
    CASE ('SEA')
      il = il_sea
      ymask='SEA   '
    CASE ('ALL')
      il = nl
      ymask='FULL  '
    CASE DEFAULT
      CALL abor1_sfx('PGD_CHEMISTRY (1): EMISSION AREA NOT SUPPORTED')
  END SELECT
  ALLOCATE(zemis_field(il))
  ALLOCATE(imask(il))
  !*    4.1     Computes the field on the surface points where it is defined
  CALL pgd_field(dtco, ug, u, uss, &
                 hprogram,che%CEMIS_NAME(jnbr),che%CEMIS_AREA(jnbr),cemis_pgd_file(jnbr), &
                   cemis_pgd_filetype(jnbr),xundef,zemis_field(:)             )  
  catype = 'ARI'
  
!*    4.2     Expends field on all surface points
  ilu=0
  CALL get_surf_mask_n(dtco, u, &
                       ymask,il,imask,ilu,iluout)
  CALL unpack_same_rank(imask,zemis_field(:),zemis_fields(:))
  DEALLOCATE(zemis_field)
  DEALLOCATE(imask)

  
!*    4.3      Weights field on all surface points 
!              (zero weight where field is not defined)
  SELECT CASE (che%CEMIS_AREA(jnbr))
    CASE ('LAN')
      che%XEMIS_FIELDS(:,jnbr) = (u%XNATURE(:)+u%XTOWN(:))*zemis_fields(:) 
    CASE ('SEA')
      che%XEMIS_FIELDS(:,jnbr) = u%XSEA*zemis_fields(:)
    CASE ('ALL')
      che%XEMIS_FIELDS(:,jnbr) = zemis_fields(:)
    CASE DEFAULT
      CALL abor1_sfx('PGD_CHEMISTRY (2): EMISSION AREA NOT SUPPORTED')
  END SELECT
END DO
DEALLOCATE(zemis_fields)
IF (lhook) CALL dr_hook('PGD_CHEMISTRY',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
!*    5.      Expends 
!             ------------
!

!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_chemistry