mpl_ioinit_mod.F90

Go to the documentation of this file.

MODULE mpl_ioinit_mod

!
!     Purpose.  initialise parallel IO environment
!     --------
!
!
!     Interface.
!     ----------
!        call mpl_ioinit(...)
!
!        Explicit arguments :
!        --------------------
!
!        input arguments:
!        kop     -  Style of parallel IO
!        kstrout - Number of output processors
!        output arguments:
!        kerror  - error code
!
!        Implicit arguments :
!        --------------------
!
!     Method.
!     -------
!     MPL supports 4 styles of MPIIO
!
!     kop = 1    -  Blocking, non collective, shared file pointer
!                   using MPI_FILE_WRITE_SHARED,
!                         MPI_FILE_READ_SHARED
!     kop = 2    -  Blocking, collective, ordered, shared file pointer
!                   using MPI_FILE_WRITE_ORDERED,
!                         MPI_FILE_READ_ORDERED
!     kop = 3    -  Non Blocking, non collective, shared file pointer
!                   using MPI_FILE_IWRITE_SHARED,
!                         MPI_FILE_IREAD_SHARED
!                   and MPI_WAIT
!     kop = 4    -  Non Blocking, collective, ordered, shared file pointer 
!                   using MPI_FILE_WRITE_ORDERED_BEGIN/END,
!                         MPI_FILE_READ_ORDERED_BEGIN/END
!
!     Externals.
!     ----------
!
!     Reference.
!     ----------
!        none yet
!
!     Author.
!     -------
!        G.Mozdzynski
!
!     Modifications.
!     --------------
!        Original : 2000-12-08 (Based on MPE_IOINIT)
!
!     -----------------------------------------------------------------
!

USE parkind1  ,ONLY : jpim     ,jprb

USE mpl_mpif
USE mpl_data_module
USE mpl_message_mod

IMPLICIT NONE


INTEGER(KIND=JPIM) :: mpl_numio
INTEGER(KIND=JPIM) :: mpl_iop
INTEGER(KIND=JPIM) :: mpl_comm_io

PRIVATE
PUBLIC :: mpl_ioinit, mpl_numio, mpl_iop, mpl_comm_io

CONTAINS

SUBROUTINE mpl_ioinit(KOP,KSTROUT,KERROR)


#ifdef USE_8_BYTE_WORDS
  USE mpi4to8, ONLY : &
    mpi_comm_split => mpi_comm_split8
#endif

INTEGER(KIND=JPIM),INTENT(IN) :: KOP,KSTROUT
INTEGER(KIND=JPIM),INTENT(OUT) :: KERROR
INTEGER(KIND=JPIM) :: COLOR,KEY

!
!     -----------------------------------------------------------------
!
!     1.    Preamble
!           --------

IF(kop < 1 .OR. kop > 4) THEN

  kerror = -1
  RETURN

ENDIF

!
!     -----------------------------------------------------------------
!
!     2. Check Style of Operation and take appropriate action
!     -------------------------------------------------------

mpl_numio = kstrout

mpl_iop = kop

IF(mpl_rank <= kstrout) THEN
  color = 1
ELSE
  color = mpi_undefined
ENDIF

key = 0

CALL mpi_comm_split(mpl_comm,color,key,mpl_comm_io,kerror)

!
!
!     -----------------------------------------------------------------
RETURN
END SUBROUTINE mpl_ioinit

END MODULE mpl_ioinit_mod