lfiomf.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfiomf_fort                             &
&                     (lfi, krep, knumer, knimes )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Ce sous-programme permet d'obtenir la valeur courante du niveau
!     de messagerie propre aux actions faites via le logiciel LFI,
!     sur un fichier particulier ouvert pour ce logiciel.
!
!        Noter que si le niveau global de messagerie *LFI%NIMESG*
!     vaut 0 ou 2, le niveau propre au fichier est inoperant.
!     *LFI%NIMESG* vaut par defaut 1, est reglable via le s/p "LFINMG",
!     et sa valeur courante peut etre obtenue par le s/p "LFIOMG".
!**
!     ARGUMENTS : KREP   (Sortie) ==> Code-REPonse du sous-programme;
!                 KNUMER (Entree) ==> NUMERo d'unite logique concernee;
!                 KNIMES (Sortie) ==> NIveau courant de MESsagerie.
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KREP, KNUMER, KNIMES, IRANG, IREP, INIMES
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIOMF_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-1
ELSE
  knimes=lfi%NIVMES(irang)
  lfi%NDEROP(irang)=21
  irep=0
ENDIF
!
llfata=llmoer(irep,irang)
krep=irep
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFIOMF_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFIOMF'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', KNIMES='',I3)') krep,knumer,knimes
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFIOMF_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfiomf_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfiomf64              &
&           (krep, knumer, knimes)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  KNIMES                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiomf_fort                       &
&           (lfi, krep, knumer, knimes)

END SUBROUTINE lfiomf64

SUBROUTINE lfiomf                &
&           (krep, knumer, knimes)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KNIMES                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiomf_mt                        &
&           (lfi, krep, knumer, knimes)

END SUBROUTINE lfiomf

SUBROUTINE lfiomf_mt                  &
&           (lfi, krep, knumer, knimes)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KNIMES                                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  INIMES                                 !   OUT
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfiomf_fort                       &
&           (lfi, irep, inumer, inimes)

krep       = int(      irep, jplikm)
knimes     = int(    inimes, jplikm)

END SUBROUTINE lfiomf_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF KNIMES          OUT