diag_inline_oceann.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_inline_ocean_n (DGO, O, PSEABATHY) 
!     ###############################################################################
!
!!****  *DIAG_INLINE_SEAFLUX_n * - computes diagnostics during SEAFLUX time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    02/2008
!!      Modified    07/2012, P. Le Moigne : CMO1D phasing
!!------------------------------------------------------------------
!
!
USE modd_diag_ocean_n, ONLY : diag_ocean_t
USE modd_ocean_n, ONLY : ocean_t
!
USE modd_ocean_csts
!
USE modd_ocean_grid
!
USE modd_surf_par,   ONLY : xundef
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!*      0.2    declarations of local variables
!
!
TYPE(diag_ocean_t), INTENT(INOUT) :: DGO
TYPE(ocean_t), INTENT(INOUT) :: O
REAL, DIMENSION(:), INTENT(IN) :: PSEABATHY
!
REAL, DIMENSION(SIZE(O%XSEAT(:,1)),NOCKMIN:NOCKMAX) :: ZSEADENS
REAL, DIMENSION(SIZE(O%XSEAT(:,1))) :: ZRHO0,ZRHOCMO,ZDRHOX,ZTCMO
REAL, DIMENSION(SIZE(O%XSEAT(:,1))) :: ZTMOY,ZSMOY,ZUMOY,ZVMOY,ZDMOY
INTEGER, DIMENSION(SIZE(O%XSEAT(:,1))) :: IHMOLEVEL
INTEGER :: INBPTS, IK1, IK2
INTEGER :: J,JPT
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_OCEAN_N',0,zhook_handle)
IF (dgo%LDIAG_OCEAN) THEN
!
   ik1=nockmin+1
   ik2=nockmin+2
!
   inbpts=SIZE(o%XSEAT(:,1))
!
   zseadens(:,:)=xrhoswref + &
          (o%XSEAT(:,:)-13.5)*(-0.19494-0.49038e-2*(o%XSEAT(:,:)-13.5))&
          +0.77475*(o%XSEAS(:,:)-32.6)  
!
   DO jpt=1,inbpts
!
!       3.     Oceanic mixed layer depth calculation
!
!              -------------------------------------
     o%XSEAHMO(jpt)=-xzhoc(nockmin+2)
     ztcmo(jpt)=o%XSEAT(jpt,ik1)-0.5
     zrhocmo(jpt)=xrhoswref+drhocompute(ztcmo(jpt),o%XSEAS(jpt,ik1))
     DO j=ik2,nockmax-1
         zrho0(jpt)=xrhoswref+drhocompute(o%XSEAT(jpt,j),o%XSEAS(jpt,j))
         zdrhox(jpt)=zrho0(jpt)-zrhocmo(jpt)
         IF ((zdrhox(jpt)<0.).AND.(o%XSEABATH(jpt,j)/=0.))  THEN 
           o%XSEAHMO(jpt)=o%XSEAHMO(jpt)+xdz1(j)
         ELSE 
           EXIT
         ENDIF
     ENDDO
     o%XSEAHMO(jpt)=min(o%XSEAHMO(jpt),-pseabathy(jpt))
!
     ihmolevel(jpt)=nockmax
!
     DO j=ik1,nockmax
       IF (-xzhoc(j)>o%XSEAHMO(jpt)) THEN
         ihmolevel(jpt)=j-1
         EXIT
       ENDIF
     ENDDO
!
!       4.     Thermal and haline contents verification
!              ----------------------------------------
     IF (ihmolevel(jpt)<=1) THEN
       dgo%XTOCMOY(jpt)=o%XSEAT(jpt,ik1)
       dgo%XSOCMOY(jpt)=o%XSEAS(jpt,ik1)
       dgo%XUOCMOY(jpt)=o%XSEAU(jpt,ik1)
       dgo%XVOCMOY(jpt)=o%XSEAV(jpt,ik1)
       dgo%XDOCMOY(jpt)=zseadens(jpt,ik1)
     ELSE !IHMOLEVEL>=2
       ztmoy(jpt)=o%XSEAT(jpt,ik1)
       zsmoy(jpt)=o%XSEAS(jpt,ik1)
       zumoy(jpt)=o%XSEAU(jpt,ik1)
       zvmoy(jpt)=o%XSEAV(jpt,ik1)
       zdmoy(jpt)=zseadens(jpt,ik1)
       DO j=ik2,ihmolevel(jpt)
         ztmoy(jpt)=ztmoy(jpt)+o%XSEAT(jpt,j)*(-xzhoc(j)+xzhoc(j-1))
         zsmoy(jpt)=zsmoy(jpt)+o%XSEAS(jpt,j)*(-xzhoc(j)+xzhoc(j-1))
         zumoy(jpt)=zumoy(jpt)+o%XSEAU(jpt,j)*(-xzhoc(j)+xzhoc(j-1))
         zvmoy(jpt)=zvmoy(jpt)+o%XSEAV(jpt,j)*(-xzhoc(j)+xzhoc(j-1))
         zdmoy(jpt)=zdmoy(jpt)+zseadens(jpt,j)*(-xzhoc(j)+xzhoc(j-1))
       ENDDO
       dgo%XTOCMOY(jpt)=ztmoy(jpt)/(-xzhoc(ihmolevel(jpt)))
       dgo%XSOCMOY(jpt)=zsmoy(jpt)/(-xzhoc(ihmolevel(jpt)))
       dgo%XUOCMOY(jpt)=zumoy(jpt)/(-xzhoc(ihmolevel(jpt)))
       dgo%XVOCMOY(jpt)=zvmoy(jpt)/(-xzhoc(ihmolevel(jpt)))
       dgo%XDOCMOY(jpt)=zdmoy(jpt)/(-xzhoc(ihmolevel(jpt)))
     ENDIF
!
   ENDDO
!
ENDIF
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_OCEAN_N',1,zhook_handle)
CONTAINS
!
!
!!           #########################################
             FUNCTION drhocompute(T,S) RESULT(R)
!            ##########################################
!
!!****  *DRHOCOMPUTE* 
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!     
!!    REFERENCE
!!    ---------
!!    
!!     
!!    AUTHOR
!!    ------
!!     C. Lebeaupin  *Meteo-France* 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original     27/02/2005
!!
!-------------------------------------------------------------------------------
!*       0.     DECLARATIONS
!               ------------
!*       0.1 declaration of arguments and results
!
REAL ::  T,S ! oceanic temperature and salinity
REAL ::  R   ! density
!
!*       0.2 local variables
!
REAL :: DET,DES
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!*       1.     COMPUTE R
!               ---------
!
IF (lhook) CALL dr_hook('DRHOCOMPUTE',0,zhook_handle)
det = t-13.5
des = s-32.6
r = det*(-0.19494-0.49038e-2*det)+0.77475*des
IF (lhook) CALL dr_hook('DRHOCOMPUTE',1,zhook_handle)
!
END FUNCTION drhocompute
!
END SUBROUTINE diag_inline_ocean_n