lfipxa.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI
SUBROUTINE lfipxa_fort                                            &
&                     (lfi, krep, knumer, cdnoma, cdstru, cdsuiv, &
&                    klsuiv )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Sous-programme Preparatoire a l'eXport d'un Article d'un
!     fichier LFI vers un systeme a priori different.
!
!     Il s'agit, en l'occurrence, de decrire la structure interne
!     de cet article en termes de types de variables.  
!**
!    ARGUMENTS : KREP   (Sortie) ==> Code-Reponse du sous-programme;
!                KNUMER (Entree) ==> Numero d'Unite Logique associe;
!                CDNOMA (Entree) ==> Nom de l'article decrit;
!                CDSTRU (Entree) ==> Structure interne de cet article;
!                CDSUIV (Sortie) ==> Nom de l'article suivant sur le
!                                    fichier, s'il en existe;
!                KLSUIV (Sortie) ==> Longueur de cet article.
!
!     (s'il n'y a pas d'article suivant, on retourne CDSUIV=' ' et
!      KLSUIV=0)
!
!     Les syntaxes autorisees pour CDSTRU sont decrites dans le sous-
!     programmes *LFIDST*.
!     
!
TYPE(lficom) :: LFI
CHARACTER CDNOMA*(*), CDSUIV*(*), CDSTRU*(*)
CHARACTER*(LFI%JPNCPN) CLNOMA, CLSUIV, CLSTRU
!
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLSUIV
INTEGER (KIND=JPLIKB) ILONEX, ILCLNO, ILCDNO, IRANMX 
INTEGER (KIND=JPLIKB) IDECBL, IPOSBL, ILCDST
INTEGER (KIND=JPLIKB) IRANG, IREP, INBALO, IRANIE 
INTEGER (KIND=JPLIKB) INIMES, IARTEX
INTEGER (KIND=JPLIKB) IRGPIM, IRGPIF, IARTIC, IRETIN 
INTEGER (KIND=JPLIKB) ILCDSU, ILCLSU, ILCLST
INTEGER (KIND=JPLIKB) ILUSTR
!
LOGICAL LLVERF
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, garantissant l'initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIPXA_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
irep=0
llverf=.false.
ilcdno=int(len(cdnoma), jplikb)
ilcdsu=int(len(cdsuiv), jplikb)
ilcdst=int(len(cdstru), jplikb)
clnoma=' '
ilclno=1
clstru=' '
ilclst=1
clsuiv=' '
ilclsu=1
klsuiv=0
!
IF (ilcdno.LE.0) THEN
  irep=-15
  clnoma=lfi%CHINCO(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
ELSEIF (cdnoma.EQ.' ') THEN
  irep=-18
ENDIF
!
IF (ilcdsu.LE.0) THEN
  irep=-15
  clsuiv=lfi%CHINCO(:lfi%JPNCPN)
  ilclsu=lfi%JPNCPN
ENDIF
!
IF (ilcdst.LE.0) THEN
  irep=-15
  clstru=lfi%CHINCO(:lfi%JPNCPN)
  ilclst=lfi%JPNCPN
ELSEIF (cdstru.EQ.' ') THEN
  irep=-39
ENDIF
!
IF (irep.NE.0) THEN
  GOTO 1001
ELSE
  cdsuiv=' '
ENDIF
!
!        Recherche de la longueur "utile" du nom d'article specifie.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
101 CONTINUE
iposbl=idecbl+int(index(cdnoma(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilclno=ilcdno
ELSEIF (cdnoma(iposbl:).EQ.' ') THEN
  ilclno=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 101
ENDIF
!
IF (ilclno.LE.lfi%JPNCPN) THEN
  clnoma=cdnoma(:ilclno)
ELSE
  clnoma=cdnoma(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  irep=-15
  GOTO 1001
ENDIF
!
!        Recherche de la longueur "utile" de la structure specifiee.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
102 CONTINUE
iposbl=idecbl+int(index(cdstru(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilustr=ilcdst
ELSEIF (cdstru(iposbl:).EQ.' ') THEN
  ilustr=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 102
ENDIF
!
ilclst=min(ilclst,ilustr)
!
IF (irang.EQ.0) THEN
  irep=-1
  GOTO 1001
ENDIF
!
 IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                (lfi, lfi%VERRUE(irang),'ON')
llverf=lfi%LMULTI
iranie=lfi%NEXPOR(irang)
!
IF (iranie.LE.0) THEN
  irep=-38
  clacti='EXPORT'
  GOTO 1001
ENDIF
!
iranmx=lfi%NRCFMX(iranie)
iartex=0
ilonex=0
inbalo=lfi%MDES1D(ixm(lfi%JPNALO,irang))

IF (inbalo.NE.0) THEN
!**
!     2.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DE L'ARTICLE LOGIQUE DEMANDE.
!-----------------------------------------------------------------------
!
  CALL lfiran_fort                                         &
&                 (lfi, irep,irang,clnoma(:ilclno),irgpim, &
&                  iartex,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
IF (iartex.EQ.0) THEN
  irep=-20
  clacti=clnoma(:ilclno)
  GOTO 1001
ENDIF
!
!        ON COMPLETE LES CARACTERISTIQUES DE L'ARTICLE.
!
irgpif=lfi%MRGPIF(irgpim)
!
IF (.NOT.lfi%LPHASP(irgpim)) THEN
!
  CALL lfipha_fort                                &
&                 (lfi, irep,irang,irgpim,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
ilonex=lfi%MLGPOS(ixm(2*iartex-1,irgpim))
!**
!     8.  -  RECHERCHE DE L'ARTICLE LOGIQUE DE DONNEES SUIVANT.
!-----------------------------------------------------------------------
!
CALL lficax_fort                                       &
&               (lfi, irep,irang,irgpim,iartic,iretin)
!
IF (iretin.EQ.1) THEN
  GOTO 903
ELSEIF (iretin.EQ.2) THEN
  GOTO 904
ELSEIF (iretin.NE.0.OR.iartic.EQ.0) THEN
  GOTO 1001
ENDIF
!
irgpif=lfi%MRGPIF(irgpim)
!
IF (.NOT.lfi%LPHASP(irgpim)) THEN
!
  CALL lfipha_fort                                &
&                 (lfi, irep,irang,irgpim,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
klsuiv=lfi%MLGPOS(ixm(iartic,irgpim))
clsuiv=lfi%CNOMAR(ixc(iartic,irgpim))
!
!        Recherche de la longueur "utile" du nom d'article.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
811 CONTINUE
iposbl=idecbl+int(index(clsuiv(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilclsu=lfi%JPNCPN
ELSEIF (clsuiv(iposbl:).EQ.' ') THEN
  ilclsu=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 811
ENDIF
!
IF (ilcdsu.GE.ilclsu) THEN
  cdsuiv=clsuiv(:ilclno)
ELSE
  irep=-24
  clacti=clsuiv
  GOTO 1001
ENDIF
!
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!-----------------------------------------------------------------------
!
903 CONTINUE
clacti='WRITE'
GOTO 909
!
904 CONTINUE
clacti='READ'
!
909 CONTINUE
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (irang.NE.0) THEN
  lfi%NDEROP(irang)=22
  lfi%NDERCO(irang)=irep
   IF (llverf) CALL lfiver_fort                               &
&                              (lfi, lfi%VERRUE(irang),'OFF')
ENDIF
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFIPXA_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFIPXA'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', CDNOMA='''''',A,'''''', CDSTRU='''''',A,     &
&       '''''', CDSUIV='''''',A,'''''', KLSUIV='',I7)')  &
&     krep,knumer,clnoma(:ilclno),clstru(:ilclst),       &
&     clsuiv(:ilcdsu),klsuiv
CALL lfiems_fort                                        &
&               (lfi, knumer,inimes,irep,llfata,clmess, &
&                clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFIPXA_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixc.h"
#include "lficom2.ixm.h"
#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfipxa_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfipxa64                                      &
&           (krep, knumer, cdnoma, cdstru, cdsuiv, klsuiv)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
CHARACTER (LEN=*)      CDSTRU                                 ! IN   
CHARACTER (LEN=*)      CDSUIV                                 !   OUT
INTEGER (KIND=JPLIKB)  KLSUIV                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfipxa_fort                                               &
&           (lfi, krep, knumer, cdnoma, cdstru, cdsuiv, klsuiv)

END SUBROUTINE lfipxa64

SUBROUTINE lfipxa                                        &
&           (krep, knumer, cdnoma, cdstru, cdsuiv, klsuiv)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
CHARACTER (LEN=*)      CDSTRU                                 ! IN   
CHARACTER (LEN=*)      CDSUIV                                 !   OUT
INTEGER (KIND=JPLIKM)  KLSUIV                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfipxa_mt                                                &
&           (lfi, krep, knumer, cdnoma, cdstru, cdsuiv, klsuiv)

END SUBROUTINE lfipxa

SUBROUTINE lfipxa_mt                                          &
&           (lfi, krep, knumer, cdnoma, cdstru, cdsuiv, klsuiv)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
CHARACTER (LEN=*)      CDSTRU                                 ! IN   
CHARACTER (LEN=*)      CDSUIV                                 !   OUT
INTEGER (KIND=JPLIKM)  KLSUIV                                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILSUIV                                 !   OUT
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfipxa_fort                                               &
&           (lfi, irep, inumer, cdnoma, cdstru, cdsuiv, ilsuiv)

krep       = int(      irep, jplikm)
klsuiv     = int(    ilsuiv, jplikm)

END SUBROUTINE lfipxa_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF CDNOMA        IN    
!INTF CDSTRU        IN    
!INTF CDSUIV          OUT 
!INTF KLSUIV          OUT