lfisfm.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfisfm_fort                     &
&                     (lfi, krep, knumer )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Sous-Programme Suprimant un Facteur Multiplicatif
!     d'une Unite Logique FORTRAN, qui a ete fermee PRECEDEMMENT
!     par le Logiciel de Fichiers Indexes *LFI* .
!     (ou du moins, n'est pas ouverte pour ce logiciel)
!
!        Ce sous-programme permet de faire de la place dans les tables
!     decrivant les associations Unite Logique/facteur Multiplicatif.
!**
!    ARGUMENTS : KREP   (Sortie) ==> Code-REPonse du sous-programme;
!                KNUMER (Entree) ==> NUMERo de l'unite logique.
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KREP, KNUMER, IRANG, IREP 
INTEGER (KIND=JPLIKB) IRANFM, INIMES, IFACTM, J
!
LOGICAL LLVERG, LLEXUL
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel a LFINUM, permettant (le cas echeant) l'initialisation
!     variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFISFM_FORT',0,zhook_handle)
clacti=''
ifactm=0
llverg=.false.
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
!
IF (irang.NE.0) THEN
  irep=-5
  GOTO 1001
ENDIF
!
!        Controle de validite FORTRAN du Numero d'Unite Logique.
!
IF (knumer > 0) THEN
  INQUIRE (unit=knumer,exist=llexul,err=901,iostat=irep)
ELSE
  llexul=.true.
ENDIF
!
IF (.NOT.llexul) THEN
  irep=-30
  GOTO 1001
ENDIF
!
!              Verrouillage Global eventuel.
!
 IF (lfi%LMULTI) CALL lfiver_fort                       &
&                                (lfi, lfi%VERGLA,'ON')
llverg=lfi%LMULTI
!**
!     2.  -  TRAVAIL EFFECTIF SUR LES TABLES DECRIVANT LES ASSOCIATIONS
!            UNITES LOGIQUES/FACTEURS.
!-----------------------------------------------------------------------
!
CALL lfifmp_fort                     &
&               (lfi, knumer,iranfm)
!
IF (iranfm.EQ.0) THEN
!
!          Unite logique non trouvee dans la table *LFI%MULOFM*.
!
  irep=-31
  GOTO 1001
ENDIF
!
ifactm=lfi%MFACTU(iranfm)
lfi%NULOFM=lfi%NULOFM-1
!
DO j=iranfm,lfi%NULOFM
lfi%MFACTU(j)=lfi%MFACTU(j+1)
lfi%MULOFM(j)=lfi%MULOFM(j+1)
ENDDO
!
irep=0
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTE DE BRANCHEMENT EN CAS D'ERREUR INQUIRE
!-----------------------------------------------------------------------
!
901 CONTINUE
clacti='INQUIRE'
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (llverg) CALL lfiver_fort                        &
&                           (lfi, lfi%VERGLA,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSEIF (irang.EQ.0) THEN
  inimes=lfi%NIMESG
ELSE
  inimes=ixnims(irang)
ENDIF
!
IF (inimes.EQ.0)  THEN 
  IF (lhook) CALL dr_hook('LFISFM_FORT',1,zhook_handle)
  RETURN
ENDIF
clnspr='LFISFM'
!
IF (inimes.EQ.2) THEN
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3)') &
&       krep,knumer
  CALL lfiems_fort                                 &
&                 (lfi, knumer,inimes,irep,llfata, &
&                  clmess,clnspr,clacti)
ENDIF
!
IF (lfi%LFRANC) THEN
  WRITE (unit=clmess,fmt=                               &
&         '(''Suppression du Facteur Multiplicatif'',I3, &
&           '', Unite Logique'',I3)') ifactm,knumer
ELSE
  WRITE (unit=clmess,fmt=                                    &
&         '(''Multiply Factor'',I3,                           &
&           '' suppressed, Logical Unit'',I3)') ifactm,knumer
ENDIF
!
CALL lfiems_fort                                  &
&               (lfi, knumer,inimes,irep,.false., &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFISFM_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfisfm_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfisfm64           &
&           (krep, knumer)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfisfm_fort               &
&           (lfi, krep, knumer)

END SUBROUTINE lfisfm64

SUBROUTINE lfisfm             &
&           (krep, knumer)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfisfm_mt                &
&           (lfi, krep, knumer)

END SUBROUTINE lfisfm

SUBROUTINE lfisfm_mt             &
&           (lfi, krep, knumer)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfisfm_fort               &
&           (lfi, irep, inumer)

krep       = int(      irep, jplikm)

END SUBROUTINE lfisfm_mt

!INTF KREP            OUT 
!INTF KNUMER        IN