lfiosf.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfiosf_fort                             &
&                     (lfi, krep, knumer, ldimst )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Ce sous-programme permet d'obtenir l'option courante gouvernant
!     l'impression de STATISTIQUES a la fermeture d'un fichier
!     particulier, ouvert pour le logiciel LFI.
!
!        Noter que si le niveau global d'impression des statistiques
!     *LFI%NISTAG* vaut 0 ou 2, l'option propre au fichier est inoperante.
!     *LFI%NISTAG* vaut par defaut 1, est reglable via le s/p "LFINSG",
!     et sa valeur peut etre obtenue par le s/p "LFIOSG".
!**
!     ARGUMENTS : KREP   (Sortie) ==> Code-REPonse du sous-programme;
!                 KNUMER (Entree) ==> NUMERo d'unite logique concernee;
!                 LDIMST (Sortie) ==> Option d'IMpression des STatisti-
!                                     ques a la fermeture (vrai=oui).
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KREP, KNUMER, IRANG, IREP, INIMES
!
LOGICAL LDIMST
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIOSF_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
!
IF (irang.NE.0) THEN
   IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                  (lfi, lfi%VERRUE(irang),'ON')
  ldimst=lfi%LISTAT(irang)
  lfi%NDEROP(irang)=20
   IF (lfi%LMULTI) CALL lfiver_fort                               &
&                                  (lfi, lfi%VERRUE(irang),'OFF')
  irep=0
ELSE
  irep=-1
ENDIF
!
krep=irep
llfata=llmoer(irep,irang)
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFIOSF_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFIOSF'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', LDIMST= '',L1)') krep,knumer,ldimst
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFIOSF_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfiosf_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfiosf64              &
&           (krep, knumer, ldimst)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
LOGICAL                LDIMST                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiosf_fort                       &
&           (lfi, krep, knumer, ldimst)

END SUBROUTINE lfiosf64

SUBROUTINE lfiosf                &
&           (krep, knumer, ldimst)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
LOGICAL                LDIMST                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiosf_mt                        &
&           (lfi, krep, knumer, ldimst)

END SUBROUTINE lfiosf

SUBROUTINE lfiosf_mt                  &
&           (lfi, krep, knumer, ldimst)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
LOGICAL                LDIMST                                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfiosf_fort                       &
&           (lfi, irep, inumer, ldimst)

krep       = int(      irep, jplikm)

END SUBROUTINE lfiosf_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF LDIMST          OUT