pgd_bathyfield.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_bathyfield (UG, U, USS, &
                                 HPROGRAM,HFIELD,HAREA,HFILE,HFILETYPE,&
                                  HNCVARNAME,PUNIF,PFIELD)  
!     ##############################################################
!
!!**** *PGD_FIELD* monitor for averaging and interpolations of ISBA physiographic fields
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    C. Lebeaupin Brossier        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    01/2008
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surfex_mpi, ONLY : nrank, npio
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_surf_par,       ONLY : xundef
USE modd_pgd_grid,       ONLY : nl
USE modd_pgdwork,        ONLY : xall, nsize_all, nsize, xsumval
!
USE modi_get_luout
USE modi_treat_bathyfield
USE modi_interpol_field
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
!
 CHARACTER(LEN=6),  INTENT(IN) :: HPROGRAM  ! Type of program
 CHARACTER(LEN=*),  INTENT(IN) :: HFIELD    ! field name for prints
 CHARACTER(LEN=3),  INTENT(IN) :: HAREA     ! area where field is defined
!                                          ! 'ALL' : everywhere
!                                          ! 'NAT' : on nature
!                                          ! 'TWN' : on town
!                                          ! 'SEA' : on sea
!                                          ! 'WAT' : on inland waters
!                                          ! 'LAN' : on nature + on town
 CHARACTER(LEN=28), INTENT(IN) :: HFILE     ! data file name
 CHARACTER(LEN=6),  INTENT(IN) :: HFILETYPE ! data file type
 CHARACTER(LEN=28), INTENT(IN) :: HNCVARNAME! variable name to read
REAL,              INTENT(IN) :: PUNIF     ! prescribed uniform value for field
REAL, DIMENSION(:),INTENT(OUT):: PFIELD    ! physiographic field
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER :: ILUOUT    ! output listing logical unit
!
 CHARACTER(LEN=20) :: YFIELD
INTEGER :: JLOOP
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('PGD_BATHYFIELD',0,zhook_handle)
!-------------------------------------------------------------------------------
!
!*    2.      Output listing logical unit
!             ---------------------------
!
 CALL get_luout(hprogram,iluout)
!
!-------------------------------------------------------------------------------
!
!*    3.2     No data
!             -------
!
IF (len_trim(hfile)/=0) THEN
!        
!-------------------------------------------------------------------------------
!
!*    3.      Averages the field
!             ------------------
!
  ALLOCATE(nsize_all(u%NDIM_FULL,1))
  ALLOCATE(xall(u%NDIM_FULL,1,1))
!
  nsize_all(:,:) = 0
  xall(:,:,:) = 0.
!
  yfield = '                    '
  yfield = hfield(1:min(len(hfield),20))
!
  pfield(:) = xundef

  CALL treat_bathyfield(ug, u, uss, &
                        hprogram,'SURF  ',hfiletype,'A_MESH',hfile, hncvarname,&
                     yfield,pfield,harea                           )  
!
!-------------------------------------------------------------------------------
!
!*    4.      Mask for the interpolations
!             ---------------------------
!
  SELECT CASE (harea)
    CASE ('LAN')
      WHERE (u%XTOWN(:)+u%XNATURE(:)==0. .AND. nsize(:,1)==0 ) nsize(:,1) = -1
    CASE ('TWN')
      WHERE (u%XTOWN  (:)==0. .AND. nsize(:,1)==0 ) nsize(:,1) = -1
    CASE ('NAT')
      WHERE (u%XNATURE(:)==0. .AND. nsize(:,1)==0 ) nsize(:,1) = -1
    CASE ('SEA')
      WHERE (u%XSEA   (:)==0. .AND. nsize(:,1)==0 ) nsize(:,1) = -1
    CASE ('WAT')
      WHERE (u%XWATER (:)==0. .AND. nsize(:,1)==0 ) nsize(:,1) = -1

  END SELECT
!
!-------------------------------------------------------------------------------
!
!*    5.      Interpolation if some points are not initialized (no data for these points)
!             ------------------------------------------------
!
  CALL interpol_field(ug, u, &
                      hprogram,iluout,nsize(:,1),pfield(:),hfield)
!
  DO jloop=1,SIZE(pfield)
   pfield(jloop)=min(pfield(jloop),-1.)
  ENDDO
  DEALLOCATE(nsize    )
  DEALLOCATE(xsumval  )
!
!-------------------------------------------------------------------------------
!
!
!*    3.      Uniform field is prescribed
!             ---------------------------
!
!
ELSEIF (punif/=xundef) THEN
!
!*    3.1     Use of the presribed field
!             --------------------------
!
  pfield(:) = punif
!
ELSE
!
  WRITE(iluout,*) ' '
  WRITE(iluout,*) '***********************************************************'
  WRITE(iluout,*) '* Error in PGD field preparation of field : ', hfield
  WRITE(iluout,*) '* There is no prescribed value and no input file          *'
  WRITE(iluout,*) '***********************************************************'
  WRITE(iluout,*) ' '
  CALL abor1_sfx('PGD_BATHYFIELD: NO PRESCRIBED VALUE NOR INPUT FILE FOR '//hfield)
!
END IF
!-------------------------------------------------------------------------------
!
!*    6.      Mask for the field
!             ------------------
!
SELECT CASE (harea)
  CASE ('LAN')
    WHERE (u%XTOWN(:)+u%XNATURE(:)==0.) pfield(:) = xundef
  CASE ('TWN')
    WHERE (u%XTOWN  (:)==0.) pfield(:) = xundef
  CASE ('NAT')
    WHERE (u%XNATURE(:)==0.) pfield(:) = xundef
  CASE ('SEA')
    WHERE (u%XSEA   (:)==0.) pfield(:) = xundef
  CASE ('WAT')
    WHERE (u%XWATER (:)==0.) pfield(:) = xundef

END SELECT
IF (lhook) CALL dr_hook('PGD_BATHYFIELD',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_bathyfield