mpl_open_mod.F90

Go to the documentation of this file.

MODULE mpl_open_mod
!
!     Purpose.  open an MPIIO file 
!     --------
!
!
!     Interface.
!     ----------
!        call mpl_open(...)
!
!        Explicit arguments :
!        --------------------
!
!        input arguments:
!        ktype   - 1 = open for reading , 2 = writing
!        kname   - Name of the file
!        output arguments:
!        kfptr   - handle for file pointer
!        kerror  - error code
!
!        Implicit arguments :
!        --------------------
!
!     Method.
!     -------
!     MPL supports 4 styles of MPIIO
!
!     kop = 1    -  Blocking, non collective, shared file pointer
!                   using MPI_FILE_WRITE_SHARED,
!                         MPI_FILE_READ_SHARED
!     kop = 2    -  Blocking, collective, ordered, shared file pointer
!                   using MPI_FILE_WRITE_ORDERED,
!                         MPI_FILE_READ_ORDERED
!     kop = 3    -  Non Blocking, non collective, shared file pointer
!                   using MPI_FILE_IWRITE_SHARED,
!                         MPI_FILE_IREAD_SHARED
!                   and MPI_WAIT
!     kop = 4    -  Non Blocking, collective, ordered, shared file pointer
!                   using MPI_FILE_WRITE_ORDERED_BEGIN/END,
!                         MPI_FILE_READ_ORDERED_BEGIN/END
!    
!
!     Externals.
!     ----------
!
!     Reference.
!     ----------
!        none yet
!
!     Author.
!     -------
!        G.Mozdzynski
!
!     Modifications.
!     --------------
!        Original : 2000-12-08 (Based on MPE_OPEN)
!        R. EL Khatib 24-May-2011 Change ifdef MPI2 into ifndef MPI1
!     -----------------------------------------------------------------
!
USE parkind1  ,ONLY : jpim     ,jprb

USE mpl_mpif
USE mpl_data_module
USE mpl_message_mod
USE mpl_ioinit_mod

IMPLICIT NONE

PRIVATE
PUBLIC mpl_open

CONTAINS

SUBROUTINE mpl_open(KFPTR,KTYPE,KNAME,KERROR)


#ifdef USE_8_BYTE_WORDS
  USE mpi4to8, ONLY : &
    mpi_file_open => mpi_file_open8
#endif

INTEGER(KIND=JPIM),INTENT(IN) :: KTYPE
INTEGER(KIND=JPIM),INTENT(OUT) :: KFPTR,KERROR
CHARACTER*(*) KNAME
INTEGER(KIND=JPIM) :: MODE,INFO

#ifndef MPI1

!
!     -----------------------------------------------------------------
!
!     1.    Preamble
!           --------
!
IF( mpl_rank > mpl_numio ) THEN
  kerror = -1
  RETURN
ENDIF

IF( ktype == 1 ) THEN
   mode = mpi_mode_rdonly
ELSEIF( ktype == 2 ) THEN
   mode = mpi_mode_wronly + mpi_mode_create
ELSE
   kerror = -1
   RETURN
ENDIF

info = mpi_info_null
    
!     -----------------------------------------------------------------
!
!     2.    open the file
!           ----------------------

CALL mpi_file_open(mpl_comm_io,kname,mode,info,kfptr,kerror)
!
!
!     -----------------------------------------------------------------
#else

CALL abor1('MPL_OPEN not built with MPI2')

#endif

RETURN
END SUBROUTINE mpl_open

END MODULE mpl_open_mod