mod1dn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE mod1d_n (DGO, O, OR, PLAT, S, &
                        HPROGRAM, PTIME, PEMIS, PDIR_ALB, PSCA_ALB, &
                        PLW, PSCA_SW, PDIR_SW, PSFTH, PSFTQ, PSFU, PSFV, PRAIN )           
!     #######################################################################
!
!!****  *MOD1D_n*  
!!
!!    PURPOSE
!!    -------
!     Source that exchanges Fluxes and SST between SURFEX (coupling_seaflux) 
!     and the oceanic 1D model in TKE eqations (mixtl_n) 
!     
!!**  METHOD
!!    ------
!     Change turbulent fluxes in solar, non solar, and fresh water fluxes 
!     with the oceanic convention for orientation of fluxes
!     The stress of wind is exchange between SURFEX and TKE model
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!     C. Lebeaupin  *Météo-France* 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original     02/2008
!!      Modified     07/2012, P. Le Moigne : CMO1D phasing
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
!
!
USE modd_diag_ocean_n, ONLY : diag_ocean_t
USE modd_ocean_n, ONLY : ocean_t
USE modd_ocean_rel_n, ONLY : ocean_rel_t
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_csts
USE modd_ocean_csts
USE modd_surf_par,   ONLY : xundef
!
USE modi_mixtl_n
USE modi_diag_inline_ocean_n
!
USE modi_get_luout
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(diag_ocean_t), INTENT(INOUT) :: DGO
TYPE(ocean_t), INTENT(INOUT) :: O
TYPE(ocean_rel_t), INTENT(INOUT) :: OR
REAL, DIMENSION(:), INTENT(IN) :: PLAT
TYPE(seaflux_t), INTENT(INOUT) :: S
!
 CHARACTER(LEN=6),    INTENT(IN)       :: HPROGRAM  ! program calling surf. schemes
REAL                ,INTENT(IN)       :: PTIME   ! current time since midnight in second
REAL, DIMENSION(:)  ,INTENT(IN)       :: PEMIS    ! emissivity
REAL, DIMENSION(:,:),INTENT(IN)       :: PDIR_ALB ! direct albedo
REAL, DIMENSION(:,:),INTENT(IN)       :: PSCA_ALB ! scattered albedo
REAL, DIMENSION(:)  ,INTENT(IN)       :: PLW     ! longwave radiation on horizontal surface (W/m2)
REAL, DIMENSION(:,:),INTENT(IN)       :: PSCA_SW ! diffuse solar radiation on horizontal surface (W/m2)
REAL, DIMENSION(:,:),INTENT(IN)       :: PDIR_SW ! direct solar radiation on horizontal surface (W/m2)
REAL, DIMENSION(:)  ,INTENT(IN)       :: PSFTH   ! flux of heat (W/m2)
REAL, DIMENSION(:)  ,INTENT(IN)       :: PSFTQ   ! flux of water vapor (kg/m2/s)
REAL, DIMENSION(:)  ,INTENT(IN)       :: PSFU    ! zonal stress (Pa)
REAL, DIMENSION(:)  ,INTENT(IN)       :: PSFV    ! meridian stress (Pa)
REAL, DIMENSION(:)  ,INTENT(IN)       :: PRAIN   ! liquid precipitation (kg/s/m2)
!
!*      0.2    declarations of local variables
!
INTEGER :: JPT
INTEGER :: ITIME,NOCEAN_STEP
REAL, DIMENSION(SIZE(PSFTH)) :: ZFSOL,ZFNSOL !total solar and non-solar fluxes (W/m2)
REAL, DIMENSION(SIZE(PSFTH)) :: ZSFTEAU      !fresh water flux(kg/m2/s)
REAL, DIMENSION(SIZE(PSFTH)) :: ZLV          !latent heat
!
REAL, DIMENSION(SIZE(PSFTH)) :: ZLWU         !long waves upward fluxes (W/m2)
REAL, DIMENSION(SIZE(PDIR_ALB,1),SIZE(PDIR_ALB,2)) :: ZSWU
                                             !shortwave upward fluxes (W/m2)
!
REAL, DIMENSION(SIZE(PSFTH)) :: ZSEATEMP     !surface temperature (K)
!
LOGICAL         :: GCALLMIXT, GTIMEOK
INTEGER         :: ILUOUT              ! output listing logical unit
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MOD1D_N',0,zhook_handle)
!
 CALL get_luout(hprogram,iluout)
!
itime=int(ptime)
nocean_step=int(o%XOCEAN_TSTEP)
!
gtimeok=(mod(itime,nocean_step)==0)
gcallmixt=((mod(itime,nocean_step)==0).AND.(o%NOCTCOUNT>0))
!
!Call 1D model if ptime proportional to the oceanic model time step
!
IF (gcallmixt) THEN
!
!       1.     Initializations
!________________________________________________________________________
!Computation of solar, non solar and fresh water fluxes
  DO jpt=1,SIZE(psfth)
 !SW Flux up
    zswu(jpt,:)= pdir_sw(jpt,:) * pdir_alb(jpt,:) + psca_sw(jpt,:)*psca_alb(jpt,:)
 !Net solar flux  
    zfsol(jpt)=(sum(pdir_sw(jpt,:))+sum(psca_sw(jpt,:))-sum(zswu(jpt,:)))/(xrhosw*xcpsw)
 !Calcul flux LW UP
    zlwu(jpt)= pemis(jpt)*xstefan*s%XSST(jpt)**4 + (1-pemis(jpt))*plw(jpt)
   
    IF (s%XSST(jpt)<=(xtt-2)) THEN
      zfnsol(jpt)=(plw(jpt)-zlwu(jpt)-psfth(jpt)-(xlstt*psftq(jpt)))/(xrhosw*xcpsw)
      zsfteau(jpt)=psftq(jpt)/xrhoswref
    ELSE
      zlv(jpt)=xlvtt+(xcpv-xcl)*(s%XSST(jpt)-xtt)
      zfnsol(jpt)=(plw(jpt)-zlwu(jpt)-psfth(jpt)-(zlv(jpt)*psftq(jpt)))/(xrhosw*xcpsw)
      zsfteau(jpt)=(psftq(jpt)-prain(jpt))/xrhoswref
    ENDIF  
  ENDDO
!__________________________________________________________________________
!
!        2. Call oceanic TKE model
!           ----------------------
!
  IF (or%LFLUX_NULL) THEN
     WRITE(iluout,*) 'Caution : SURFACE FLUX ARE SET TO 0 '
     zfsol(:)   = 0.
     zfnsol(:)  = 0.
     zsfteau(:) = 0.
  END IF

  CALL mixtl_n(o, or, plat, zfsol,zfnsol,zsfteau,psfu,psfv,zseatemp)
!
!---------------------------------------------------------------------------
!        3. Coupling with SURFEX by SST (and relative wind) evolution
!
  IF (o%LPROGSST) THEN 
    s%XSST(:)=zseatemp(:)
    !WRITE(ILUOUT,*) '**SST CHANGED FOR THE ',NOCTCOUNT,'TIME BY FIRST LEVEL OCEANIC MODEL TEMPERATURE AT ', ITIME,' s **'
  ENDIF
  !
ENDIF
!
IF (gtimeok) THEN
  CALL diag_inline_ocean_n(dgo, o, s%XSEABATHY)
  o%NOCTCOUNT = o%NOCTCOUNT+1
ENDIF
!
IF (lhook) CALL dr_hook('MOD1D_N',1,zhook_handle)
!!-------------------------------------------------------------------------------
!!-----------------------------------------------------------------------------
END SUBROUTINE mod1d_n