lfiren.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfiren_fort                                     &
&                     (lfi, krep, knumer, cdnom1, cdnom2 )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        SOUS-PROGRAMME PERMETTANT DE RENOMMER UN ARTICLE (DE DONNEES)
!     SUR UNE UNITE LOGIQUE OUVERTE POUR LE LOGICIEL DE FICHIERS INDEXES
!     *LFI*. LE NOUVEAU NOM D'ARTICLE NE DOIT PAS Y ETRE DEJA UTILISE.
!**
!    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                KNUMER (ENTREE) ==> LFI%NUMERO DE L'UNITE LOGIQUE;
!                CDNOM1 (ENTREE) ==> NOM DE L'ARTICLE A RENOMMER;
!                CDNOM2 (ENTREE) ==> NOUVEAU NOM A DONNER A L'ARTICLE.
!
!
TYPE(lficom) :: LFI
CHARACTER CDNOM1*(*), CDNOM2*(*), CLNOM1*(lfi%jpncpn),  &
&          CLNOM2*(LFI%JPNCPN)
!
INTEGER (KIND=JPLIKB) KREP, KNUMER, IRANG, IREP, ILCDN1 
INTEGER (KIND=JPLIKB) ILCLN1, ILCDN2, ILCLN2
INTEGER (KIND=JPLIKB) IDECBL, IPOSBL, IARTEX, INBALO 
INTEGER (KIND=JPLIKB) IRGPIM, IRETIN, INIMES
!
LOGICAL LLECR, LLVERF
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, garantissant l'initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIREN_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
llverf=.false.
irep=0
llecr=.false.
ilcdn1=int(len(cdnom1), jplikb)
ilcdn2=int(len(cdnom2), jplikb)
!
IF (min(ilcdn1,ilcdn2).LE.0) THEN
!
  irep=-15
!
  IF (ilcdn1.LE.0) THEN
    clnom1=lfi%CHINCO(:lfi%JPNCPN)
    ilcln1=lfi%JPNCPN
  ELSE
    ilcln1=min(ilcdn1,lfi%JPNCPN)
    clnom1=cdnom1(:ilcln1)
  ENDIF
!
  IF (ilcdn2.LE.0) THEN
    clnom2=lfi%CHINCO(:lfi%JPNCPN)
    ilcln2=lfi%JPNCPN
  ELSE
    ilcln2=min(ilcdn2,lfi%JPNCPN)
    clnom2=cdnom2(:ilcln2)
  ENDIF
!
  GOTO 1001
!
ELSEIF (cdnom1.EQ.' '.OR.cdnom2.EQ.' ') THEN
!
  irep=-18
!
  IF (cdnom1.EQ.' ') THEN
    clnom1=' '
    ilcln1=1
  ELSE
    ilcln1=min(ilcdn1,lfi%JPNCPN)
    clnom1=cdnom1(:ilcln1)
  ENDIF
!
  IF (cdnom2.EQ.' ') THEN
    clnom2=' '
    ilcln2=1
  ELSE
    ilcln2=min(ilcdn2,lfi%JPNCPN)
    clnom2=cdnom2(:ilcln2)
  ENDIF
!
  GOTO 1001
!
ENDIF
!
!        Recherche de la longueur "utile" des noms d'article specifies.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
101 CONTINUE
iposbl=idecbl+int(index(cdnom1(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilcln1=ilcdn1
ELSEIF (cdnom1(iposbl:).EQ.' ') THEN
  ilcln1=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 101
ENDIF
!
idecbl=0
!
102 CONTINUE
iposbl=idecbl+int(index(cdnom2(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilcln2=ilcdn2
ELSEIF (cdnom2(iposbl:).EQ.' ') THEN
  ilcln2=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 102
ENDIF
!
IF (ilcln1.GT.lfi%JPNCPN) THEN
  ilcln1=lfi%JPNCPN
  irep=-15
ENDIF
!
IF (ilcln2.GT.lfi%JPNCPN) THEN
  ilcln2=lfi%JPNCPN
  irep=-15
ENDIF
!
clnom1=cdnom1(:ilcln1)
clnom2=cdnom2(:ilcln2)
IF (irep.NE.0) GOTO 1001
!
IF (irang.EQ.0) THEN
  irep=-1
  GOTO 1001
ENDIF
!
 IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                (lfi, lfi%VERRUE(irang),'ON')
llverf=lfi%LMULTI
!
IF (lfi%NEXPOR(irang).GT.0) THEN
!
!         Fichier en cours d'export... la seule modification acceptee
!         est l'ajout de nouveaux articles.
!
  irep=-37
  GOTO 1001
ENDIF
!
iartex=0
inbalo=lfi%MDES1D(ixm(lfi%JPNALO,irang))
!
IF (inbalo.NE.0) THEN
!**
!     2.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DU NOUVEAU NOM D'ARTICLE, QUI NE DOIT
!            PAS ETRE LE NOM D'UN ARTICLE EXISTANT.
!-----------------------------------------------------------------------
!
  CALL lfiran_fort                                  &
&                 (lfi, irep,irang,clnom2(:ilcln2), &
&                  irgpim,iartex,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
  IF (iartex.NE.0) THEN
    irep=-25
    clacti=clnom2(:ilcln2)
    GOTO 1001
  ENDIF
!**
!     3.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DE L'ARTICLE LOGIQUE A RENOMMER.
!-----------------------------------------------------------------------
!
  CALL lfiran_fort                                  &
&                 (lfi, irep,irang,clnom1(:ilcln1), &
&                  irgpim,iartex,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
IF (iartex.EQ.0) THEN
  irep=-20
  clacti=clnom1(:ilcln1)
  GOTO 1001
ENDIF
!**
!     4.  -  TOUT EST OK... ON EFFECTUE LE CHANGEMENT DE NOM.
!-----------------------------------------------------------------------
!
lfi%CNOMAR(ixc(iartex,irgpim))=clnom2(:ilcln2)
lfi%LECRPI(irgpim,1)=.true.
lfi%NBRENO(irang)=lfi%NBRENO(irang)+1
!
!        On met a jour ce qui a trait aux acces pseudo-sequentiels...
!
lfi%NDERGF(irang)=lfi%JPNAPP*lfi%MFACTM(irang)* &
&                  (lfi%MRGPIF(irgpim)-1)+iartex
lfi%CNDERA(irang)=clnom2(:ilcln2)
lfi%NSUIVF(irang)=lfi%JPNIL
lfi%NPRECF(irang)=lfi%JPNIL
!
IF (.NOT.lfi%LMODIF(irang)) THEN
!
!         CAS DE LA PREMIERE MODIFICATION DEPUIS L'OUVERTURE DU FICHIER.
!
  lfi%LMODIF(irang)=.true.
  CALL lfimoe_fort                         &
&                 (lfi, irep,irang,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!-----------------------------------------------------------------------
!
903 CONTINUE
clacti='WRITE'
GOTO 909
!
904 CONTINUE
clacti='READ'
!
909 CONTINUE
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (irang.NE.0) THEN
  lfi%NDEROP(irang)=13
  lfi%NDERCO(irang)=irep
   IF (llverf) CALL lfiver_fort                               &
&                              (lfi, lfi%VERRUE(irang),'OFF')
ENDIF
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFIREN_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFIREN'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3,        &
&       '', CDNOM1='''''',A,'''''', CDNOM2='''''',A,'''''''')') &
&     krep,knumer,clnom1(:ilcln1),clnom2(:ilcln2)
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFIREN_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixc.h"
#include "lficom2.ixm.h"
#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfiren_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfiren64                      &
&           (krep, knumer, cdnom1, cdnom2)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOM1                                 ! IN   
CHARACTER (LEN=*)      CDNOM2                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiren_fort                               &
&           (lfi, krep, knumer, cdnom1, cdnom2)

END SUBROUTINE lfiren64

SUBROUTINE lfiren                        &
&           (krep, knumer, cdnom1, cdnom2)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOM1                                 ! IN   
CHARACTER (LEN=*)      CDNOM2                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiren_mt                                &
&           (lfi, krep, knumer, cdnom1, cdnom2)

END SUBROUTINE lfiren

SUBROUTINE lfiren_mt                          &
&           (lfi, krep, knumer, cdnom1, cdnom2)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOM1                                 ! IN   
CHARACTER (LEN=*)      CDNOM2                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfiren_fort                               &
&           (lfi, irep, inumer, cdnom1, cdnom2)

krep       = int(      irep, jplikm)

END SUBROUTINE lfiren_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF CDNOM1        IN    
!INTF CDNOM2        IN